kmailtransport/src/CMakeLists.txt

0001 add_library(KPim6MailTransport)
0002 add_library(KPim6::MailTransport ALIAS KPim6MailTransport)
0003
0004 ecm_setup_version(PROJECT VARIABLE_PREFIX MAILTRANSPORT
0005     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/mailtransport_version.h"
0006     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6MailTransportConfigVersion.cmake"
0007     SOVERSION 6
0008     )
0009
0010 target_sources(KPim6MailTransport PRIVATE
0011     transport.cpp
0012     transportmanager.cpp
0013     transporttype.cpp
0014     transportjob.cpp
0015     precommandjob.cpp
0016     socket.cpp
0017     servertest.cpp
0018     )
0019
0020 target_sources(KPim6MailTransport PRIVATE
0021     widgets/transportconfigwidget.cpp
0022     widgets/transportcombobox.cpp
0023     widgets/transportlistview.cpp
0024     widgets/transportmanagementwidget.cpp
0025     widgets/addtransportdialogng.cpp
0026     )
0027
0028 target_sources(KPim6MailTransport PRIVATE
0029     plugins/transportabstractplugin.cpp
0030     plugins/transportpluginmanager.cpp
0031     )
0032 target_sources(KPim6MailTransport PRIVATE
0033     transporttype_p.h
0034     mailtransport_defs.h
0035     socket.h
0036     precommandjob.h
0037     transport_p.h
0038     transport.h
0039     kmailtransport_private_export.h
0040     plugins/transportpluginmanager.h
0041     plugins/transportabstractplugin.h
0042     widgets/addtransportdialogng.h
0043     widgets/transportcombobox.h
0044     widgets/transportlistview.h
0045     widgets/transportconfigwidget_p.h
0046     widgets/transportconfigwidget.h
0047     widgets/transportmanagementwidget.h
0048     transportjob.h
0049     transportmanager.h
0050     transporttype.h
0051     servertest.h
0052     )
0053
0054 ecm_qt_declare_logging_category(KPim6MailTransport HEADER mailtransport_debug.h IDENTIFIER MAILTRANSPORT_LOG CATEGORY_NAME org.kde.pim.mailtransport
0055         DESCRIPTION "kmailtransport (kmailtransport)"
0056         OLD_CATEGORY_NAMES log_mailtransport
0057         EXPORT MAILTRANSPORT
0058     )
0059
0060 ki18n_wrap_ui(KPim6MailTransport
0061     ui/addtransportdialog.ui
0062     ui/transportmanagementwidget.ui
0063     )
0064
0065 kconfig_add_kcfg_files(KPim6MailTransport GENERATE_MOC transportbase.kcfgc)
0066
0067 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0068     set_target_properties(KPim6MailTransport PROPERTIES UNITY_BUILD ON)
0069 endif()
0070
0071 generate_export_header(KPim6MailTransport BASE_NAME mailtransport)
0072
0073 target_include_directories(KPim6MailTransport INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/MailTransport>")
0074 target_include_directories(KPim6MailTransport PUBLIC "$<BUILD_INTERFACE:${MailTransport_SOURCE_DIR}/src;${MailTransport_BINARY_DIR}/src>")
0075
0076 target_link_libraries(KPim6MailTransport
0077     PUBLIC
0078     KF6::ConfigGui
0079     PRIVATE
0080     KF6::I18n
0081     KF6::WidgetsAddons
0082     KF6::CoreAddons
0083     KF6::ConfigWidgets
0084     Qt::DBus
0085     Qt::Network
0086     )
0087
0088 if (TARGET KF6::Wallet)
0089     target_link_libraries(KPim6MailTransport PRIVATE KF6::Wallet)
0090 endif()
0091
0092 target_link_libraries(KPim6MailTransport PRIVATE qt6keychain)
0093
0094
0095 set_target_properties(KPim6MailTransport PROPERTIES
0096     VERSION ${MAILTRANSPORT_VERSION}
0097     SOVERSION ${MAILTRANSPORT_SOVERSION}
0098     EXPORT_NAME MailTransport
0099     )
0100
0101
0102 install(TARGETS KPim6MailTransport EXPORT KPim6MailTransportTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0103
0104 install(FILES mailtransport.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0105
0106
0107 ecm_generate_headers(MailTransport_CamelCase_HEADERS
0108     HEADER_NAMES
0109     PrecommandJob
0110     ServerTest
0111     Transport
0112     TransportJob
0113     TransportManager
0114     TransportType
0115     PREFIX MailTransport
0116     REQUIRED_HEADERS MailTransport_HEADERS
0117     )
0118
0119 ecm_generate_headers(MailTransport_widgets_CamelCase_HEADERS
0120     HEADER_NAMES
0121     TransportComboBox
0122     TransportManagementWidget
0123     TransportConfigWidget
0124     PREFIX MailTransport
0125     REQUIRED_HEADERS MailTransport_widgets_HEADERS
0126     RELATIVE widgets
0127     )
0128
0129 ecm_generate_headers(MailTransport_plugins_CamelCase_HEADERS
0130     HEADER_NAMES
0131     TransportAbstractPlugin
0132     PREFIX MailTransport
0133     REQUIRED_HEADERS MailTransport_plugins_HEADERS
0134     RELATIVE plugins
0135     )
0136
0137 install(FILES
0138     ${MailTransport_SOURCE_DIR}/src/widgets/transportconfigwidget_p.h
0139     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MailTransport/mailtransport/private COMPONENT Devel )
0140
0141 install(FILES
0142     ${MailTransport_CamelCase_HEADERS}
0143     ${MailTransport_widgets_CamelCase_HEADERS}
0144     ${MailTransport_plugins_CamelCase_HEADERS}
0145     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MailTransport/MailTransport/ COMPONENT Devel )
0146
0147 install(FILES
0148     ${CMAKE_CURRENT_BINARY_DIR}/mailtransport_export.h
0149     ${MailTransport_HEADERS}
0150     ${MailTransport_widgets_HEADERS}
0151     ${MailTransport_plugins_HEADERS}
0152     ${CMAKE_CURRENT_BINARY_DIR}/transportbase.h
0153
0154     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MailTransport/mailtransport COMPONENT Devel
0155     )
0156
0157
0158 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6MailTransport")
0159
0160 install(FILES
0161     ${CMAKE_CURRENT_BINARY_DIR}/mailtransport_version.h
0162     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MailTransport COMPONENT Devel
0163     )
0164
0165
0166 if(BUILD_TESTING)
0167     add_subdirectory(tests)
0168     add_subdirectory(plugins/tests)
0169 endif()
0170
0171 if (BUILD_QCH)
0172     ecm_add_qch(
0173         KPim6MailTransport_QCH
0174         NAME KMailTransport
0175         BASE_NAME KPim6MailTransport
0176         VERSION ${PIM_VERSION}
0177         ORG_DOMAIN org.kde
0178         SOURCES # using only public headers, to cover only public API
0179             ${MailTransport_HEADERS}
0180             ${MailTransport_widgets_HEADERS}
0181             ${MailTransport_plugins_HEADERS}
0182         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0183         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0184         LINK_QCHS
0185             Qt6Core_QCH
0186             Qt6Gui_QCH
0187             Qt6Widgets_QCH
0188         INCLUDE_DIRS
0189             ${CMAKE_CURRENT_BINARY_DIR}
0190         BLANK_MACROS
0191             MAILTRANSPORT_EXPORT
0192         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0193         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0194         COMPONENT Devel
0195     )
0196 endif()
0197 if (BUILD_QCH)
0198     ecm_install_qch_export(
0199         TARGETS KPim6MailTransport_QCH
0200         FILE KPim6MailTransportQchTargets.cmake
0201         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0202         COMPONENT Devel
0203     )
0204     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6MailTransportQchTargets.cmake\")")
0205 endif()
0206
0207
0208 configure_package_config_file(
0209     "${CMAKE_CURRENT_SOURCE_DIR}/KPimMailTransportConfig.cmake.in"
0210     "${CMAKE_CURRENT_BINARY_DIR}/KPim6MailTransportConfig.cmake"
0211     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0212     )
0213
0214 install(FILES
0215     "${CMAKE_CURRENT_BINARY_DIR}/KPim6MailTransportConfig.cmake"
0216     "${CMAKE_CURRENT_BINARY_DIR}/KPim6MailTransportConfigVersion.cmake"
0217     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0218     COMPONENT Devel
0219     )
0220
0221 install(EXPORT KPim6MailTransportTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6MailTransportTargets.cmake NAMESPACE KPim6::)
0222
0223 add_subdirectory(plugins/smtp)