kjots/src/CMakeLists.txt

0001
0002 add_subdirectory(noteshared)
0003
0004 add_subdirectory(kontact_plugin)
0005
0006 add_definitions(-DTRANSLATION_DOMAIN=\"kjots\")
0007
0008 configure_file(kjots-version.h.in
0009                ${CMAKE_CURRENT_BINARY_DIR}/kjots-version.h
0010                @ONLY
0011 )
0012
0013 #########################################################################
0014 # Code common to the kjots application and the kontact plugin
0015 # Don't make it a static library, this code needs to be compiled
0016 # with -fPIC for the part and without -fPIC for the executable
0017 #########################################################################
0018
0019 set(kjots_config_SRCS kjotsconfigdlg.cpp kjotsconfigdlg.h)
0020 kconfig_add_kcfg_files(kjots_config_SRCS KJotsSettings.kcfgc )
0021 ki18n_wrap_ui(kjots_config_SRCS confpagemisc.ui)
0022
0023 set(kjots_common_SRCS
0024   aboutdata.cpp
0025   kjotsedit.cpp
0026   kjotsbookmarks.cpp
0027   kjotsmodel.cpp
0028   kjotswidget.cpp
0029   kjotsbrowser.cpp
0030   kjotslinkdialog.cpp
0031   notesortproxymodel.cpp
0032   uistatesaver.cpp
0033   aboutdata.h
0034   kjotsedit.h
0035   kjotsbookmarks.h
0036   kjotsmodel.h
0037   kjotswidget.h
0038   kjotsbrowser.h
0039   kjotslinkdialog.h
0040   notesortproxymodel.h
0041   uistatesaver.h
0042   ${kjots_config_SRCS}
0043 )
0044 ki18n_wrap_ui(kjots_common_SRCS linkdialog.ui)
0045
0046 add_library(kjots_common STATIC ${kjots_common_SRCS})
0047 set_property(TARGET kjots_common PROPERTY POSITION_INDEPENDENT_CODE ON)
0048 target_link_libraries(kjots_common
0049     KF${KF_MAJOR_VERSION}::KCMUtils
0050
0051   noteshared
0052   Qt::DBus
0053   Qt::PrintSupport
0054   KF${KF_MAJOR_VERSION}::Bookmarks
0055   KF${KF_MAJOR_VERSION}::TextWidgets
0056   KPim${KF_MAJOR_VERSION}::Mime
0057   KPim${KF_MAJOR_VERSION}::AkonadiCore
0058   KPim${KF_MAJOR_VERSION}::AkonadiWidgets
0059   KPim${KF_MAJOR_VERSION}::PimTextEdit
0060   KF${KF_MAJOR_VERSION}::XmlGui
0061   KF${KF_MAJOR_VERSION}::KIOWidgets
0062   ${MAIN_LIB}
0063 )
0064 if (TARGET KF${KF_MAJOR_VERSION}::TextEditTextToSpeech)
0065     target_link_libraries(kjots_common KF${KF_MAJOR_VERSION}::TextEditTextToSpeech)
0066 endif()
0067 if (TARGET KF${KF_MAJOR_VERSION}::TextAddonsWidgets)
0068     target_link_libraries(kjots_common KF${KF_MAJOR_VERSION}::TextAddonsWidgets)
0069 endif()
0070 if (TARGET KF${KF_MAJOR_VERSION}::TextCustomEditor)
0071     target_link_libraries(kjots_common KF${KF_MAJOR_VERSION}::TextCustomEditor)
0072 endif()
0073 if (QT_MAJOR_VERSION STREQUAL "6")
0074     target_link_libraries(kjots_common KF6::BookmarksWidgets)
0075 endif()
0076
0077 #########################################################################
0078 # D-Bus interface
0079 #########################################################################
0080
0081 qt_generate_dbus_interface( kjotswidget.h org.kde.KJotsWidget.xml OPTIONS -m )
0082 qt_add_dbus_interfaces(kjots_common_SRCS
0083     ${CMAKE_CURRENT_BINARY_DIR}/org.kde.KJotsWidget.xml)
0084
0085
0086 #########################################################################
0087 # Main Application SECTION
0088 #########################################################################
0089
0090 set(kjots_SRCS
0091    main.cpp
0092    KJotsMain.cpp
0093    KJotsMain.h
0094    kjots.qrc
0095 )
0096
0097 file(GLOB ICONS_SRCS "${CMAKE_SOURCE_DIR}/icons/*-apps-kjots.png")
0098 ecm_add_app_icon(kjots_SRCS ICONS ${ICONS_SRCS})
0099
0100 add_executable(kjots ${kjots_SRCS})
0101
0102 target_link_libraries(kjots
0103   kjots_common
0104   KPim${KF_MAJOR_VERSION}::KontactInterface
0105 )
0106
0107 install(TARGETS kjots ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0108
0109 install(FILES kjots.kcfg
0110         DESTINATION ${KDE_INSTALL_KCFGDIR}
0111 )
0112
0113 ############## next target ##############
0114
0115 set(kjotspart_PART_SRCS
0116   kjotspart.cpp
0117   kjotspart.h
0118 )
0119
0120 add_library(kjotspart MODULE ${kjotspart_PART_SRCS})
0121
0122 target_link_libraries(kjotspart
0123   kjots_common
0124   KF${KF_MAJOR_VERSION}::Parts
0125 )
0126
0127 install(TARGETS kjotspart
0128         DESTINATION ${KDE_INSTALL_PLUGINDIR}
0129 )
0130
0131 ###########################################################################
0132
0133 set(kcm_kjots_PART_SRCS
0134     kcm_kjots.cpp
0135     ${kjots_config_SRCS}
0136 )
0137
0138 add_library(kcm_kjots MODULE ${kcm_kjots_PART_SRCS})
0139
0140 target_link_libraries(kcm_kjots
0141     KF${KF_MAJOR_VERSION}::KCMUtils
0142     KF${KF_MAJOR_VERSION}::I18n
0143 )
0144
0145 install(TARGETS kcm_kjots
0146         DESTINATION ${KDE_INSTALL_PLUGINDIR}
0147 )