kontact/src/CMakeLists.txt

0001 configure_file(kontact-version.h.in ${CMAKE_CURRENT_BINARY_DIR}/kontact-version.h @ONLY)
0002 add_subdirectory(about)
0003 add_library(kontactprivate)
0004
0005 ########### next target ###############
0006
0007 target_sources(kontactprivate PRIVATE
0008     webengine/introductionwebenginepage.cpp
0009     webengine/introductionwebengineview.cpp
0010     mainwindow.cpp
0011     sidepanebase.cpp
0012     iconsidepane.cpp
0013     ksettingsdialog/kontactkcmultidialog.cpp
0014     ksettingsdialog/kontactsettingsdialog.cpp
0015     kontactconfiguredialog.cpp
0016     webengine/introductionwebenginepage.h
0017     webengine/introductionwebengineview.h
0018     mainwindow.h
0019     sidepanebase.h
0020     iconsidepane.h
0021     ksettingsdialog/kontactkcmultidialog.h
0022     ksettingsdialog/kontactsettingsdialog.h
0023     ksettingsdialog/kontactkcmultidialog_p.h
0024     ksettingsdialog/kontactsettingsdialog_p.h
0025     kontactconfiguredialog.h
0026     kontact.qrc
0027     )
0028
0029 ecm_qt_declare_logging_category(kontactprivate HEADER kontact_debug.h IDENTIFIER KONTACT_LOG CATEGORY_NAME org.kde.pim.kontact
0030         DESCRIPTION "kontact (kontact application)"
0031         OLD_CATEGORY_NAMES log_kontact
0032         EXPORT KONTACT
0033     )
0034
0035 kconfig_add_kcfg_files(kontactprivate prefs.kcfgc)
0036
0037
0038 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0039     set_target_properties(kontactprivate PROPERTIES UNITY_BUILD ON)
0040 endif()
0041
0042 generate_export_header(kontactprivate BASE_NAME kontact)
0043
0044 target_link_libraries(kontactprivate
0045     PUBLIC
0046     KF6::IconThemes
0047     PRIVATE
0048     KF6::KCMUtils
0049     KF6::I18n
0050     KF6::KIOWidgets
0051     KPim6::KontactInterface
0052     KF6::GuiAddons
0053     KPim6::Libkdepim
0054     KPim6::PimCommon
0055     KPim6::GrantleeTheme
0056     Qt::WebEngineWidgets
0057     )
0058
0059 set_target_properties(kontactprivate PROPERTIES
0060     VERSION ${KDEPIM_LIB_VERSION}
0061     SOVERSION ${KDEPIM_LIB_SOVERSION}
0062     )
0063
0064 install(TARGETS kontactprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
0065
0066 ########### next target ###############
0067
0068
0069 file(GLOB icons "${CMAKE_CURRENT_SOURCE_DIR}/icons/*-apps-kontact.png")
0070 ecm_add_app_icon(kontact_bin_SRCS ICONS ${icons})
0071
0072 add_executable(kontact_bin)
0073 target_sources(kontact_bin PRIVATE main.cpp kontact_debug.cpp)
0074
0075 set_target_properties(kontact_bin PROPERTIES OUTPUT_NAME kontact)
0076
0077 target_link_libraries(kontact_bin
0078     kontactprivate
0079     KF6::I18n
0080     KPim6::KontactInterface
0081     KF6::Crash
0082     )
0083 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0084     set_target_properties(kontact_bin PROPERTIES UNITY_BUILD ON)
0085 endif()
0086
0087 install(TARGETS kontact_bin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0088
0089 ########### next target ###############
0090
0091 add_library(kcm_kontact MODULE kcmkontact.cpp kcmkontact.h)
0092 target_link_libraries(kcm_kontact
0093     KF6::I18n
0094     KF6::KCMUtils
0095     KPim6::Libkdepim
0096     kontactprivate
0097     KF6::KIOWidgets
0098     KPim6::KontactInterface
0099     )
0100
0101 install(TARGETS kcm_kontact DESTINATION ${KDE_INSTALL_PLUGINDIR}/pim6/kcms/kontact)
0102
0103 ########### install files ###############
0104
0105 install(PROGRAMS data/org.kde.kontact.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0106 install(FILES data/org.kde.kontact.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0107 install(FILES kontact.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0108 configure_file(data/org.kde.kontact.service.in org.kde.kontact.service)
0109 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/org.kde.kontact.service DESTINATION ${KDE_INSTALL_DBUSSERVICEDIR})
0110
0111 add_subdirectory(icons)
0112