src/importexport/CMakeLists.txt

0001 add_library(KPim6AddressbookImportExport)
0002 add_library(KPim6::AddressbookImportExport ALIAS KPim6AddressbookImportExport)
0003
0004 ecm_setup_version(PROJECT VARIABLE_PREFIX KADDRESSBOOKIMPORTEXPORT
0005     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kaddressbookimportexport_version.h"
0006     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6AddressbookImportExportConfigVersion.cmake"
0007     SOVERSION 6
0008 )
0009
0010 target_sources(KPim6AddressbookImportExport PRIVATE
0011     contactfields.cpp
0012     contactlist.cpp
0013     contactselectiondialog.cpp
0014     contactselectionwidget.cpp
0015     exportselectionwidget.cpp
0016     importexportengine.cpp
0017     plugin.cpp
0018     plugininterface.cpp
0019     pluginmanager.cpp
0020     contactfields.h
0021     contactlist.h
0022     contactselectiondialog.h
0023     contactselectionwidget.h
0024     exportselectionwidget.h
0025     importexportengine.h
0026     plugin.h
0027     plugininterface.h
0028     pluginmanager.h
0029 )
0030
0031 ecm_qt_declare_logging_category(KPim6AddressbookImportExport
0032     HEADER libkaddressbookexportimport_debug.h
0033     IDENTIFIER LIBKADDRESSBOOKIMPORTEXPORT_LOG
0034     CATEGORY_NAME org.kde.pim.kaddressbookimportexport
0035     DESCRIPTION "kaddressbook (kaddressbookimportexport)"
0036     EXPORT KADDRESSBOOK
0037 )
0038
0039
0040 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0041     set_target_properties(KPim6AddressbookImportExport PROPERTIES UNITY_BUILD ON)
0042 endif()
0043
0044 generate_export_header(KPim6AddressbookImportExport BASE_NAME kaddressbook_importexport)
0045
0046 target_include_directories(KPim6AddressbookImportExport
0047     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6;${KDE_INSTALL_INCLUDEDIR}/KPim6/KAddressBookImportExport;${KDE_INSTALL_INCLUDEDIR}/KPim6/KAddressBookImportExport/kaddressbookimportexport>"
0048 )
0049
0050 target_link_libraries(KPim6AddressbookImportExport
0051     PRIVATE
0052     KF6::Contacts
0053     KPim6::PimCommon
0054     KF6::I18n
0055     KPim6::AkonadiWidgets
0056 )
0057
0058 set_target_properties(KPim6AddressbookImportExport PROPERTIES
0059     VERSION ${KDEPIM_LIB_VERSION}
0060     SOVERSION ${KDEPIM_LIB_SOVERSION}
0061     EXPORT_NAME AddressbookImportExport
0062 )
0063
0064 install(TARGETS
0065     KPim6AddressbookImportExport
0066     EXPORT KPim6AddressbookImportExportTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0067 )
0068
0069 ecm_generate_headers(KaddressbookImportExport_CamelCase_HEADERS
0070     HEADER_NAMES
0071     PluginInterface
0072     Plugin
0073     PluginManager
0074     ContactList
0075     ContactFields
0076     ContactSelectionDialog
0077     ContactSelectionWidget
0078     ImportExportEngine
0079     ExportSelectionWidget
0080     REQUIRED_HEADERS KaddressbookImportExport_HEADERS
0081     PREFIX KAddressBookImportExport
0082 )
0083
0084 ######## CMake Config Files ##########
0085
0086 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6AddressbookImportExport")
0087 configure_package_config_file(
0088     "${CMAKE_CURRENT_SOURCE_DIR}/KPimAddressbookImportExportConfig.cmake.in"
0089     "${CMAKE_CURRENT_BINARY_DIR}/KPim6AddressbookImportExportConfig.cmake"
0090     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0091 )
0092
0093 install(FILES
0094     "${CMAKE_CURRENT_BINARY_DIR}/KPim6AddressbookImportExportConfig.cmake"
0095     "${CMAKE_CURRENT_BINARY_DIR}/KPim6AddressbookImportExportConfigVersion.cmake"
0096     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0097     COMPONENT Devel
0098 )
0099
0100 install(EXPORT KPim6AddressbookImportExportTargets
0101     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0102     FILE KPim6AddressbookImportExportTargets.cmake
0103     NAMESPACE KPim6::
0104 )
0105
0106 install(FILES
0107     ${CMAKE_CURRENT_BINARY_DIR}/kaddressbookimportexport_version.h
0108     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KAddressBookImportExport COMPONENT Devel
0109 )
0110
0111 install(FILES
0112     ${KaddressbookImportExport_CamelCase_HEADERS}
0113     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KAddressBookImportExport/KAddressBookImportExport
0114     COMPONENT Devel
0115 )
0116
0117 install(FILES
0118     ${KaddressbookImportExport_HEADERS}
0119     ${CMAKE_CURRENT_BINARY_DIR}/kaddressbook_importexport_export.h
0120     contactfields.h
0121     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KAddressBookImportExport/kaddressbookimportexport
0122     COMPONENT Devel
0123 )
0124