pim/kmbox/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0005 set(PIM_VERSION "6.0.40")
0006
0007 project(KMbox VERSION ${PIM_VERSION})
0008
0009 # ECM setup
0010 set(KF_MIN_VERSION "5.248.0")
0011 set(QT_REQUIRED_VERSION "6.6.0")
0012 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDECompilerSettings NO_POLICY_SCOPE)
0018
0019 include(ECMGenerateExportHeader)
0020 include(ECMGenerateHeaders)
0021
0022 include(ECMSetupVersion)
0023 include(FeatureSummary)
0024 include(KDEGitCommitHooks)
0025 include(KDEClangFormat)
0026 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0027 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0028
0029 include(ECMQtDeclareLoggingCategory)
0030 include(ECMDeprecationSettings)
0031 include(ECMFeatureSummary)
0032 include(ECMAddQch)
0033
0034 set(KMBOX_LIB_VERSION ${PIM_VERSION})
0035 set(KMIME_LIB_VERSION "6.0.40")
0036
0037 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0038 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0039 ecm_setup_version(PROJECT VARIABLE_PREFIX KMBOX
0040                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/kmbox_version.h"
0041                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6MboxConfigVersion.cmake"
0042                         SOVERSION 6
0043 )
0044
0045 ########### Find packages ###########
0046 find_package(KPim6Mime ${KMIME_LIB_VERSION} CONFIG REQUIRED)
0047
0048 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0049 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.249.0)
0050
0051 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0052
0053 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0054 if (USE_UNITY_CMAKE_SUPPORT)
0055     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0056 endif()
0057
0058 ########### Targets ###########
0059 add_subdirectory(src)
0060
0061 if(BUILD_TESTING)
0062     add_subdirectory(autotests)
0063 endif()
0064
0065 ########### CMake Config Files ###########
0066 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6Mbox")
0067 if (BUILD_QCH)
0068     ecm_install_qch_export(
0069         TARGETS KPim6Mbox_QCH
0070         FILE KPim6MBoxQchTargets.cmake
0071         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0072         COMPONENT Devel
0073     )
0074     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6MBoxQchTargets.cmake\")")
0075 endif()
0076 configure_package_config_file(
0077   "${CMAKE_CURRENT_SOURCE_DIR}/KPimMboxConfig.cmake.in"
0078   "${CMAKE_CURRENT_BINARY_DIR}/KPim6MboxConfig.cmake"
0079   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0080 )
0081
0082 install(FILES
0083   "${CMAKE_CURRENT_BINARY_DIR}/KPim6MboxConfig.cmake"
0084   "${CMAKE_CURRENT_BINARY_DIR}/KPim6MboxConfigVersion.cmake"
0085   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0086   COMPONENT Devel
0087 )
0088
0089 install(EXPORT KPim6MboxTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0090     FILE KPim6MboxTargets.cmake NAMESPACE KPim6::)
0091
0092 install(FILES
0093    ${CMAKE_CURRENT_BINARY_DIR}/src/kmbox_version.h
0094    DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KMbox
0095    COMPONENT Devel
0096 )
0097
0098 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0099 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)