src/widgets/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 ecm_setup_version(PROJECT VARIABLE_PREFIX KLDAPWIDGETS
0005                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kldap_widgets_version.h"
0006                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6LdapWidgetsConfigVersion.cmake"
0007                         SOVERSION 6
0008 )
0009
0010 add_library(KPim6LdapWidgets)
0011 add_library(KPim6::LdapWidgets ALIAS KPim6LdapWidgets)
0012
0013 target_sources(KPim6LdapWidgets PRIVATE
0014   ldapconfigwidget.cpp
0015   addhostdialog.cpp
0016   ldapclient.cpp
0017   ldapclientsearch.cpp
0018   ldapclientsearchconfig.cpp
0019   ldapconfigurewidget.cpp
0020   ldapclientsearchconfigreadconfigjob.cpp
0021   ldapclientsearchconfigwriteconfigjob.cpp
0022   ldapwidgetitem_p.cpp
0023   ldapwidgetitemreadconfigserverjob.cpp
0024   ldapsearchclientreadconfigserverjob.cpp
0025
0026   ldapclientsearchconfig.h
0027   ldapclientsearchconfigreadconfigjob.h
0028   ldapclient.h
0029   addhostdialog.h
0030   ldapwidgetitem_p.h
0031   ldapconfigwidget.h
0032   ldapclientsearch.h
0033   ldapclientsearchconfigwriteconfigjob.h
0034   ldapconfigurewidget.h
0035   ldapsearchclientreadconfigserverjob.h
0036   ldapwidgetitemreadconfigserverjob.h
0037    )
0038
0039 ecm_qt_declare_logging_category(KPim6LdapWidgets HEADER ldap_widgets_debug.h IDENTIFIER LDAP_LOG CATEGORY_NAME org.kde.pim.ldap.widgets
0040         DESCRIPTION "kldap widgets (kldap)"
0041         OLD_CATEGORY_NAMES log_ldap_widgets
0042         EXPORT KLDAP
0043     )
0044
0045 ecm_qt_declare_logging_category(KPim6LdapWidgets HEADER ldapclient_debug.h IDENTIFIER LDAPCLIENT_LOG CATEGORY_NAME org.kde.pim.ldapclient
0046         DESCRIPTION "ldapclient (kldap)"
0047         OLD_CATEGORY_NAMES log_ldapclient
0048         EXPORT KLDAP
0049     )
0050
0051 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0052         set_target_properties(KPim6LdapWidgets PROPERTIES UNITY_BUILD ON)
0053 endif()
0054 generate_export_header(KPim6LdapWidgets BASE_NAME kldapwidgets)
0055
0056
0057
0058 target_link_libraries(KPim6LdapWidgets
0059 PUBLIC
0060         KPim6::LdapCore
0061 PRIVATE
0062   Qt::Widgets
0063   KF6::I18n
0064   KF6::WidgetsAddons
0065   KF6::ConfigCore
0066   KF6::CoreAddons
0067   KF6::KIOCore
0068   KF6::ConfigGui
0069 )
0070
0071 target_link_libraries(KPim6LdapWidgets PRIVATE qt6keychain)
0072
0073 target_include_directories(KPim6LdapWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KLDAPWidgets>")
0074 target_include_directories(KPim6LdapWidgets PUBLIC "$<BUILD_INTERFACE:${KLdap_SOURCE_DIR}/src/widgets;${KLdap_BINARY_DIR}/src>")
0075
0076 set_target_properties(KPim6LdapWidgets PROPERTIES
0077         VERSION ${KLDAPWIDGETS_VERSION}
0078         SOVERSION ${KLDAPWIDGETS_SOVERSION}
0079         EXPORT_NAME LdapWidgets
0080 )
0081
0082 install(TARGETS KPim6LdapWidgets EXPORT KPim6LdapWidgetsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0083
0084 ########### install files ###############
0085
0086 ecm_generate_headers(KLdapWidgets_CamelCase_HEADERS
0087   HEADER_NAMES
0088   LdapConfigWidget
0089   LdapClientSearchConfig
0090   LdapClientSearch
0091   AddHostDialog
0092   LdapClient
0093   LdapConfigureWidget
0094   LdapClientSearchConfigWriteConfigJob
0095   LdapClientSearchConfigReadConfigJob
0096   LdapSearchClientReadConfigServerJob
0097   PREFIX KLDAPWidgets
0098   REQUIRED_HEADERS KLdapWidgets_HEADERS
0099 )
0100
0101 install(FILES
0102     ${CMAKE_CURRENT_BINARY_DIR}/kldapwidgets_export.h
0103     ${KLdapWidgets_HEADERS}
0104     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KLDAPWidgets/kldapwidgets
0105     COMPONENT Devel
0106 )
0107
0108 install(FILES
0109     ${KLdapWidgets_CamelCase_HEADERS}
0110     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KLDAPWidgets/KLDAPWidgets/
0111     COMPONENT Devel
0112 )
0113
0114 install(FILES
0115    ${CMAKE_CURRENT_BINARY_DIR}/kldap_widgets_version.h
0116    DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KLDAPWidgets
0117    COMPONENT Devel
0118 )
0119
0120
0121 if (BUILD_QCH)
0122     ecm_add_qch(
0123             KPim6LdapWidgets_QCH
0124             NAME KLdapWidgets
0125         BASE_NAME KPim6LdapWidgets
0126         VERSION ${PIM_VERSION}
0127         ORG_DOMAIN org.kde
0128
0129         SOURCES # using only public headers, to cover only public API
0130             ${KLdapWidgets_HEADERS}
0131         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0132         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0133         LINK_QCHS
0134             Qt6Core_QCH
0135             Qt6Gui_QCH
0136             Qt6Widgets_QCH
0137         INCLUDE_DIRS
0138             ${CMAKE_CURRENT_BINARY_DIR}
0139         BLANK_MACROS
0140             KLDAPWIDGETS_EXPORT
0141         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0142         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0143         COMPONENT Devel
0144     )
0145 endif()
0146
0147 if(BUILD_TESTING)
0148     add_subdirectory(tests)
0149     add_subdirectory(autotests)
0150 endif()
0151
0152 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6LdapWidgets")
0153
0154 install(EXPORT KPim6LdapWidgetsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6LdapWidgetsTargets.cmake NAMESPACE KPim6::)
0155
0156
0157 if (BUILD_QCH)
0158     ecm_install_qch_export(
0159             TARGETS KPim6LdapWidgets_QCH
0160             FILE KPim6LdapWidgetsQchTargets.cmake
0161         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0162         COMPONENT Devel
0163     )
0164     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6LdapWidgetsQchTargets.cmake\")")
0165 endif()
0166
0167
0168 configure_package_config_file(
0169         "${CMAKE_CURRENT_SOURCE_DIR}/KPimLdapWidgetsConfig.cmake.in"
0170         "${CMAKE_CURRENT_BINARY_DIR}/KPim6LdapWidgetsConfig.cmake"
0171   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0172 )
0173
0174 install(FILES
0175         "${CMAKE_CURRENT_BINARY_DIR}/KPim6LdapWidgetsConfig.cmake"
0176         "${CMAKE_CURRENT_BINARY_DIR}/KPim6LdapWidgetsConfigVersion.cmake"
0177   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0178   COMPONENT Devel
0179 )
0180