pim/kalarm/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002 set(PIM_VERSION "6.0.40")
0003 set(PIM_VERSION ${PIM_VERSION})
0004 set(RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set(RELEASE_SERVICE_VERSION_MINOR "04")
0006 set(RELEASE_SERVICE_VERSION_MICRO "70")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 # Whenever KALARM_VERSION changes, set the 3 variables below it to the first
0010 # KDE Release Service version which will contain that KAlarm release.
0011 # (This must be the full release version, not an alpha or beta release.)
0012 set(KALARM_VERSION "3.7.0")
0013 set(KALARM_VERSION_RELEASE_SERVICE_MAJOR "24")
0014 set(KALARM_VERSION_RELEASE_SERVICE_MINOR "02")
0015 set(KALARM_VERSION_RELEASE_SERVICE_MICRO "0")
0016
0017 # If KAlarm's version has not changed since the last KDE Release Service version,
0018 # this code sets a sub-version x.x.x.N to avoid duplicate version numbers in
0019 # org.kde.kalarm.appdata.xml, which cause appstream to choke.
0020 math(EXPR LAST_RELEASE_MONTH "${KALARM_VERSION_RELEASE_SERVICE_MAJOR} * 12 + ${KALARM_VERSION_RELEASE_SERVICE_MINOR} + ${KALARM_VERSION_RELEASE_SERVICE_MICRO}")
0021 math(EXPR THIS_RELEASE_MONTH "${RELEASE_SERVICE_VERSION_MAJOR} * 12 + ${RELEASE_SERVICE_VERSION_MINOR} + ${RELEASE_SERVICE_VERSION_MICRO}")
0022 math(EXPR KALARM_RELEASE_SUB_VERSION "${THIS_RELEASE_MONTH} - ${LAST_RELEASE_MONTH}")
0023 if (${KALARM_RELEASE_SUB_VERSION} GREATER 0)
0024     set(KALARM_VERSION "${KALARM_VERSION}.${KALARM_RELEASE_SUB_VERSION}")
0025 endif()
0026
0027 project(kalarm VERSION ${KALARM_VERSION})
0028
0029 set(KF_MIN_VERSION "5.248.0")
0030
0031 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0032 set(CMAKE_MODULE_PATH ${kalarm_SOURCE_DIR}/cmake/modules ${ECM_MODULE_PATH})
0033 include(ECMInstallIcons)
0034
0035 include(ECMSetupVersion)
0036 include(ECMAddTests)
0037
0038 include(GenerateExportHeader)
0039 include(ECMGenerateHeaders)
0040
0041 include(FeatureSummary)
0042 include(CheckFunctionExists)
0043
0044 include(KDEInstallDirs)
0045 include(KDECMakeSettings)
0046 include(KDECompilerSettings NO_POLICY_SCOPE)
0047 include(ECMAddAppIcon)
0048 include(ECMQtDeclareLoggingCategory)
0049 include(ECMDeprecationSettings)
0050 include(ECMFeatureSummary)
0051 set(QT_REQUIRED_VERSION "6.6.0")
0052 set(KTEXTADDONS_MIN_VERSION "1.5.3")
0053 # Do NOT add quote
0054 set(KDEPIM_DEV_VERSION alpha)
0055
0056 # add an extra space
0057 if (DEFINED KDEPIM_DEV_VERSION)
0058     set(KDEPIM_DEV_VERSION " ${KDEPIM_DEV_VERSION}")
0059 endif()
0060
0061
0062 set(KDEPIM_VERSION "${PIM_VERSION}${KDEPIM_DEV_VERSION} (${RELEASE_SERVICE_VERSION})")
0063 set(AKONADI_VERSION "6.0.40")
0064 set(AKONADI_MIMELIB_VERSION "6.0.40")
0065 set(AKONADI_CONTACT_VERSION "6.0.40")
0066 set(KMAILTRANSPORT_LIB_VERSION "6.0.40")
0067 set(IDENTITYMANAGEMENT_LIB_VERSION "6.0.40")
0068 set(KMIME_LIB_VERSION "6.0.40")
0069
0070 set(KDEPIM_LIB_VERSION "${PIM_VERSION}")
0071 set(KDEPIM_LIB_SOVERSION "6")
0072
0073 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED DBus Gui Network Widgets)
0074 set(CALENDARUTILS_LIB_VERSION "6.0.40")
0075
0076 find_package(Qt6Core5Compat)
0077
0078
0079 option(ENABLE_AKONADI_PLUGIN "Build the Akonadi plugin" ON)
0080 add_feature_info(AKONADI_PLUGIN ${ENABLE_AKONADI_PLUGIN} "Provides features dependent on Akonadi (including birthday import,
0081                    email functions, email address book, first run resource migration)")
0082
0083 option(ENABLE_RTC_WAKE_FROM_SUSPEND "Enable RTC wake-from-suspend alarms (requires KAuth)" ON)
0084 if (ENABLE_RTC_WAKE_FROM_SUSPEND)
0085     find_package(KF6Auth ${KF_MIN_VERSION})
0086     if (NOT KF6Auth_FOUND)
0087         set(ENABLE_RTC_WAKE_FROM_SUSPEND OFF)
0088     endif()
0089 endif()
0090 add_feature_info(RTC_WAKE_FROM_SUSPEND ${ENABLE_RTC_WAKE_FROM_SUSPEND} "If kernel timers are not available, use RTC for wake-from-suspend alarms")
0091
0092 # Find KF6 packages
0093 find_package(KF6CalendarCore ${KF_MIN_VERSION} CONFIG REQUIRED)
0094 find_package(KF6Codecs ${KF_MIN_VERSION} CONFIG REQUIRED)
0095 find_package(KF6Completion ${KF_MIN_VERSION} REQUIRED)
0096 find_package(KF6Config ${KF_MIN_VERSION} CONFIG REQUIRED)
0097 find_package(KF6ConfigWidgets ${KF_MIN_VERSION} CONFIG REQUIRED)
0098 find_package(KF6Contacts ${KF_MIN_VERSION} CONFIG REQUIRED)
0099 find_package(KF6Crash ${KF_MIN_VERSION} CONFIG REQUIRED)
0100 find_package(KF6DBusAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0101 find_package(KF6GlobalAccel ${KF_MIN_VERSION} REQUIRED)
0102 find_package(KF6GuiAddons ${KF_MIN_VERSION} REQUIRED)
0103 find_package(KF6Holidays ${KF_MIN_VERSION} CONFIG REQUIRED)
0104 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0105 find_package(KF6ItemModels ${KF_MIN_VERSION} CONFIG REQUIRED)
0106 find_package(KF6JobWidgets ${KF_MIN_VERSION} REQUIRED)
0107 find_package(KF6KIO ${KF_MIN_VERSION} CONFIG REQUIRED)
0108 find_package(KF6Notifications ${KF_MIN_VERSION} CONFIG REQUIRED)
0109 find_package(KF6NotifyConfig ${KF_MIN_VERSION} CONFIG REQUIRED)
0110 find_package(KF6Service ${KF_MIN_VERSION} CONFIG REQUIRED)
0111 find_package(KF6WidgetsAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0112 find_package(KF6WindowSystem ${KF_MIN_VERSION} CONFIG REQUIRED)
0113 find_package(KF6XmlGui ${KF_MIN_VERSION} CONFIG REQUIRED)
0114 find_package(KF6TextWidgets ${KF_MIN_VERSION} CONFIG REQUIRED)
0115 find_package(KF6StatusNotifierItem ${KF_MIN_VERSION} CONFIG REQUIRED)
0116 find_package(Phonon4Qt6 CONFIG REQUIRED)
0117
0118 find_package(KF6DocTools ${KF_MIN_VERSION})
0119 set_package_properties(KF6DocTools PROPERTIES DESCRIPTION
0120     "Tools to generate documentation"
0121     TYPE OPTIONAL
0122 )
0123
0124 # Find KDE PIM packages
0125 find_package(KPim6CalendarUtils ${CALENDARUTILS_LIB_VERSION} CONFIG REQUIRED)
0126 find_package(KPim6IdentityManagementWidgets ${IDENTITYMANAGEMENT_LIB_VERSION} CONFIG REQUIRED)
0127 find_package(KPim6Mime ${KMIME_LIB_VERSION} CONFIG REQUIRED)
0128
0129 find_package(KF6TextEditTextToSpeech ${KTEXTADDONS_MIN_VERSION} CONFIG)
0130 set_package_properties(KF6TextEditTextToSpeech PROPERTIES DESCRIPTION
0131     "Add support for text to speech"
0132     TYPE OPTIONAL
0133 )
0134
0135 if (TARGET KF6::TextEditTextToSpeech)
0136     add_definitions(-DHAVE_TEXT_TO_SPEECH_SUPPORT)
0137 endif()
0138
0139 if (ENABLE_AKONADI_PLUGIN)
0140     find_package(KPim6Akonadi ${AKONADI_VERSION} CONFIG REQUIRED)
0141     find_package(KPim6AkonadiContactWidgets ${AKONADI_CONTACT_VERSION} CONFIG REQUIRED)
0142     find_package(KPim6AkonadiMime ${AKONADI_MIMELIB_VERSION} CONFIG REQUIRED)
0143     find_package(KPim6MailTransport ${KMAILTRANSPORT_LIB_VERSION} CONFIG REQUIRED)
0144 endif()
0145
0146 configure_file(kalarm-version-string.h.in ${CMAKE_CURRENT_BINARY_DIR}/kalarm-version-string.h @ONLY)
0147
0148 if (NOT APPLE)
0149     option(WITHOUT_X11 "Build without X11 integration (skips finding X11)" OFF)
0150     add_feature_info(WITHOUT_X11 ${WITHOUT_X11} "Disable X11 integration, even if X11 is available")
0151     if (NOT WITHOUT_X11)
0152         find_package(X11)
0153         set(ENABLE_X11 ${X11_FOUND})
0154         if (X11_FOUND)
0155             find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Gui)
0156             add_feature_info(ENABLE_X11 ${ENABLE_X11} "Enable use of X11")
0157         endif()
0158     endif()
0159 endif()
0160
0161 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0162
0163 configure_file(src/config-kalarm.h.in ${CMAKE_CURRENT_BINARY_DIR}/config-kalarm.h)
0164
0165 include_directories(${kalarm_SOURCE_DIR} ${kalarm_BINARY_DIR})
0166
0167 add_definitions(-DQT_MESSAGELOGCONTEXT)
0168 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0169 ecm_set_disabled_deprecation_versions(QT 5.15.2  KF 5.249.0)
0170
0171 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0172
0173 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0174 if (USE_UNITY_CMAKE_SUPPORT)
0175     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0176 endif()
0177
0178 add_subdirectory(src)
0179
0180 ecm_qt_install_logging_categories(
0181     EXPORT KALARM
0182     FILE kalarm.categories
0183     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0184     )
0185
0186 if (KF6DocTools_FOUND)
0187     kdoctools_install(po)
0188     add_subdirectory(doc)
0189 endif()
0190 ki18n_install(po)
0191
0192 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)