src/core/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 ecm_setup_version(PROJECT VARIABLE_PREFIX KIDENTITYMANAGEMENTCORE
0004                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kidentitymanagementcore_version.h"
0005                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6IdentityManagementCoreConfigVersion.cmake"
0006                         SOVERSION 6
0007 )
0008
0009
0010
0011
0012 add_library(KPim6IdentityManagementCore)
0013 add_library(KPim6::IdentityManagementCore ALIAS KPim6IdentityManagementCore)
0014
0015
0016 qt_add_dbus_adaptor(kidentity_dbs_adaptor_SRCS org.kde.pim.IdentityManager.xml identitymanager.h KIdentityManagementCore::IdentityManager )
0017
0018 target_sources(KPim6IdentityManagementCore PRIVATE
0019     ${kidentity_dbs_adaptor_SRCS}
0020   identity.cpp
0021   identitymanager.cpp
0022   identitymodel.cpp
0023   signature.cpp
0024   utils.cpp
0025   utils.h
0026   signature.h
0027   identitymanager.h
0028   identity.h
0029 )
0030
0031 ecm_qt_declare_logging_category(KPim6IdentityManagementCore HEADER kidentitymanagementcore_debug.h
0032         IDENTIFIER KIDENTITYMANAGEMENT_LOG CATEGORY_NAME org.kde.pim.kidentitymanagement
0033         OLD_CATEGORY_NAMES log_kidentitymanagement
0034         DESCRIPTION "kidentitymanagement (pim lib)" EXPORT KIDENTITYMANAGEMENT)
0035
0036 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0037     set_target_properties(KPim6IdentityManagementCore PROPERTIES UNITY_BUILD ON)
0038 endif()
0039
0040 generate_export_header(KPim6IdentityManagementCore BASE_NAME kidentitymanagementcore)
0041
0042 target_include_directories(KPim6IdentityManagementCore INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KIdentityManagementCore>")
0043 target_include_directories(KPim6IdentityManagementCore PUBLIC "$<BUILD_INTERFACE:${KIdentityManagement_SOURCE_DIR}/src/;${KIdentityManagement_BINARY_DIR}/src/>")
0044
0045 target_link_libraries(KPim6IdentityManagementCore
0046 PUBLIC
0047   Qt::Gui
0048 PRIVATE
0049   KF6::CoreAddons
0050   KF6::ConfigCore
0051   KF6::Codecs
0052   KF6::I18n
0053   Qt::DBus
0054   Qt::Network
0055 )
0056
0057 set_target_properties(KPim6IdentityManagementCore PROPERTIES
0058     VERSION ${KIDENTITYMANAGEMENTCORE_VERSION}
0059     SOVERSION ${KIDENTITYMANAGEMENTCORE_SOVERSION}
0060     EXPORT_NAME IdentityManagementCore
0061 )
0062
0063 ########### CMake Config Files ###########
0064 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6IdentityManagementCore")
0065
0066
0067 install(FILES
0068   "${CMAKE_CURRENT_BINARY_DIR}/KPim6IdentityManagementCoreConfig.cmake"
0069   "${CMAKE_CURRENT_BINARY_DIR}/KPim6IdentityManagementCoreConfigVersion.cmake"
0070   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0071   COMPONENT Devel
0072 )
0073
0074 install(EXPORT KPim6IdentityManagementCoreTargets
0075     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0076     FILE KPim6IdentityManagementCoreTargets.cmake
0077     NAMESPACE KPim6::
0078 )
0079
0080 install(FILES
0081    ${CMAKE_CURRENT_BINARY_DIR}/kidentitymanagementcore_version.h
0082    DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KIdentityManagementCore
0083    COMPONENT Devel
0084 )
0085
0086
0087
0088
0089 install(TARGETS KPim6IdentityManagementCore EXPORT KPim6IdentityManagementCoreTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0090
0091 ########### Generate Headers ###############
0092 ecm_generate_headers(KIdentityManagementCore_CamelCase_HEADERS
0093   HEADER_NAMES
0094   Identity
0095   IdentityManager
0096   IdentityModel
0097   Signature
0098   Utils
0099   PREFIX KIdentityManagementCore
0100   REQUIRED_HEADERS KIdentityManagementCore_HEADERS
0101 )
0102
0103 ########### install files ###############
0104
0105 install(FILES
0106   ${CMAKE_CURRENT_BINARY_DIR}/kidentitymanagementcore_export.h
0107   ${KIdentityManagementCore_HEADERS}
0108     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KIdentityManagementCore/kidentitymanagementcore
0109     COMPONENT Devel
0110 )
0111 install(FILES    ${KIdentityManagementCore_CamelCase_HEADERS}
0112     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KIdentityManagementCore/KIdentityManagementCore/
0113     COMPONENT Devel
0114 )
0115
0116
0117 install(FILES org.kde.pim.IdentityManager.xml DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR} RENAME kf6_org.kde.pim.IdentityManager.xml)
0118
0119 ecm_qt_install_logging_categories(EXPORT KIDENTITYMANAGEMENT FILE kidentitymanagement.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0120
0121 if (BUILD_QCH)
0122     ecm_add_qch(
0123         KPim6IdentityManagementCore_QCH
0124         NAME KIdentityManagementCore
0125         BASE_NAME KPim6IdentityManagementCore
0126         VERSION ${PIM_VERSION}
0127         ORG_DOMAIN org.kde
0128         SOURCES # using only public headers, to cover only public API
0129             ${KIdentityManagementCore_HEADERS}
0130         LINK_QCHS
0131             Qt6Gui_QCH
0132         INCLUDE_DIRS
0133             ${CMAKE_CURRENT_BINARY_DIR}
0134         BLANK_MACROS
0135             KIDENTITYMANAGEMENTCORE_EXPORT
0136         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0137         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0138         COMPONENT Devel
0139     )
0140 endif()
0141
0142 if (BUILD_QCH)
0143     ecm_install_qch_export(
0144         TARGETS KPim6IdentityManagementCore_QCH
0145         FILE KPim6IdentityManagementCoreQchTargets.cmake
0146         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0147         COMPONENT Devel
0148     )
0149     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6IdentityManagementCoreQchTargets.cmake\")")
0150 endif()
0151 configure_package_config_file(
0152   "${CMAKE_CURRENT_SOURCE_DIR}/KPimIdentityManagementCoreConfig.cmake.in"
0153   "${CMAKE_CURRENT_BINARY_DIR}/KPim6IdentityManagementCoreConfig.cmake"
0154   INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0155 )