resources/maildir/CMakeLists.txt

0001
0002 include_directories(
0003     ${CMAKE_CURRENT_SOURCE_DIR}/libmaildir
0004     ${kdepim-runtime_SOURCE_DIR}
0005 )
0006
0007
0008 if (BUILD_TESTING)
0009    add_subdirectory( autotests )
0010 endif()
0011
0012 # maildir access library
0013 add_subdirectory(libmaildir)
0014
0015 add_definitions(-DTRANSLATION_DOMAIN=\"akonadi_maildir_resource\")
0016
0017 set(maildir_common_SRCS)
0018 kconfig_add_kcfg_files(maildir_common_SRCS settings.kcfgc)
0019
0020 ############################### Resource #####################################
0021 set( maildirresource_SRCS
0022   main.cpp
0023   maildirresource.cpp
0024   retrieveitemsjob.cpp
0025   maildirresource.h
0026   retrieveitemsjob.h
0027   ${maildir_common_SRCS}
0028 )
0029
0030 ecm_qt_declare_logging_category(maildirresource_SRCS HEADER maildirresource_debug.h IDENTIFIER MAILDIRRESOURCE_LOG CATEGORY_NAME org.kde.pim.maildirresource
0031         DESCRIPTION "maildir resource (kdepim-runtime)"
0032         OLD_CATEGORY_NAMES log_maildirresource
0033         EXPORT KDEPIMRUNTIME
0034     )
0035
0036
0037 kcfg_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/maildirresource.kcfg org.kde.Akonadi.Maildir.Settings)
0038
0039 qt_add_dbus_adaptor(maildirresource_SRCS
0040   ${CMAKE_CURRENT_BINARY_DIR}/org.kde.Akonadi.Maildir.Settings.xml settings.h Akonadi_Maildir_Resource::MaildirSettings maildirsettingsadaptor MaildirSettingsAdaptor
0041 )
0042
0043 add_executable(akonadi_maildir_resource ${maildirresource_SRCS})
0044 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0045     set_target_properties(akonadi_maildir_resource PROPERTIES UNITY_BUILD ON)
0046 endif()
0047 target_link_libraries(akonadi_maildir_resource
0048     maildir
0049     folderarchivesettings
0050     KPim6::AkonadiCore
0051     KPim6::AkonadiMime
0052     KPim6::Mime
0053     KPim6::AkonadiAgentBase
0054     KF6::I18n
0055 )
0056
0057 install(TARGETS akonadi_maildir_resource ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0058 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/org.kde.Akonadi.Maildir.Settings.xml
0059         DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR})
0060
0061 install( FILES maildirresource.desktop DESTINATION "${KDE_INSTALL_DATAROOTDIR}/akonadi/agents" )
0062
0063 ############################# Config plugin ###############################
0064 kcoreaddons_add_plugin(maildirconfig
0065     INSTALL_NAMESPACE "pim6/akonadi/config"
0066 )
0067
0068 target_sources(maildirconfig PRIVATE
0069     maildirconfigmain.cpp
0070     maildirconfig.cpp
0071     configwidget.cpp
0072     maildirconfig.h
0073     configwidget.h
0074     ${maildir_common_SRCS}
0075 )
0076
0077 ki18n_wrap_ui(maildirconfig settings.ui)
0078
0079
0080 target_link_libraries(maildirconfig
0081     KPim6::AkonadiCore
0082     KF6::ConfigWidgets
0083     KF6::KIOWidgets
0084     KF6::I18n
0085     folderarchivesettings
0086     maildir
0087 )