libkdepim/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 add_definitions(-DTRANSLATION_DOMAIN=\"libkdepim6\")
0004 add_library(KPim6Libkdepim)
0005 add_library(KPim6::Libkdepim ALIAS KPim6Libkdepim)
0006 ecm_setup_version(PROJECT VARIABLE_PREFIX LIBKDEPIM
0007     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/libkdepim_version.h"
0008     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6LibkdepimConfigVersion.cmake"
0009     SOVERSION 6
0010     )
0011
0012 if (BUILD_TESTING)
0013     add_subdirectory(tests)
0014     add_subdirectory(progresswidget/autotests/)
0015     add_subdirectory(progresswidget/tests/)
0016 endif()
0017
0018
0019 ########### next target ###############
0020 target_sources(KPim6Libkdepim PRIVATE
0021     progresswidget/progressmanager.cpp
0022     progresswidget/progressdialog.cpp
0023     progresswidget/statusbarprogresswidget.cpp
0024     progresswidget/ssllabel.cpp
0025     progresswidget/progressstatusbarwidget.cpp
0026     widgets/kcheckcombobox.cpp
0027     widgets/kwidgetlister.cpp
0028     widgets/progressindicatorlabel.cpp
0029     multiplyingline/multiplyingline.cpp
0030     multiplyingline/multiplyinglineeditor.cpp
0031     multiplyingline/multiplyinglineview_p.cpp
0032     progresswidget/statusbarprogresswidget.h
0033     progresswidget/ssllabel.h
0034     progresswidget/progressmanager.h
0035     progresswidget/progressdialog.h
0036     progresswidget/progressstatusbarwidget.h
0037     multiplyingline/multiplyinglineeditor.h
0038     multiplyingline/multiplyingline.h
0039     multiplyingline/multiplyinglineview_p.h
0040     libkdepim_private_export.h
0041     widgets/kwidgetlister.h
0042     widgets/kcheckcombobox.h
0043     widgets/progressindicatorlabel.h
0044     )
0045 ecm_qt_declare_logging_category(KPim6Libkdepim HEADER libkdepim_debug.h IDENTIFIER LIBKDEPIM_LOG CATEGORY_NAME org.kde.pim.libkdepim
0046         DESCRIPTION "libkdepim (libkdepim)"
0047         OLD_CATEGORY_NAMES log_libkdepim
0048         EXPORT LIBKDEPIM
0049     )
0050
0051
0052 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0053     set_target_properties(KPim6Libkdepim PROPERTIES UNITY_BUILD ON)
0054 endif()
0055 ecm_generate_export_header(KPim6Libkdepim
0056     BASE_NAME kdepim
0057     VERSION ${LIBKDEPIM_VERSION}
0058     DEPRECATED_BASE_VERSION 0
0059     USE_VERSION_HEADER \"libkdepim_version.h\"
0060 )
0061 target_include_directories(KPim6Libkdepim INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/Libkdepim/>")
0062 target_include_directories(KPim6Libkdepim PUBLIC "$<BUILD_INTERFACE:${libkdepim_SOURCE_DIR}/src;${libkdepim_BINARY_DIR}/src;>")
0063
0064 target_link_libraries(KPim6Libkdepim
0065     PRIVATE
0066     KF6::Completion
0067     KF6::I18n
0068     KF6::WidgetsAddons
0069     )
0070
0071
0072 if(MINGW)
0073     target_link_libraries(KPim6Libkdepim oleaut32)
0074 endif()
0075
0076
0077 set_target_properties(KPim6Libkdepim PROPERTIES
0078     VERSION ${LIBKDEPIM_VERSION}
0079     SOVERSION ${LIBKDEPIM_SOVERSION}
0080     EXPORT_NAME Libkdepim
0081     )
0082
0083 install(TARGETS
0084     KPim6Libkdepim
0085     EXPORT KPim6LibkdepimTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0086     )
0087
0088 ecm_generate_headers(libkdepim_Camelcasewidgets_HEADERS
0089     HEADER_NAMES
0090     KCheckComboBox
0091     KWidgetLister
0092     ProgressIndicatorLabel
0093     REQUIRED_HEADERS libkdepim_widgets_HEADERS
0094     PREFIX Libkdepim
0095     RELATIVE widgets
0096     )
0097
0098 ecm_generate_headers(libkdepim_Camelcaseprogresswidget_HEADERS
0099     HEADER_NAMES
0100     ProgressStatusBarWidget
0101     StatusbarProgressWidget
0102     ProgressDialog
0103     ProgressManager
0104     REQUIRED_HEADERS libkdepim_progresswidget_HEADERS
0105     PREFIX Libkdepim
0106     RELATIVE progresswidget
0107     )
0108
0109 ecm_generate_headers(libkdepim_Camelcasemultiline_HEADERS
0110     HEADER_NAMES
0111     MultiplyingLine
0112     MultiplyingLineEditor
0113     REQUIRED_HEADERS libkdepim_multiline_HEADERS
0114     PREFIX Libkdepim
0115     RELATIVE multiplyingline
0116     )
0117
0118 install(FILES
0119     ${libkdepim_CamelcaseCamelCase_HEADERS}
0120     ${libkdepim_Camelcasewidgets_HEADERS}
0121     ${libkdepim_Camelcaseprogresswidget_HEADERS}
0122     ${libkdepim_Camelcasemultiline_HEADERS}
0123     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/Libkdepim/Libkdepim
0124     COMPONENT Devel
0125     )
0126
0127 install(FILES
0128     ${CMAKE_CURRENT_BINARY_DIR}/kdepim_export.h
0129     ${libkdepim_CamelCase_HEADERS}
0130     ${libkdepim_progresswidget_HEADERS}
0131     ${libkdepim_widgets_HEADERS}
0132     ${libkdepim_multiline_HEADERS}
0133     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/Libkdepim/libkdepim
0134     COMPONENT Devel
0135     )
0136
0137 if(BUILD_DESIGNERPLUGIN)
0138     add_subdirectory(designer)
0139 endif()
0140 ########### install files ###############
0141
0142 install(FILES interfaces/org.kde.addressbook.service.xml interfaces/org.kde.mailtransport.service.xml DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR})
0143
0144 install(FILES
0145     ${CMAKE_CURRENT_BINARY_DIR}/libkdepim_version.h
0146     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/Libkdepim COMPONENT Devel
0147     )
0148
0149 if (BUILD_QCH)
0150     ecm_add_qch(
0151         KPim6Libkdepim_QCH
0152         NAME KPim6Libkdepim
0153         BASE_NAME KPim6Libkdepim
0154         VERSION ${PIM_VERSION}
0155         ORG_DOMAIN org.kde
0156         SOURCES # using only public headers, to cover only public API
0157             ${libkdepim_CamelCase_HEADERS}
0158             ${libkdepim_progresswidget_HEADERS}
0159             ${libkdepim_widgets_HEADERS}
0160             ${libkdepim_multiline_HEADERS}
0161         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0162         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0163         LINK_QCHS
0164             Qt6Core_QCH
0165             Qt6Gui_QCH
0166             Qt6Widgets_QCH
0167         INCLUDE_DIRS
0168             ${CMAKE_CURRENT_BINARY_DIR}
0169         BLANK_MACROS
0170             KDEPIM_EXPORT
0171         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0172         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0173         COMPONENT Devel
0174     )
0175 endif()