pim/libgravatar/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.40")
0005
0006 project(gravatar VERSION ${PIM_VERSION})
0007
0008 set(KF_MIN_VERSION "5.248.0")
0009 set(QT_REQUIRED_VERSION "6.6.0")
0010 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDECompilerSettings NO_POLICY_SCOPE)
0016
0017 include(ECMGenerateExportHeader)
0018 include(ECMSetupVersion)
0019 include(ECMGenerateHeaders)
0020
0021 include(FeatureSummary)
0022 include(KDEGitCommitHooks)
0023 include(KDEClangFormat)
0024 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0025 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0026
0027 include(ECMQtDeclareLoggingCategory)
0028 include(ECMDeprecationSettings)
0029 include(ECMFeatureSummary)
0030 include(ECMAddTests)
0031 include(ECMAddQch)
0032
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036
0037 set(LIBGRAVATAR_LIB_VERSION ${PIM_VERSION})
0038 set(PIMCOMMON_LIB_VERSION "6.0.40")
0039 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Widgets Network)
0040 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0041 find_package(KF6Config ${KF_MIN_VERSION} CONFIG REQUIRED)
0042 find_package(KF6WidgetsAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0043 find_package(KF6TextWidgets ${KF_MIN_VERSION} CONFIG REQUIRED)
0044 find_package(KF6KIO ${KF_MIN_VERSION} CONFIG REQUIRED)
0045 find_package(KPim6PimCommon ${PIMCOMMON_LIB_VERSION} CONFIG REQUIRED)
0046
0047 ecm_setup_version(PROJECT VARIABLE_PREFIX GRAVATAR
0048     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/gravatar_version.h"
0049     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6GravatarConfigVersion.cmake"
0050     SOVERSION 6
0051     )
0052
0053
0054 ########### Targets ###########
0055
0056
0057 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0058 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.249.0)
0059
0060
0061 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0062
0063 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0064 if (USE_UNITY_CMAKE_SUPPORT)
0065     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0066 endif()
0067 if(BUILD_TESTING)
0068    add_definitions(-DBUILD_TESTING)
0069 endif()
0070
0071
0072 add_subdirectory(src)
0073
0074 ########### CMake Config Files ###########
0075 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6Gravatar")
0076 if (BUILD_QCH)
0077     ecm_install_qch_export(
0078         TARGETS KPim6Gravatar_QCH
0079         FILE KPim6GravatarQchTargets.cmake
0080         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0081         COMPONENT Devel
0082     )
0083     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6GravatarQchTargets.cmake\")")
0084 endif()
0085
0086 configure_package_config_file(
0087     "${CMAKE_CURRENT_SOURCE_DIR}/KPimGravatarConfig.cmake.in"
0088     "${CMAKE_CURRENT_BINARY_DIR}/KPim6GravatarConfig.cmake"
0089     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0090     )
0091
0092 install(FILES
0093     "${CMAKE_CURRENT_BINARY_DIR}/KPim6GravatarConfig.cmake"
0094     "${CMAKE_CURRENT_BINARY_DIR}/KPim6GravatarConfigVersion.cmake"
0095     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0096     COMPONENT Devel
0097     )
0098
0099 install(EXPORT KPim6GravatarTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0100     FILE KPim6GravatarTargets.cmake NAMESPACE KPim6::)
0101
0102 install(FILES
0103     ${CMAKE_CURRENT_BINARY_DIR}/src/gravatar_version.h
0104     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/Gravatar COMPONENT Devel
0105     )
0106
0107 if (BUILD_TESTING)
0108     find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Test)
0109     add_subdirectory(autotests)
0110     add_subdirectory(tests)
0111 endif()
0112
0113 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0114 ki18n_install(po)
0115 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)