src/blogger/CMakeLists.txt

0001 add_library(KPim6GAPIBlogger)
0002 add_library(KPim6::GAPIBlogger ALIAS KPim6GAPIBlogger)
0003
0004 target_sources(KPim6GAPIBlogger PRIVATE
0005     ${libkgapi_debug_SRCS}
0006     blog.cpp
0007     blogfetchjob.cpp
0008     blogfetchjob.h
0009     bloggerservice.cpp
0010     bloggerservice.h
0011     blog.h
0012     commentapprovejob.cpp
0013     commentapprovejob.h
0014     comment.cpp
0015     commentdeletecontentjob.cpp
0016     commentdeletecontentjob.h
0017     commentdeletejob.cpp
0018     commentdeletejob.h
0019     commentfetchjob.cpp
0020     commentfetchjob.h
0021     comment.h
0022     page.cpp
0023     pagecreatejob.cpp
0024     pagecreatejob.h
0025     pagedeletejob.cpp
0026     pagedeletejob.h
0027     pagefetchjob.cpp
0028     pagefetchjob.h
0029     page.h
0030     pagemodifyjob.cpp
0031     pagemodifyjob.h
0032     post.cpp
0033     postcreatejob.cpp
0034     postcreatejob.h
0035     postdeletejob.cpp
0036     postdeletejob.h
0037     postfetchjob.cpp
0038     postfetchjob.h
0039     post.h
0040     postmodifyjob.cpp
0041     postmodifyjob.h
0042     postpublishjob.cpp
0043     postpublishjob.h
0044     postsearchjob.cpp
0045     postsearchjob.h
0046 )
0047
0048 ecm_generate_headers(kgapiblogger_CamelCase_HEADERS
0049     HEADER_NAMES
0050     Blog
0051     BlogFetchJob
0052     Comment
0053     CommentApproveJob
0054     CommentDeleteContentJob
0055     CommentDeleteJob
0056     CommentFetchJob
0057     Page
0058     PageCreateJob
0059     PageDeleteJob
0060     PageFetchJob
0061     PageModifyJob
0062     Post
0063     PostCreateJob
0064     PostDeleteJob
0065     PostFetchJob
0066     PostModifyJob
0067     PostPublishJob
0068     PostSearchJob
0069     PREFIX KGAPI/Blogger
0070     REQUIRED_HEADERS kgapiblogger_HEADERS
0071 )
0072
0073 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0074     set_target_properties(KPim6GAPIBlogger PROPERTIES UNITY_BUILD ON)
0075 endif()
0076
0077 generate_export_header(KPim6GAPIBlogger BASE_NAME kgapiblogger)
0078
0079
0080 target_include_directories(KPim6GAPIBlogger INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI>")
0081
0082 target_link_libraries(KPim6GAPIBlogger
0083 PUBLIC
0084     KPim6::GAPICore
0085 PRIVATE
0086     Qt::Network
0087 )
0088
0089 set_target_properties(KPim6GAPIBlogger PROPERTIES
0090     VERSION ${KGAPI_VERSION}
0091     SOVERSION ${KGAPI_SOVERSION}
0092     EXPORT_NAME GAPIBlogger
0093 )
0094
0095 install(TARGETS
0096     KPim6GAPIBlogger
0097     EXPORT KPim6GAPITargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0098 )
0099
0100 install(FILES
0101     ${kgapiblogger_CamelCase_HEADERS}
0102     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI/KGAPI/Blogger"
0103     COMPONENT Devel
0104 )
0105
0106 install(FILES
0107     ${kgapiblogger_HEADERS}
0108     "${CMAKE_CURRENT_BINARY_DIR}/kgapiblogger_export.h"
0109     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI/kgapi/blogger"
0110     COMPONENT Devel
0111 )
0112
0113 if (BUILD_QCH)
0114     ecm_add_qch(
0115         KPim6GAPIBlogger_QCH
0116         NAME KPim6GAPIBlogger
0117         BASE_NAME KPim6GAPIBlogger
0118         VERSION ${PIM_VERSION}
0119         ORG_DOMAIN org.kde
0120         SOURCES # using only public headers, to cover only public API
0121         ${kgapiblogger_HEADERS}
0122         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0123         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0124         LINK_QCHS
0125             Qt6Core_QCH
0126             Qt6Gui_QCH
0127             Qt6Widgets_QCH
0128         INCLUDE_DIRS
0129             ${CMAKE_CURRENT_BINARY_DIR}
0130         BLANK_MACROS
0131             KGAPIBLOGGER_EXPORT
0132         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0133         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0134         COMPONENT Devel
0135     )
0136 endif()