kmbox/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 add_library(KPim6Mbox)
0005 add_library(KPim6::Mbox ALIAS KPim6Mbox)
0006
0007 target_sources(KPim6Mbox PRIVATE
0008     mboxentry.cpp
0009     mbox_p.cpp
0010     mbox.cpp
0011     mboxentry.h
0012     mbox.h
0013     mbox_p.h
0014     mboxentry_p.h
0015 )
0016
0017 ecm_qt_declare_logging_category(KPim6Mbox HEADER kmbox_debug.h IDENTIFIER KMBOX_LOG CATEGORY_NAME org.kde.pim.kmbox
0018         OLD_CATEGORY_NAMES log_kmbox
0019         DESCRIPTION "kmbox (pim lib)" EXPORT KMBOX)
0020
0021
0022 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0023     set_target_properties(KPim6Mbox PROPERTIES UNITY_BUILD ON)
0024 endif()
0025
0026 ecm_generate_export_header(KPim6Mbox
0027     BASE_NAME kmbox
0028     VERSION ${KMBOX_VERSION}
0029     DEPRECATED_BASE_VERSION 0
0030     USE_VERSION_HEADER
0031 )
0032 target_include_directories(KPim6Mbox INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KMbox>")
0033 target_include_directories(KPim6Mbox PUBLIC "$<BUILD_INTERFACE:${KMbox_SOURCE_DIR}/src;${KMbox_BINARY_DIR}/src>")
0034
0035 target_link_libraries(KPim6Mbox
0036    PUBLIC
0037     KPim6::Mime
0038 )
0039
0040 set_target_properties(KPim6Mbox PROPERTIES
0041     VERSION ${KMBOX_VERSION}
0042     SOVERSION ${KMBOX_SOVERSION}
0043     EXPORT_NAME Mbox
0044 )
0045
0046 install(TARGETS KPim6Mbox EXPORT KPim6MboxTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0047
0048 ########### Generate Headers ###############
0049 ecm_generate_headers(KMbox_CamelCase_HEADERS
0050   HEADER_NAMES
0051   MBox
0052   MBoxEntry
0053   PREFIX KMbox
0054   REQUIRED_HEADERS KMbox_HEADERS
0055 )
0056
0057 install(FILES
0058     ${KMbox_CamelCase_HEADERS}
0059     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KMbox/KMbox/
0060     COMPONENT Devel
0061 )
0062
0063
0064 install(FILES
0065   ${KMbox_BINARY_DIR}/src/kmbox_export.h
0066   ${KMbox_HEADERS}
0067     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KMbox/kmbox
0068     COMPONENT Devel
0069 )
0070
0071 ecm_qt_install_logging_categories(EXPORT KMBOX FILE kmbox.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0072
0073 if (BUILD_QCH)
0074     ecm_add_qch(
0075         KPim6Mbox_QCH
0076         NAME KMbox
0077         BASE_NAME KPim6Mbox
0078         VERSION ${PIM_VERSION}
0079         ORG_DOMAIN org.kde
0080         SOURCES # using only public headers, to cover only public API
0081             ${KMbox_HEADERS}
0082         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0083         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0084         LINK_QCHS
0085             Qt6Core_QCH
0086         INCLUDE_DIRS
0087             ${CMAKE_CURRENT_BINARY_DIR}
0088         BLANK_MACROS
0089             KMBOX_EXPORT
0090         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0091         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0092         COMPONENT Devel
0093     )
0094 endif()