kontactinterface/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 add_library(KPim6KontactInterface)
0005 add_library(KPim6::KontactInterface ALIAS KPim6KontactInterface)
0006
0007 target_sources(KPim6KontactInterface PRIVATE
0008     core.cpp
0009     plugin.cpp
0010     summary.cpp
0011     processes.cpp
0012     uniqueapphandler.cpp
0013     pimuniqueapplication.cpp
0014     processes.h
0015     core.h
0016     plugin.h
0017     uniqueapphandler.h
0018     pimuniqueapplication.h
0019     summary.h)
0020
0021 ecm_qt_declare_logging_category(KPim6KontactInterface HEADER kontactinterface_debug.h IDENTIFIER KONTACTINTERFACE_LOG CATEGORY_NAME org.kde.pim.kontactinterface
0022         OLD_CATEGORY_NAMES log_kontactinterface
0023         DESCRIPTION "kontactinterface (pim lib)" EXPORT KONTACTINTERFACE)
0024
0025 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0026     set_target_properties(KPim6KontactInterface PROPERTIES UNITY_BUILD ON)
0027 endif()
0028
0029 ecm_generate_export_header(KPim6KontactInterface
0030     BASE_NAME kontactinterface
0031     VERSION ${KONTACTINTERFACE_VERSION}
0032     DEPRECATED_BASE_VERSION 0
0033     USE_VERSION_HEADER
0034 )
0035
0036 target_include_directories(KPim6KontactInterface INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KontactInterface>")
0037 target_include_directories(KPim6KontactInterface PUBLIC "$<BUILD_INTERFACE:${KontactInterface_SOURCE_DIR}/src;${KontactInterface_BINARY_DIR}/src;${KontactInterface_BINARY_DIR}>")
0038
0039 target_link_libraries(KPim6KontactInterface
0040                      PUBLIC
0041                       KF6::CoreAddons
0042                       KF6::Parts
0043                       KF6::XmlGui
0044                      PRIVATE
0045                       KF6::WindowSystem
0046                       KF6::I18n
0047                       KF6::KIOGui
0048 )
0049
0050 if (KONTACTINTERFACE_HAVE_X11)
0051     target_link_libraries(KPim6KontactInterface PRIVATE Qt::GuiPrivate)
0052 endif()
0053
0054 set_target_properties(KPim6KontactInterface PROPERTIES
0055     VERSION ${KONTACTINTERFACE_VERSION}
0056     SOVERSION ${KONTACTINTERFACE_SOVERSION}
0057     EXPORT_NAME KontactInterface
0058 )
0059
0060
0061 install(TARGETS KPim6KontactInterface EXPORT KPim6KontactInterfaceTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0062
0063 ########### install files ###############
0064
0065 ecm_generate_headers(KontactInterface_CamelCase_HEADERS
0066   HEADER_NAMES
0067   Core
0068   PimUniqueApplication
0069   Plugin
0070   Summary
0071   UniqueAppHandler
0072   Processes
0073   PREFIX KontactInterface
0074   REQUIRED_HEADERS KontactInterface_HEADERS
0075 )
0076
0077 install(FILES
0078   ${CMAKE_CURRENT_BINARY_DIR}/kontactinterface_export.h
0079   ${KontactInterface_HEADERS}
0080   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KontactInterface/kontactinterface
0081   COMPONENT Devel
0082 )
0083
0084 install(FILES
0085     ${KontactInterface_CamelCase_HEADERS}
0086     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KontactInterface/KontactInterface/
0087     COMPONENT Devel
0088 )
0089
0090 ecm_qt_install_logging_categories(EXPORT KONTACTINTERFACE FILE kontactinterface.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0091
0092 if (BUILD_QCH)
0093     ecm_add_qch(
0094         KPim6KontactInterface_QCH
0095         NAME KPim6KontactInterface
0096         BASE_NAME KPim6KontactInterface
0097         VERSION ${PIM_VERSION}
0098         ORG_DOMAIN org.kde
0099         SOURCES # using only public headers, to cover only public API
0100              ${KontactInterface_HEADERS}
0101         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0102         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0103         LINK_QCHS
0104             Qt6Core_QCH
0105             Qt6Gui_QCH
0106             Qt6Widgets_QCH
0107         INCLUDE_DIRS
0108             ${CMAKE_CURRENT_BINARY_DIR}
0109         BLANK_MACROS
0110             KONTACTINTERFACE_EXPORT
0111         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0112         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0113         COMPONENT Devel
0114     )
0115 endif()