pim/kimap2/CMakeLists.txt

0001 cmake_minimum_required(VERSION 2.8.12)
0002
0003 project(KIMAP2)
0004
0005 # ECM setup
0006 find_package(ECM 5.19.0 CONFIG REQUIRED)
0007 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${KIMAP2_SOURCE_DIR}/cmake)
0008
0009 include(KDEInstallDirs)
0010 include(KDECMakeSettings)
0011 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0012 include(GenerateExportHeader)
0013 include(ECMGenerateHeaders)
0014 include(ECMGeneratePriFile)
0015 include(ECMPackageConfigHelpers)
0016 include(ECMSetupVersion)
0017 include(FeatureSummary)
0018 include(ECMQtDeclareLoggingCategory)
0019 include(ECMCoverageOption)
0020
0021 set(KIMAP2_LIB_VERSION "0.4.0")
0022 ecm_setup_version(${KIMAP2_LIB_VERSION} VARIABLE_PREFIX KIMAP2
0023                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kimap2_version.h"
0024                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KIMAP2ConfigVersion.cmake"
0025                         SOVERSION 0
0026 )
0027
0028 ########### Find packages ###########
0029 set(KF5CoreAddons_VERSION "5.19.0")
0030 set(KF5Mime_VERSION "5.1.40")
0031
0032 find_package(Qt5 5.2 COMPONENTS REQUIRED Core Network)
0033 find_package(KF5CoreAddons ${KF5CoreAddons_VERSION} CONFIG REQUIRED)
0034 find_package(KF5Codecs "5.19.0" CONFIG REQUIRED)
0035 find_package(KF5Mime ${KF5Mime_VERSION} CONFIG REQUIRED)
0036
0037 find_package(Sasl2)
0038 set_package_properties(Sasl2 PROPERTIES
0039                              DESCRIPTION "The Cyrus-sasl library"
0040                              URL "http://www.cyrussasl.org"
0041                              TYPE REQUIRED
0042 )
0043
0044 ########### CMake Config Files ###########
0045 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KIMAP2")
0046
0047 ecm_configure_package_config_file(
0048   "${CMAKE_CURRENT_SOURCE_DIR}/KIMAP2Config.cmake.in"
0049   "${CMAKE_CURRENT_BINARY_DIR}/KIMAP2Config.cmake"
0050   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0051 )
0052
0053 ########### Targets ###########
0054 add_subdirectory(src)
0055
0056 if(BUILD_TESTING)
0057     add_subdirectory(autotests)
0058     add_subdirectory(tests)
0059 endif()
0060
0061 add_subdirectory(cmake)
0062
0063 ########### Install Files ###########
0064 install(FILES
0065   "${CMAKE_CURRENT_BINARY_DIR}/KIMAP2Config.cmake"
0066   "${CMAKE_CURRENT_BINARY_DIR}/KIMAP2ConfigVersion.cmake"
0067   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0068   COMPONENT Devel
0069 )
0070
0071 install(EXPORT KIMAP2Targets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KIMAP2Targets.cmake)
0072
0073 install(FILES
0074    ${CMAKE_CURRENT_BINARY_DIR}/kimap2_version.h
0075   DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel
0076 )
0077
0078 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)