ktnef/src/CMakeLists.txt

0001 add_library(KPim6Tnef)
0002 add_library(KPim6::Tnef ALIAS KPim6Tnef)
0003
0004 target_sources(KPim6Tnef PRIVATE
0005   ktnefparser.cpp
0006   ktnefproperty.cpp
0007   ktnefattach.cpp
0008   mapi.cpp
0009   ktnefpropertyset.cpp
0010   ktnefmessage.cpp
0011   ktnefwriter.cpp
0012   lzfu.cpp
0013   formatter.cpp
0014   ktnefpropertyset.h
0015   ktnefparser.h
0016   mapi.h
0017   ktnefattach.h
0018   lzfu.h
0019   ktnefmessage.h
0020   ktnefdefs.h
0021   formatter.h
0022   ktnefwriter.h
0023   ktnefproperty.h
0024 )
0025
0026 ecm_qt_declare_logging_category(KPim6Tnef HEADER ktnef_debug.h IDENTIFIER KTNEF_LOG CATEGORY_NAME org.kde.pim.ktnef
0027         OLD_CATEGORY_NAMES log_ktnef
0028         DESCRIPTION "ktnef (pim lib)" EXPORT KTNEF)
0029
0030 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0031     set_target_properties(KPim6Tnef PROPERTIES UNITY_BUILD ON)
0032 endif()
0033 generate_export_header(KPim6Tnef BASE_NAME ktnef)
0034
0035
0036
0037 target_include_directories(KPim6Tnef INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KTNEF>")
0038 target_include_directories(KPim6Tnef PUBLIC "$<BUILD_INTERFACE:${KTnef_SOURCE_DIR}/src;${KTnef_BINARY_DIR}/src>")
0039
0040 target_link_libraries(KPim6Tnef
0041 PUBLIC
0042   KF6::CalendarCore
0043 PRIVATE
0044   KPim6::CalendarUtils
0045   KF6::Contacts
0046   KF6::I18n
0047 )
0048
0049 set_target_properties(KPim6Tnef PROPERTIES
0050     VERSION ${KTNEF_VERSION}
0051     SOVERSION ${KTNEF_SOVERSION}
0052     EXPORT_NAME Tnef
0053 )
0054
0055 install(TARGETS KPim6Tnef EXPORT KPim6TnefTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0056
0057 ecm_generate_headers(KTnef_CamelCase_HEADERS
0058   HEADER_NAMES
0059   Formatter
0060   KTNEFAttach
0061   KTNEFDefs
0062   KTNEFMessage
0063   KTNEFParser
0064   KTNEFProperty
0065   KTNEFPropertySet
0066   KTNEFWriter
0067   PREFIX KTNEF
0068   REQUIRED_HEADERS KTnef_HEADERS
0069 )
0070
0071 install(FILES ${KTnef_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KTNEF/KTNEF/ COMPONENT Devel)
0072
0073 install(FILES
0074     ${CMAKE_CURRENT_BINARY_DIR}/ktnef_export.h
0075     ${KTnef_HEADERS}
0076     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KTNEF/ktnef
0077     COMPONENT Devel
0078 )
0079
0080 ecm_qt_install_logging_categories(EXPORT KTNEF FILE ktnef.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0081
0082
0083 if (BUILD_QCH)
0084     ecm_add_qch(
0085         KPim6Tnef_QCH
0086         NAME KTnef
0087         BASE_NAME KPim6Tnef
0088         VERSION ${PIM_VERSION}
0089         ORG_DOMAIN org.kde
0090         SOURCES # using only public headers, to cover only public API
0091             ${KTnef_HEADERS}
0092         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0093         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0094         LINK_QCHS
0095             Qt6Core_QCH
0096         INCLUDE_DIRS
0097             ${CMAKE_CURRENT_BINARY_DIR}
0098         BLANK_MACROS
0099             KTNEF_EXPORT
0100         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0101         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0102         COMPONENT Devel
0103     )
0104 endif()