src/widgets/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004
0005 ecm_setup_version(PROJECT VARIABLE_PREFIX KIDENTITYMANAGEMENTWIDGETS
0006                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kidentitymanagementwidgets_version.h"
0007                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6IdentityManagementWidgetsConfigVersion.cmake"
0008                         SOVERSION 6
0009 )
0010
0011
0012 add_library(KPim6IdentityManagementWidgets)
0013 add_library(KPim6::IdentityManagementWidgets ALIAS KPim6IdentityManagementWidgets)
0014 set_target_properties(KPim6IdentityManagementWidgets PROPERTIES
0015     VERSION ${KIDENTITYMANAGEMENTWIDGETS_VERSION}
0016     SOVERSION ${KIDENTITYMANAGEMENTWIDGETS_SOVERSION}
0017     EXPORT_NAME IdentityManagementWidgets
0018 )
0019
0020 target_sources(KPim6IdentityManagementWidgets PRIVATE
0021   identitycombo.cpp
0022   signatureconfigurator.cpp
0023   signaturerichtexteditor.cpp
0024   signaturerichtexteditor_p.h
0025   identitycombo.h
0026   signatureconfigurator.h
0027 )
0028
0029 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0030     set_target_properties(KPim6IdentityManagementWidgets PROPERTIES UNITY_BUILD ON)
0031 endif()
0032
0033 generate_export_header(KPim6IdentityManagementWidgets BASE_NAME kidentitymanagementwidgets)
0034
0035 target_include_directories(KPim6IdentityManagementWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KIdentityManagementWidgets>")
0036 target_include_directories(KPim6IdentityManagementWidgets PUBLIC "$<BUILD_INTERFACE:${KIdentityManagement_SOURCE_DIR}/src;${KIdentityManagement_BINARY_DIR}/src>")
0037
0038 target_link_libraries(KPim6IdentityManagementWidgets
0039 PUBLIC
0040   KPim6IdentityManagementCore
0041   Qt::Widgets
0042 PRIVATE
0043   KF6::CoreAddons
0044   KPim6::PimTextEdit
0045   KF6::Codecs
0046   Qt::Network
0047   KF6::I18n
0048   KF6::WidgetsAddons
0049   KF6::XmlGui
0050   KF6::KIOWidgets
0051   KF6::ConfigCore
0052   KF6::TextCustomEditor
0053 )
0054
0055 ########### CMake Config Files ###########
0056 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6IdentityManagementWidgets")
0057
0058
0059 install(FILES
0060   "${CMAKE_CURRENT_BINARY_DIR}/KPim6IdentityManagementWidgetsConfig.cmake"
0061   "${CMAKE_CURRENT_BINARY_DIR}/KPim6IdentityManagementWidgetsConfigVersion.cmake"
0062   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0063   COMPONENT Devel
0064 )
0065
0066 install(EXPORT KPim6IdentityManagementWidgetsTargets
0067     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0068     FILE KPim6IdentityManagementWidgetsTargets.cmake
0069     NAMESPACE KPim6::
0070 )
0071
0072 install(FILES
0073    ${CMAKE_CURRENT_BINARY_DIR}/kidentitymanagementwidgets_version.h
0074    DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KIdentityManagementWidgets
0075    COMPONENT Devel
0076 )
0077
0078
0079
0080 install(TARGETS KPim6IdentityManagementWidgets EXPORT KPim6IdentityManagementWidgetsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0081
0082 ########### Generate Headers ###############
0083 ecm_generate_headers(KIdentityManagementWidgets_CamelCase_HEADERS
0084   HEADER_NAMES
0085   IdentityCombo
0086   SignatureConfigurator
0087   PREFIX KIdentityManagementWidgets
0088   REQUIRED_HEADERS KIdentityManagementWidgets_HEADERS
0089 )
0090
0091 ########### install files ###############
0092
0093 install(FILES
0094   ${CMAKE_CURRENT_BINARY_DIR}/kidentitymanagementwidgets_export.h
0095   ${KIdentityManagementWidgets_HEADERS}
0096     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KIdentityManagementWidgets/kidentitymanagementwidgets
0097     COMPONENT Devel
0098 )
0099 install(FILES ${KIdentityManagementWidgets_CamelCase_HEADERS}
0100     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KIdentityManagementWidgets/KIdentityManagementWidgets/
0101     COMPONENT Devel
0102 )
0103
0104 if (BUILD_QCH)
0105     ecm_add_qch(
0106         KPim6IdentityManagementWidgets_QCH
0107         NAME KIdentityManagementWidgets
0108         BASE_NAME KPim6IdentityManagementWidgets
0109         VERSION ${PIM_VERSION}
0110         ORG_DOMAIN org.kde
0111         SOURCES # using only public headers, to cover only public API
0112             ${KIdentityManagementWidgets_HEADERS}
0113         LINK_QCHS
0114             Qt6Core_QCH
0115             Qt6Gui_QCH
0116             Qt6Widgets_QCH
0117         INCLUDE_DIRS
0118             ${CMAKE_CURRENT_BINARY_DIR}
0119         BLANK_MACROS
0120             KIDENTITYMANAGEMENTWIDGETS_EXPORT
0121         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0122         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0123         COMPONENT Devel
0124     )
0125 endif()
0126
0127 if (BUILD_QCH)
0128     ecm_install_qch_export(
0129         TARGETS KPim6IdentityManagementWidgets_QCH
0130         FILE KPim6IdentityManagementWidgetsQchTargets.cmake
0131         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0132         COMPONENT Devel
0133     )
0134     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6IdentityManagementWidgetsQchTargets.cmake\")")
0135 endif()
0136
0137 configure_package_config_file(
0138   "${CMAKE_CURRENT_SOURCE_DIR}/KPimIdentityManagementWidgetsConfig.cmake.in"
0139   "${CMAKE_CURRENT_BINARY_DIR}/KPim6IdentityManagementWidgetsConfig.cmake"
0140   INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0141 )