agents/maildispatcher/CMakeLists.txt

0001
0002 add_definitions(-DTRANSLATION_DOMAIN=\"akonadi_maildispatcher_agent\")
0003 add_executable(akonadi_maildispatcher_agent)
0004
0005
0006 ecm_qt_declare_logging_category(akonadi_maildispatcher_agent HEADER maildispatcher_debug.h IDENTIFIER MAILDISPATCHER_LOG CATEGORY_NAME org.kde.pim.maildispatcher
0007         DESCRIPTION "maildispacher agent (kdepim-runtime)"
0008         OLD_CATEGORY_NAMES log_maildispatcher
0009         EXPORT KDEPIMRUNTIME
0010     )
0011
0012 kconfig_add_kcfg_files(maildispatcheragent_SRCS settings.kcfgc)
0013 kcfg_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/maildispatcheragent.kcfg org.kde.Akonadi.MailDispatcher.Settings)
0014 qt_add_dbus_adaptor(maildispatcheragent_SRCS
0015   ${CMAKE_CURRENT_BINARY_DIR}/org.kde.Akonadi.MailDispatcher.Settings.xml settings.h Settings
0016 )
0017 qt_add_dbus_adaptor( maildispatcheragent_SRCS
0018   org.freedesktop.Akonadi.MailDispatcherAgent.xml maildispatcheragent.h MailDispatcherAgent
0019 )
0020 target_sources( akonadi_maildispatcher_agent PRIVATE
0021   maildispatcheragent.cpp
0022   outboxqueue.cpp
0023   sendjob.cpp
0024   sentactionhandler.cpp
0025   storeresultjob.cpp
0026
0027   maildispatcheragent.h
0028   outboxqueue.h
0029   sendjob.h
0030   sentactionhandler.h
0031   storeresultjob.h
0032   ${maildispatcheragent_SRCS}
0033 )
0034
0035 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0036     set_target_properties(akonadi_maildispatcher_agent PROPERTIES UNITY_BUILD ON)
0037 endif()
0038
0039 if( APPLE )
0040   set_target_properties(akonadi_maildispatcher_agent PROPERTIES MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/../Info.plist.template)
0041   set_target_properties(akonadi_maildispatcher_agent PROPERTIES MACOSX_BUNDLE_GUI_IDENTIFIER "org.kde.Akonadi.maildispatcher")
0042   set_target_properties(akonadi_maildispatcher_agent PROPERTIES MACOSX_BUNDLE_BUNDLE_NAME "KDE Akonadi Maildispatcher")
0043 endif ()
0044
0045 target_link_libraries(akonadi_maildispatcher_agent
0046     KPim6::AkonadiCore
0047     KPim6::AkonadiMime
0048     KPim6::Mime
0049     KPim6::MailTransport
0050     KPim6::AkonadiAgentBase
0051     KF6::I18n
0052     KF6::Notifications
0053 )
0054
0055 install( TARGETS akonadi_maildispatcher_agent ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0056 install( FILES maildispatcheragent.desktop DESTINATION "${KDE_INSTALL_DATAROOTDIR}/akonadi/agents" )
0057 install( FILES akonadi_maildispatcher_agent.notifyrc DESTINATION ${KDE_INSTALL_KNOTIFYRCDIR} )
0058
0059 ############################## Configuration ##############################
0060
0061 kcoreaddons_add_plugin(maildispatcherconfig
0062     SOURCES maildispatcherconfig.cpp maildispatcherconfig.h
0063     INSTALL_NAMESPACE "pim6/akonadi/config")
0064 target_link_libraries(maildispatcherconfig
0065     KPim6::AkonadiCore
0066     KF6::NotifyConfig
0067     KF6::ConfigCore
0068 )