noteshared/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 add_definitions(-DTRANSLATION_DOMAIN=\"libnoteshared\")
0005
0006 set(libnoteshared_SRCS
0007     akonadi/notesakonaditreemodel.cpp
0008     akonadi/noteschangerecorder.cpp
0009     attributes/notealarmattribute.cpp
0010     attributes/notedisplayattribute.cpp
0011     attributes/notelockattribute.cpp
0012     attributes/showfoldernotesattribute.cpp
0013     attributes/attributeregistrar.cpp
0014     noteutils.cpp
0015     network/notesnetworksender.cpp
0016     network/notesnetworkreceiver.cpp
0017     network/notehostdialog.cpp
0018     editor/noteeditorutils.cpp
0019     editor/noteeditor.cpp
0020     config/noteactionconfig.cpp
0021     config/notenetworkconfig.cpp
0022     resources/localresourcecreator.cpp
0023     job/createnewnotejob.cpp
0024     dialog/selectednotefolderdialog.cpp
0025     widget/notelistwidget.cpp
0026     alarms/notealarmdialog.cpp
0027
0028     akonadi/notesakonaditreemodel.h
0029     akonadi/noteschangerecorder.h
0030     attributes/notealarmattribute.h
0031     attributes/notedisplayattribute.h
0032     attributes/notelockattribute.h
0033     attributes/showfoldernotesattribute.h
0034     noteutils.h
0035     network/notesnetworksender.h
0036     network/notesnetworkreceiver.h
0037     network/notehostdialog.h
0038     editor/noteeditorutils.h
0039     editor/noteeditor.h
0040     config/noteactionconfig.h
0041     config/notenetworkconfig.h
0042     resources/localresourcecreator.h
0043     job/createnewnotejob.h
0044     dialog/selectednotefolderdialog.h
0045     widget/notelistwidget.h
0046     alarms/notealarmdialog.h
0047
0048     widget/richtexteditwithautocorrection.cpp
0049     widget/richtexteditwithautocorrection.h
0050 )
0051
0052 ecm_qt_declare_logging_category(libnoteshared_SRCS HEADER noteshared_debug.h IDENTIFIER NOTESHARED_LOG CATEGORY_NAME org.kde.pim.noteshared
0053         DESCRIPTION "knotes (noteshared)"
0054         OLD_CATEGORY_NAMES log_noteshared
0055         EXPORT KNOTES
0056     )
0057
0058
0059 macro(add_resource_iface _kcfgFile _ifaceName _className)
0060     kcfg_generate_dbus_interface(${_kcfgFile} ${_ifaceName})
0061     set_source_files_properties( ${CMAKE_CURRENT_BINARY_DIR}/${_ifaceName}.xml PROPERTIES INCLUDE "resources/metatype.h")
0062     qt_add_dbus_interface(libnoteshared_SRCS
0063         ${CMAKE_CURRENT_BINARY_DIR}/${_ifaceName}.xml ${_className}
0064         )
0065 endmacro()
0066
0067 add_resource_iface( ${CMAKE_CURRENT_SOURCE_DIR}/resources/maildirresource.kcfg
0068     org.kde.Akonadi.Maildir.Settings maildirsettings )
0069
0070 add_custom_target(noteshared_settings_xml ALL
0071     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.Akonadi.Maildir.Settings.xml
0072     SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/resources/maildirresource.kcfg
0073     )
0074
0075
0076
0077 set( libnoteshared_kcfg_lib_SRCS settings/notesharedglobalconfig.kcfgc )
0078
0079 kconfig_add_kcfg_files(libnoteshared_kcfg_lib_SRCS ${libnoteshared_kcfg_lib_SRCS})
0080
0081
0082 add_library(notesharedprivate ${libnoteshared_SRCS} ${libnoteshared_kcfg_lib_SRCS} )
0083 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0084     set_target_properties(notesharedprivate PROPERTIES UNITY_BUILD ON)
0085 endif()
0086
0087 generate_export_header(notesharedprivate BASE_NAME noteshared)
0088
0089 target_link_libraries(notesharedprivate
0090     PUBLIC
0091     KPim6::AkonadiCore
0092     PRIVATE
0093     KF6::KCMUtils
0094     KF6::DNSSD KPim6::PimCommon  KPim6::Mime KPim6::AkonadiNotes
0095      KF6::Completion Qt::DBus KF6::I18n
0096     KPim6::AkonadiWidgets
0097     )
0098     target_link_libraries(notesharedprivate PRIVATE KF6::TextAutoCorrectionWidgets)
0099
0100 set_target_properties(notesharedprivate
0101     PROPERTIES VERSION ${KDEPIM_LIB_VERSION} SOVERSION ${KDEPIM_LIB_SOVERSION}
0102     )
0103
0104 install(TARGETS notesharedprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)