pim/kdav2/CMakeLists.txt

0001 cmake_minimum_required(VERSION 2.8.12)
0002
0003 project(libkdav2)
0004
0005 set(LIBKDAV2_VERSION "0.4.0")
0006
0007 configure_file(libkdav2-version.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/libkdav2-version.h @ONLY)
0008
0009 set(KF5_VERSION "5.29.0")
0010 find_package(ECM ${KF5_VERSION} REQUIRED NO_MODULE)
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 include(ECMPackageConfigHelpers)
0017 include(ECMSetupVersion)
0018 include(GenerateExportHeader)
0019 include(ECMGenerateHeaders)
0020 include(ECMGeneratePriFile)
0021 include(FeatureSummary)
0022 include(ECMAddTests)
0023 include(ECMInstallIcons)
0024 include(ECMQtDeclareLoggingCategory)
0025 include(ECMCoverageOption)
0026
0027 set(QT_REQUIRED_VERSION "5.6.0")
0028
0029 find_package(Qt5 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Core Gui Xml XmlPatterns Test)
0030 find_package(KF5 ${KF5_VERSION} REQUIRED CoreAddons)
0031
0032 # setup lib
0033
0034 remove_definitions( -DQT_NO_CAST_FROM_ASCII )
0035 remove_definitions( -DQT_NO_CAST_TO_ASCII )
0036 remove_definitions( -DQT_NO_URL_CAST_FROM_STRING )
0037
0038 ecm_setup_version(${LIBKDAV2_VERSION} VARIABLE_PREFIX KDAV2
0039     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kpimkdav2_version.h"
0040     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPimKDAV2ConfigVersion.cmake"
0041     SOVERSION 5
0042     )
0043
0044 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPimKDAV2")
0045
0046 ecm_configure_package_config_file(
0047     "${CMAKE_CURRENT_SOURCE_DIR}/KPimKDAV2Config.cmake.in"
0048     "${CMAKE_CURRENT_BINARY_DIR}/KPimKDAV2Config.cmake"
0049     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0050     )
0051
0052 install(FILES
0053     "${CMAKE_CURRENT_BINARY_DIR}/KPimKDAV2Config.cmake"
0054     "${CMAKE_CURRENT_BINARY_DIR}/KPimKDAV2ConfigVersion.cmake"
0055     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0056     COMPONENT Devel
0057     )
0058
0059 install(EXPORT KPimKDAV2Targets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPimKDAV2Targets.cmake NAMESPACE KPim::)
0060
0061 install(FILES
0062     ${CMAKE_CURRENT_BINARY_DIR}/kpimkdav2_version.h
0063     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim COMPONENT Devel
0064     )
0065
0066 install(FILES kdav2.categories DESTINATION ${KDE_INSTALL_CONFDIR})
0067
0068
0069 add_subdirectory(3rdparty)
0070 include_directories(3rdparty)
0071 add_subdirectory(src)
0072 add_subdirectory(autotests)
0073 add_subdirectory(test)
0074
0075 feature_summary(WHAT ALL
0076                 INCLUDE_QUIET_PACKAGES
0077                 FATAL_ON_MISSING_REQUIRED_PACKAGES
0078 )