pim/kidentitymanagement/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.40")
0005
0006 project(KIdentityManagement VERSION ${PIM_VERSION})
0007
0008 # ECM setup
0009 set(KF_MIN_VERSION "5.248.0")
0010 set(QT_REQUIRED_VERSION "6.6.0")
0011 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDECompilerSettings NO_POLICY_SCOPE)
0017
0018 include(GenerateExportHeader)
0019 include(ECMGenerateHeaders)
0020
0021 include(ECMSetupVersion)
0022 include(FeatureSummary)
0023 include(KDEGitCommitHooks)
0024 include(KDEClangFormat)
0025 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0026 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0027
0028 include(ECMQtDeclareLoggingCategory)
0029 include(ECMDeprecationSettings)
0030 include(ECMFeatureSummary)
0031 include(ECMAddQch)
0032 include(ECMQmlModule)
0033
0034 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0035 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0036
0037 option(BUILD_QUICK_SUPPORT "Build quick support. Needed for merkuro project" ON)
0038
0039 set(KIDENTITYMANAGEMENT_LIB_VERSION ${PIM_VERSION})
0040 set(PIMTEXTEDIT_LIB_VERSION "6.0.40")
0041 set(KTEXTADDONS_MIN_VERSION "1.5.3")
0042
0043 ########### Find packages ###########
0044
0045 find_package(Qt6Network NO_MODULE REQUIRED)
0046
0047 if (BUILD_QUICK_SUPPORT)
0048    find_package(Qt6Quick NO_MODULE REQUIRED)
0049 endif()
0050
0051 find_package(KF6CoreAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0052 find_package(KF6XmlGui ${KF_MIN_VERSION} CONFIG REQUIRED)
0053 find_package(KF6KIO ${KF_MIN_VERSION} CONFIG REQUIRED)
0054 find_package(KF6Config ${KF_MIN_VERSION} CONFIG REQUIRED)
0055 find_package(KF6Codecs ${KF_MIN_VERSION} CONFIG REQUIRED)
0056 find_package(KF6I18n   ${KF_MIN_VERSION} CONFIG REQUIRED)
0057
0058 find_package(KF6TextCustomEditor ${KTEXTADDONS_MIN_VERSION} CONFIG REQUIRED)
0059 find_package(KPim6TextEdit ${PIMTEXTEDIT_LIB_VERSION} CONFIG REQUIRED)
0060 if (BUILD_QUICK_SUPPORT)
0061    find_package(KF6KirigamiAddons 0.11 REQUIRED)
0062    set_package_properties(KF6KirigamiAddons PROPERTIES
0063        TYPE REQUIRED
0064        PURPOSE "Addons for the Kirigami application UI framework"
0065    )
0066 endif()
0067 add_definitions(-DTRANSLATION_DOMAIN=\"libkpimidentities6\")
0068
0069 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0070
0071 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0072 if (USE_UNITY_CMAKE_SUPPORT)
0073     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0074 endif()
0075
0076 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0077 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.249.0)
0078
0079
0080 ########### Targets ###########
0081 add_subdirectory(src)
0082
0083 if(BUILD_TESTING)
0084     add_subdirectory(autotests)
0085 endif()
0086
0087 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0088 ki18n_install(po)
0089 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)