agents/mailfilteragent/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 add_definitions(-DTRANSLATION_DOMAIN=\"akonadi_mailfilter_agent\")
0005
0006 add_library(mailfilteragentprivate)
0007
0008
0009 target_sources(mailfilteragentprivate PRIVATE
0010     filterlogdialog.cpp
0011     filterlogdialog.h
0012     mailfilterpurposemenuwidget.cpp
0013     mailfilterpurposemenuwidget.h
0014
0015     mailfilteragent_private_export.h
0016 )
0017
0018 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0019     set_target_properties(mailfilteragentprivate PROPERTIES UNITY_BUILD ON)
0020 endif()
0021
0022 generate_export_header(mailfilteragentprivate BASE_NAME mailfilteragentprivate)
0023 target_link_libraries(mailfilteragentprivate
0024     KF6::I18n
0025     Qt::Widgets
0026     KF6::TextCustomEditor
0027     KPim6::PimCommon
0028     KPim6::MailCommon
0029 )
0030
0031 set_target_properties(mailfilteragentprivate
0032     PROPERTIES OUTPUT_NAME mailfilteragentprivate VERSION ${KDEPIM_LIB_VERSION} SOVERSION ${KDEPIM_LIB_SOVERSION}
0033 )
0034 install(TARGETS mailfilteragentprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
0035
0036
0037 add_executable(akonadi_mailfilter_agent)
0038 set(dbusobjectmanager_xml org.freedesktop.Akonadi.MailFilterAgent.xml)
0039 set_source_files_properties(${dbusobjectmanager_xml} PROPERTIES INCLUDE "dbusoperators.h")
0040 qt_add_dbus_adaptor(akonadi_mailfilter_agent_SRCS ${dbusobjectmanager_xml} mailfilteragent.h MailFilterAgent)
0041
0042 target_sources(akonadi_mailfilter_agent PRIVATE
0043     dummykernel.cpp
0044     filtermanager.cpp
0045     mailfilteragent.cpp
0046     dummykernel.h
0047     filtermanager.h
0048     mailfilteragent.h
0049     ${akonadi_mailfilter_agent_SRCS}
0050     )
0051
0052
0053
0054 ecm_qt_declare_logging_category(akonadi_mailfilter_agent HEADER mailfilteragent_debug.h IDENTIFIER MAILFILTERAGENT_LOG CATEGORY_NAME org.kde.pim.mailfilteragent
0055         DESCRIPTION "kmail (mailfilter agent)"
0056         OLD_CATEGORY_NAMES log_mailfilteragent
0057         EXPORT KMAIL
0058     )
0059
0060
0061 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0062     set_target_properties(akonadi_mailfilter_agent PROPERTIES UNITY_BUILD ON)
0063 endif()
0064
0065 if( APPLE )
0066     set_target_properties(akonadi_mailfilter_agent PROPERTIES MACOSX_BUNDLE_INFO_PLIST ${kmail_SOURCE_DIR}/agents/Info.plist.template)
0067     set_target_properties(akonadi_mailfilter_agent PROPERTIES MACOSX_BUNDLE_GUI_IDENTIFIER "org.kde.Akonadi.mailfilter")
0068     set_target_properties(akonadi_mailfilter_agent PROPERTIES MACOSX_BUNDLE_BUNDLE_NAME "KDE Akonadi Email Filter")
0069 endif ()
0070
0071
0072 target_link_libraries(akonadi_mailfilter_agent
0073     KPim6::MailCommon
0074     KPim6::MessageComposer
0075     KPim6::PimCommon
0076     KPim6::AkonadiCore
0077     KPim6::AkonadiMime
0078     KPim6::AkonadiAgentBase
0079     KPim6::Mime
0080     KPim6::IdentityManagementCore
0081     KF6::DBusAddons
0082     KF6::Notifications
0083     KF6::WindowSystem
0084     KF6::I18n
0085     mailfilteragentprivate
0086     )
0087
0088 install(TARGETS akonadi_mailfilter_agent ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0089 install(FILES mailfilteragent.desktop DESTINATION "${KDE_INSTALL_DATAROOTDIR}/akonadi/agents")
0090 install(FILES akonadi_mailfilter_agent.notifyrc DESTINATION ${KDE_INSTALL_KNOTIFYRCDIR} )
0091
0092 add_subdirectory(tests)