pim/kimap/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0005 set(PIM_VERSION "6.0.41")
0006
0007 project(KIMAP VERSION ${PIM_VERSION})
0008
0009
0010 # ECM setup
0011 set(KF_MIN_VERSION "5.248.0")
0012 set(QT_REQUIRED_VERSION "6.6.0")
0013
0014 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0015 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0016
0017 include(KDEInstallDirs)
0018 include(KDECMakeSettings)
0019 include(KDECompilerSettings NO_POLICY_SCOPE)
0020
0021 include(ECMGenerateExportHeader)
0022 include(ECMGenerateHeaders)
0023
0024 include(ECMSetupVersion)
0025 include(FeatureSummary)
0026 include(KDEGitCommitHooks)
0027 include(KDEClangFormat)
0028 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0029 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0030
0031 include(ECMQtDeclareLoggingCategory)
0032 include(ECMDeprecationSettings)
0033 include(ECMFeatureSummary)
0034 include(ECMAddQch)
0035
0036 set(KIMAP_LIB_VERSION ${PIM_VERSION})
0037 set(KMIME_LIBS_VERSION "6.0.40")
0038 ecm_setup_version(PROJECT VARIABLE_PREFIX KIMAP
0039                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/kimap_version.h"
0040                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6IMAPConfigVersion.cmake"
0041                         SOVERSION 6
0042 )
0043
0044 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0045 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0046 ########### Find packages ###########
0047 find_package(Sasl2)
0048 set_package_properties(Sasl2 PROPERTIES TYPE REQUIRED)
0049 find_package(KF6CoreAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0050 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0051 find_package(KF6KIO ${KF_MIN_VERSION} CONFIG REQUIRED)
0052 find_package(KPim6Mime ${KMIME_LIBS_VERSION} CONFIG REQUIRED)
0053
0054 ########### CMake Config Files ###########
0055 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6IMAP")
0056 add_definitions(-DTRANSLATION_DOMAIN=\"libkimap6\")
0057
0058 ecm_set_disabled_deprecation_versions(QT 6.6
0059      KF 5.249.0
0060 )
0061 add_definitions(-DQT_NO_EMIT)
0062
0063 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0064
0065 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0066 if (USE_UNITY_CMAKE_SUPPORT)
0067     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0068 endif()
0069
0070 ########### Targets ###########
0071 add_subdirectory(src)
0072
0073 if(BUILD_TESTING)
0074     find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Test)
0075     add_subdirectory(autotests)
0076     add_subdirectory(tests)
0077 endif()
0078
0079 ########### Install Files ###########
0080
0081
0082
0083 install(FILES
0084   "${CMAKE_CURRENT_BINARY_DIR}/KPim6IMAPConfig.cmake"
0085   "${CMAKE_CURRENT_BINARY_DIR}/KPim6IMAPConfigVersion.cmake"
0086   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0087   COMPONENT Devel
0088 )
0089
0090 install(EXPORT KPim6IMAPTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6IMAPTargets.cmake NAMESPACE KPim6::)
0091
0092 install(FILES
0093    ${CMAKE_CURRENT_BINARY_DIR}/src/kimap_version.h
0094   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KIMAP/ COMPONENT Devel
0095 )
0096
0097 if (BUILD_QCH)
0098     ecm_install_qch_export(
0099         TARGETS KPim6Imap_QCH
0100         FILE KPim6ImapQchTargets.cmake
0101         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0102         COMPONENT Devel
0103     )
0104     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6ImapQchTargets.cmake\")")
0105 endif()
0106
0107 configure_package_config_file(
0108   "${CMAKE_CURRENT_SOURCE_DIR}/KPimIMAPConfig.cmake.in"
0109   "${CMAKE_CURRENT_BINARY_DIR}/KPim6IMAPConfig.cmake"
0110   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0111 )
0112
0113 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0114 ki18n_install(po)
0115 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)