pim/kjots/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002 project(kjots)
0003
0004 set(KF_VERSION "5.103.0")
0005 find_package(ECM ${KF_VERSION} REQUIRED NO_MODULE)
0006 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules ${ECM_MODULE_PATH})
0007 set(CMAKE_CXX_STANDARD 17)
0008 include(ECMAddTests)
0009 include(CMakePackageConfigHelpers)
0010 include(FeatureSummary)
0011 include(KDEInstallDirs)
0012 include(KDECMakeSettings)
0013 include(KDECompilerSettings NO_POLICY_SCOPE)
0014 include(ECMInstallIcons)
0015 include(ECMQtDeclareLoggingCategory)
0016 include(ECMAddAppIcon)
0017 include(ECMDeprecationSettings)
0018
0019 set(KJOTS_VERSION "5.1.2")
0020
0021 set(AKONADINOTES_LIB_VERSION "5.22.80")
0022 set(KDEPIMLIBS_LIB_VERSION "5.22.80")
0023 set(KMIME_LIB_VERSION "5.22.80")
0024 set(KPIMTEXTEDIT_LIB_VERSION "5.22.80")
0025 set(KONTACTINTERFACE_LIB_VERSION "5.22.80")
0026
0027 #Qt Packages
0028 set(QT_REQUIRED_VERSION "5.15.2")
0029 if (QT_MAJOR_VERSION STREQUAL "6")
0030     set(QT_REQUIRED_VERSION "6.6.0")
0031     set(KF_MIN_VERSION "5.240.0")
0032     set(KF_MAJOR_VERSION "6")
0033     set(KTEXTADDONS_MIN_VERSION "1.5.0")
0034 else()
0035     set(KF_MAJOR_VERSION "5")
0036     set(KTEXTADDONS_MIN_VERSION "1.5.0")
0037 endif()
0038 find_package(Qt${QT_MAJOR_VERSION} ${QT_REQUIRED_VERSION} CONFIG REQUIRED DBus PrintSupport)
0039
0040 # KF5 Packages
0041 find_package(KF${KF_MAJOR_VERSION}KCMUtils ${KF_VERSION} CONFIG REQUIRED)
0042 find_package(KF${KF_MAJOR_VERSION}KIO ${KF_VERSION} CONFIG REQUIRED)
0043 find_package(KF${KF_MAJOR_VERSION}Config ${KF_VERSION} CONFIG REQUIRED)
0044 find_package(KF${KF_MAJOR_VERSION}I18n ${KF_VERSION} CONFIG REQUIRED)
0045 find_package(KF${KF_MAJOR_VERSION}Parts ${KF_VERSION} CONFIG REQUIRED)
0046 find_package(KF${KF_MAJOR_VERSION}Bookmarks ${KF_VERSION} CONFIG REQUIRED)
0047 find_package(KF${KF_MAJOR_VERSION}XmlGui ${KF_VERSION} CONFIG REQUIRED)
0048 if (QT_MAJOR_VERSION STREQUAL "6")
0049 find_package(KF${KF_MAJOR_VERSION}TextWidgets ${KF_VERSION} CONFIG REQUIRED)
0050 endif()
0051
0052 # PIM packages
0053 find_package(KPim${KF_MAJOR_VERSION}Akonadi ${KDEPIMLIBS_LIB_VERSION} CONFIG REQUIRED)
0054 find_package(KPim${KF_MAJOR_VERSION}Mime ${KMIME_LIB_VERSION} CONFIG REQUIRED)
0055 find_package(KPim${KF_MAJOR_VERSION}AkonadiNotes ${AKONADINOTES_LIB_VERSION} CONFIG REQUIRED)
0056 find_package(KPim${KF_MAJOR_VERSION}TextEdit ${KPIMTEXTEDIT_LIB_VERSION} CONFIG REQUIRED)
0057 find_package(KPim${KF_MAJOR_VERSION}KontactInterface ${KONTACTINTERFACE_LIB_VERSION} CONFIG REQUIRED)
0058 set(GRANTLEE_VERSION "5.3")
0059 if (QT_MAJOR_VERSION STREQUAL "5")
0060     find_package(Grantlee5 ${GRANTLEE_VERSION} CONFIG REQUIRED)
0061     set(MAIN_LIB Grantlee5::Templates Grantlee5::TextDocument)
0062 else()
0063     find_package(KF6TextCustomEditor ${KTEXTADDONS_MIN_VERSION} CONFIG REQUIRED)
0064     find_package(KF6TextAddonsWidgets ${KTEXTADDONS_MIN_VERSION} CONFIG REQUIRED)
0065     find_package(KF6TextTemplate CONFIG REQUIRED)
0066     set(MAIN_LIB KF6::TextTemplate)
0067 endif()
0068
0069 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0070 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.248.0)
0071
0072 find_package(KF${KF_MAJOR_VERSION}TextEditTextToSpeech ${KTEXTADDONS_MIN_VERSION} CONFIG)
0073 set_package_properties(KF${KF_MAJOR_VERSION}TextEditTextToSpeech PROPERTIES DESCRIPTION
0074     "Add support for text to speech"
0075     TYPE OPTIONAL
0076 )
0077 if (TARGET KF${KF_MAJOR_VERSION}::TextEditTextToSpeech)
0078     add_definitions(-DHAVE_TEXT_TO_SPEECH_SUPPORT)
0079 endif()
0080 ##################### Definitions #####################
0081 add_definitions(-DQT_NO_KEYWORDS)
0082 add_definitions(-DQT_NO_CAST_FROM_ASCII)
0083
0084 ##################### Targets #######################
0085
0086 add_subdirectory(src)
0087 add_subdirectory(icons)
0088
0089 ##################### Translations ##################
0090
0091 ki18n_install(po)
0092
0093 ##################### Install ######################
0094
0095 install(DIRECTORY themes
0096         DESTINATION ${KDE_INSTALL_DATADIR}/kjots
0097 )
0098
0099 install(FILES data/org.kde.kjots.appdata.xml
0100         DESTINATION ${KDE_INSTALL_METAINFODIR}
0101 )
0102 install(FILES data/org.kde.kjots.desktop
0103         DESTINATION ${KDE_INSTALL_APPDIR}
0104 )
0105 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)