src/staticmaps/CMakeLists.txt

0001 add_library(KPim6GAPIMaps)
0002 add_library(KPim6::GAPIMaps ALIAS KPim6GAPIMaps)
0003 target_sources(KPim6GAPIMaps PRIVATE
0004     ${libkgapi_debug_SRCS}
0005     staticmapmarker.cpp
0006     staticmapmarker.h
0007     staticmappath.cpp
0008     staticmappath.h
0009     staticmaptilefetchjob.cpp
0010     staticmaptilefetchjob.h
0011     staticmapurl.cpp
0012     staticmapurl.h
0013 )
0014
0015 ecm_generate_headers(kgapimaps_CamelCase_HEADERS
0016     HEADER_NAMES
0017     StaticMapMarker
0018     StaticMapPath
0019     StaticMapTileFetchJob
0020     StaticMapUrl
0021     PREFIX KGAPI/Maps
0022     REQUIRED_HEADERS kgapimaps_HEADERS
0023 )
0024
0025 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0026     set_target_properties(KPim6GAPIMaps PROPERTIES UNITY_BUILD ON)
0027 endif()
0028
0029 generate_export_header(KPim6GAPIMaps BASE_NAME kgapimaps)
0030
0031 target_include_directories(KPim6GAPIMaps INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI>")
0032
0033 target_link_libraries(KPim6GAPIMaps
0034 PUBLIC
0035     KPim6::GAPICore
0036     KF6::Contacts
0037     Qt::Gui
0038 PRIVATE
0039     Qt::Network
0040 )
0041
0042 set_target_properties(KPim6GAPIMaps PROPERTIES
0043     VERSION ${KGAPI_VERSION}
0044     SOVERSION ${KGAPI_SOVERSION}
0045     EXPORT_NAME GAPIMaps
0046 )
0047
0048 install(TARGETS
0049     KPim6GAPIMaps
0050     EXPORT KPim6GAPITargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0051 )
0052
0053 install(FILES
0054     ${kgapimaps_CamelCase_HEADERS}
0055     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI/KGAPI/Maps"
0056     COMPONENT Devel
0057 )
0058
0059 install(FILES
0060     ${kgapimaps_HEADERS}
0061     "${CMAKE_CURRENT_BINARY_DIR}/kgapimaps_export.h"
0062     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI/kgapi/maps"
0063     COMPONENT Devel
0064 )
0065
0066 if (BUILD_QCH)
0067     ecm_add_qch(
0068         KPim6GAPIMaps_QCH
0069         NAME KPim6GAPIMaps
0070         BASE_NAME KPim6GAPIMaps
0071         VERSION ${PIM_VERSION}
0072         ORG_DOMAIN org.kde
0073         SOURCES # using only public headers, to cover only public API
0074         ${kgapimaps_HEADERS}
0075         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0076         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0077         LINK_QCHS
0078             Qt6Core_QCH
0079             Qt6Gui_QCH
0080             Qt6Widgets_QCH
0081         INCLUDE_DIRS
0082             ${CMAKE_CURRENT_BINARY_DIR}
0083         BLANK_MACROS
0084             KGAPIMAPS_EXPORT
0085         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0086         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0087         COMPONENT Devel
0088     )
0089 endif()