kcalutils/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 add_subdirectory(grantlee_plugin)
0005
0006 add_library(KPim6CalendarUtils)
0007 add_library(KPim6::CalendarUtils ALIAS KPim6CalendarUtils)
0008
0009 configure_file(config-kcalutils.h.in ${CMAKE_CURRENT_BINARY_DIR}/config-kcalutils.h)
0010
0011 target_sources(KPim6CalendarUtils PRIVATE
0012   icaldrag.cpp
0013   incidenceformatter.cpp
0014   recurrenceactions.cpp
0015   stringify.cpp
0016   vcaldrag.cpp
0017   dndfactory.cpp
0018   grantleeki18nlocalizer.cpp
0019   grantleetemplatemanager.cpp
0020   qtresourcetemplateloader.cpp
0021   templates.qrc
0022   vcaldrag.h
0023   kcalutils_private_export.h
0024   stringify.h
0025   icaldrag.h
0026   grantleetemplatemanager_p.h
0027   grantleeki18nlocalizer_p.h
0028   qtresourcetemplateloader.h
0029   incidenceformatter.h
0030   dndfactory.h
0031   recurrenceactions.h
0032 )
0033 ecm_qt_declare_logging_category(KPim6CalendarUtils HEADER kcalutils_debug.h IDENTIFIER KCALUTILS_LOG CATEGORY_NAME org.kde.pim.kcalutils
0034         OLD_CATEGORY_NAMES log_kcalutils
0035         DESCRIPTION "kcalutils (pim lib)" EXPORT KCALUTILS)
0036
0037
0038 ki18n_wrap_ui(KPim6CalendarUtils recurrenceactionsscopewidget.ui)
0039
0040 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0041     set_target_properties(KPim6CalendarUtils PROPERTIES UNITY_BUILD ON)
0042 endif()
0043 ecm_generate_export_header(KPim6CalendarUtils
0044     BASE_NAME kcalutils
0045     VERSION ${KCALUTILS_VERSION}
0046     DEPRECATED_BASE_VERSION 0
0047     USE_VERSION_HEADER
0048 )
0049
0050
0051
0052 target_include_directories(KPim6CalendarUtils INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KCalUtils;${KDE_INSTALL_INCLUDEDIR}/KPim6/KCalUtils/kcalutils>")
0053 target_include_directories(KPim6CalendarUtils PUBLIC "$<BUILD_INTERFACE:${KCalUtils_SOURCE_DIR}/src;${KCalUtils_BINARY_DIR}/src>")
0054
0055 target_link_libraries(KPim6CalendarUtils
0056 PUBLIC
0057   Qt::Widgets
0058   KF6::CalendarCore
0059   KF6::CoreAddons
0060 PRIVATE
0061   KF6::WidgetsAddons
0062   KF6::IconThemes
0063   KF6::I18n
0064   KPim6::IdentityManagementCore
0065   KF6::Codecs
0066   KF6::TextTemplate
0067 )
0068
0069 set_target_properties(KPim6CalendarUtils PROPERTIES
0070     VERSION ${KCALUTILS_VERSION}
0071     SOVERSION ${KCALUTILS_SOVERSION}
0072     EXPORT_NAME CalendarUtils
0073 )
0074
0075 install(TARGETS KPim6CalendarUtils EXPORT KPim6CalendarUtilsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0076
0077 ########### Generate Headers ###############
0078 ecm_generate_headers(KCalUtils_CamelCase_HEADERS
0079   HEADER_NAMES
0080   DndFactory
0081   ICalDrag
0082   IncidenceFormatter
0083   RecurrenceActions
0084   Stringify
0085   VCalDrag
0086   PREFIX KCalUtils
0087   REQUIRED_HEADERS KCalUtils_HEADERS
0088 )
0089
0090 ########### install files ###############
0091
0092 install(FILES
0093   ${CMAKE_CURRENT_BINARY_DIR}/kcalutils_export.h
0094   ${KCalUtils_HEADERS}
0095   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KCalUtils/kcalutils
0096   COMPONENT Devel
0097 )
0098
0099 install(FILES
0100   ${KCalUtils_CamelCase_HEADERS}
0101   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KCalUtils/KCalUtils/
0102   COMPONENT Devel
0103 )
0104
0105 if (BUILD_QCH)
0106     ecm_add_qch(
0107         KPim6CalendarUtils_QCH
0108         NAME KCalendarUtils
0109         BASE_NAME KPim6CalendarUtils
0110         VERSION ${PIM_VERSION}
0111         ORG_DOMAIN org.kde
0112         SOURCES # using only public headers, to cover only public API
0113             ${KCalUtils_HEADERS}
0114         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0115         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0116         LINK_QCHS
0117             Qt6Core_QCH
0118             Qt6Gui_QCH
0119             Qt6Widgets_QCH
0120         INCLUDE_DIRS
0121             ${CMAKE_CURRENT_BINARY_DIR}
0122         BLANK_MACROS
0123             KCALUTILS_EXPORT
0124         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0125         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0126         COMPONENT Devel
0127     )
0128 endif()
0129
0130 ecm_qt_install_logging_categories(EXPORT KCALUTILS FILE kcalutils.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0131