pim/libkdepim/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.40")
0005
0006 project(libkdepim VERSION ${PIM_VERSION})
0007
0008 set(KF_MIN_VERSION "5.248.0")
0009 set(QT_REQUIRED_VERSION "6.6.0")
0010 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDECompilerSettings NO_POLICY_SCOPE)
0016
0017 include(ECMGenerateExportHeader)
0018 include(ECMSetupVersion)
0019 include(ECMGenerateHeaders)
0020
0021 include(FeatureSummary)
0022 include(KDEGitCommitHooks)
0023 include(KDEClangFormat)
0024 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0025 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0026
0027 include(ECMQtDeclareLoggingCategory)
0028 include(ECMDeprecationSettings)
0029 include(ECMFeatureSummary)
0030 include(ECMAddTests)
0031 include(ECMAddQch)
0032
0033
0034 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0035 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0036
0037 set(LIBKDEPIM_LIB_VERSION ${PIM_VERSION})
0038 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Widgets Test DBus Network)
0039
0040 find_package(KF6Completion ${KF_MIN_VERSION} CONFIG REQUIRED)
0041 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0042 find_package(KF6WidgetsAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0043
0044 option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON)
0045 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0046
0047 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0048 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.249.0)
0049
0050
0051
0052 ########### CMake Config Files ###########
0053 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6Libkdepim")
0054
0055
0056
0057 configure_package_config_file(KPimMailTransportDBusServiceConfig.cmake.in
0058   ${CMAKE_CURRENT_BINARY_DIR}/KPim6MailTransportDBusServiceConfig.cmake
0059   PATH_VARS KDE_INSTALL_DBUSINTERFACEDIR
0060   INSTALL_DESTINATION "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6MailTransportDBusService")
0061
0062 install(FILES
0063   ${CMAKE_CURRENT_BINARY_DIR}/KPim6MailTransportDBusServiceConfig.cmake
0064   DESTINATION "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6MailTransportDBusService")
0065
0066 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0067
0068 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0069 if (USE_UNITY_CMAKE_SUPPORT)
0070     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0071 endif()
0072
0073 add_subdirectory(src)
0074
0075 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6Libkdepim")
0076
0077 if (BUILD_QCH)
0078     ecm_install_qch_export(
0079         TARGETS KPim6Libkdepim_QCH
0080         FILE KPim6LibkdepimQchTargets.cmake
0081         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0082         COMPONENT Devel
0083     )
0084     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6LibkdepimQchTargets.cmake\")")
0085 endif()
0086
0087 configure_package_config_file(
0088     "${CMAKE_CURRENT_SOURCE_DIR}/KPimLibkdepimConfig.cmake.in"
0089     "${CMAKE_CURRENT_BINARY_DIR}/KPim6LibkdepimConfig.cmake"
0090     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0091     )
0092
0093 install(FILES
0094     "${CMAKE_CURRENT_BINARY_DIR}/KPim6LibkdepimConfig.cmake"
0095     "${CMAKE_CURRENT_BINARY_DIR}/src/KPim6LibkdepimConfigVersion.cmake"
0096     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0097     COMPONENT Devel
0098     )
0099
0100 install(EXPORT KPim6LibkdepimTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6LibkdepimTargets.cmake NAMESPACE KPim6::)
0101
0102
0103 ecm_qt_install_logging_categories(
0104         EXPORT LIBKDEPIM
0105         FILE libkdepim.categories
0106         DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0107         )
0108
0109 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0110 ki18n_install(po)
0111
0112
0113
0114 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)