ksmtp/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 add_library(KPim6SMTP)
0004 add_library(KPim6::SMTP ALIAS KPim6SMTP)
0005 target_sources(KPim6SMTP PRIVATE
0006     job.cpp
0007     loginjob.cpp
0008     sendjob.cpp
0009     session.cpp
0010     sessionthread.cpp
0011     sessionuiproxy.cpp
0012     loginjob.h
0013     sessionthread_p.h
0014     session_p.h
0015     job.h
0016     serverresponse_p.h
0017     session.h
0018     sessionuiproxy.h
0019     job_p.h
0020     sendjob.h
0021 )
0022
0023 ecm_qt_declare_logging_category(KPim6SMTP HEADER ksmtp_debug.h
0024         IDENTIFIER KSMTP_LOG CATEGORY_NAME org.kde.pim.ksmtp
0025         DESCRIPTION "ksmtp (ksmtp)" EXPORT KSMTP
0026         )
0027
0028 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0029     set_target_properties(KPim6SMTP PROPERTIES UNITY_BUILD ON)
0030 endif()
0031
0032 ecm_generate_export_header(KPim6SMTP
0033     BASE_NAME ksmtp
0034     VERSION ${KSMTP_VERSION}
0035     DEPRECATED_BASE_VERSION 0
0036     USE_VERSION_HEADER
0037 )
0038 target_include_directories(KPim6SMTP INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KSMTP;${KDE_INSTALL_INCLUDEDIR}/KPim6/KSMTP/ksmtp>")
0039
0040 if (WIN32)
0041     set(extra_LIBS ws2_32)
0042 endif()
0043
0044
0045 target_link_libraries(KPim6SMTP
0046 PUBLIC
0047     KF6::CoreAddons
0048 PRIVATE
0049     KF6::I18n
0050     KF6::KIOCore
0051     Qt::Network
0052     Sasl2::Sasl2
0053     ${extra_LIBS}
0054 )
0055
0056 set_target_properties(KPim6SMTP PROPERTIES
0057     VERSION ${KSMTP_VERSION}
0058     SOVERSION ${KSMTP_SOVERSION}
0059     EXPORT_NAME SMTP
0060 )
0061
0062 ecm_generate_headers(KSMTP_CamelCase_HEADERS
0063     HEADER_NAMES
0064     Job
0065     LoginJob
0066     SendJob
0067     Session
0068     SessionUiProxy
0069     PREFIX KSMTP
0070
0071     REQUIRED_HEADERS KSMTP_HEADERS
0072 )
0073
0074 install(TARGETS KPim6SMTP EXPORT KPim6SMTPTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0075
0076 install(FILES
0077     ${CMAKE_CURRENT_BINARY_DIR}/ksmtp_export.h
0078     ${KSMTP_HEADERS}
0079     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KSMTP/ksmtp
0080 )
0081
0082 install(FILES
0083     ${KSMTP_CamelCase_HEADERS}
0084     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KSMTP/KSMTP
0085 )
0086 ecm_qt_install_logging_categories(EXPORT KSMTP FILE ksmtp.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0087
0088 if (BUILD_QCH)
0089     ecm_add_qch(
0090         KPim6SMTP_QCH
0091         NAME KPim6SMTP
0092         BASE_NAME KPim6SMTP
0093         VERSION ${PIM_VERSION}
0094         ORG_DOMAIN org.kde
0095         SOURCES # using only public headers, to cover only public API
0096             ${KSMTP_HEADERS}
0097             ${KSMTP_CamelCase_HEADERS}
0098         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0099         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0100         LINK_QCHS
0101             Qt6Core_QCH
0102             Qt6Gui_QCH
0103             Qt6Widgets_QCH
0104         INCLUDE_DIRS
0105             ${CMAKE_CURRENT_BINARY_DIR}
0106         BLANK_MACROS
0107             KSMTP_EXPORT
0108         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0109         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0110         COMPONENT Devel
0111     )
0112 endif()
0113