kpkpass/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2018 Volker Krause <vkrause@kde.org>
0002 # SPDX-FileCopyrightText: 2019-2024 Laurent Montel <montel@kde.org>
0003 # SPDX-License-Identifier: BSD-3-Clause
0004
0005 set(KDE_INSTALL_INCLUDEDIR_PIM ${KDE_INSTALL_INCLUDEDIR}/KPim6)
0006 add_library(KPim6PkPass)
0007 add_library(KPim6::PkPass ALIAS KPim6PkPass)
0008
0009 target_sources(KPim6PkPass PRIVATE
0010     barcode.cpp
0011     boardingpass.cpp
0012     field.cpp
0013     location.cpp
0014     pass.cpp
0015     pass.h
0016     pass_p.h
0017     location.h
0018     field.h
0019     boardingpass.h
0020     barcode.h
0021 )
0022
0023 ecm_qt_declare_logging_category(KPim6PkPass
0024         HEADER logging.h
0025         IDENTIFIER KPkPass::Log
0026         CATEGORY_NAME org.kde.pkpass
0027         DESCRIPTION "KPkPass" EXPORT KPKPASS)
0028
0029 ecm_generate_export_header(KPim6PkPass
0030     BASE_NAME KPkPass
0031     VERSION ${KPKPASS_VERSION}
0032     DEPRECATED_BASE_VERSION 0
0033     USE_VERSION_HEADER \"kpkpass_version.h\"
0034 )
0035
0036
0037 set_target_properties(KPim6PkPass PROPERTIES
0038     VERSION ${KPKPASS_VERSION}
0039     SOVERSION ${KPKPASS_SOVERSION}
0040     EXPORT_NAME PkPass
0041 )
0042 target_include_directories(KPim6PkPass INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_PIM}>")
0043 target_link_libraries(KPim6PkPass
0044     PUBLIC
0045         Qt::Gui
0046     PRIVATE
0047         KF6::Archive
0048 )
0049
0050 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0051     set_target_properties(KPim6PkPass PROPERTIES UNITY_BUILD ON)
0052 endif()
0053
0054 ecm_generate_headers(KPkPass_HEADERS
0055     HEADER_NAMES
0056         Barcode
0057         BoardingPass
0058         Field
0059         Location
0060         Pass
0061     REQUIRED_HEADERS KPkPass_HEADERS
0062 )
0063
0064 install(TARGETS KPim6PkPass EXPORT KPim6PkPassTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0065 install(FILES
0066     ${KPkPass_HEADERS}
0067     ${CMAKE_CURRENT_BINARY_DIR}/kpkpass_export.h
0068     ${CMAKE_BINARY_DIR}/src/kpkpass_version.h
0069     DESTINATION ${KDE_INSTALL_INCLUDEDIR_PIM}/KPkPass
0070 )
0071
0072 if (NOT ANDROID AND SharedMimeInfo_VERSION_STRING VERSION_LESS 2.2)
0073     install(FILES application-vnd-apple-pkpass.xml DESTINATION ${KDE_INSTALL_MIMEDIR})
0074     update_xdg_mimetypes(${KDE_INSTALL_MIMEDIR})
0075 endif()
0076
0077 if (BUILD_QCH)
0078     ecm_add_qch(
0079         KPim6PkPass_QCH
0080         NAME KPim6PkPass
0081         BASE_NAME KPim6PkPass
0082         VERSION ${PIM_VERSION}
0083         ORG_DOMAIN org.kde
0084         SOURCES # using only public headers, to cover only public API
0085             ${KPkPass_HEADERS}
0086         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0087         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0088         LINK_QCHS
0089             Qt6Core_QCH
0090             Qt6Gui_QCH
0091             Qt6Widgets_QCH
0092         INCLUDE_DIRS
0093             ${CMAKE_CURRENT_BINARY_DIR}
0094         BLANK_MACROS
0095             KPKPASS_EXPORT
0096         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0097         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0098         COMPONENT Devel
0099     )
0100 endif()
0101
0102 ecm_qt_install_logging_categories(EXPORT KPKPASS FILE org_kde_kpkpass.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})