pim/kaddressbook/CMakeLists.txt

0001 # SPDX-License-Identifier: CC0-1.0
0002 # SPDX-FileCopyrightText: none
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.0")
0005 project(kaddressbook VERSION ${PIM_VERSION})
0006 set(RELEASE_SERVICE_VERSION "24.02.0")
0007 set(KF_MIN_VERSION "5.246.0")
0008
0009 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0010 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0011 include(ECMInstallIcons)
0012
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDECompilerSettings NO_POLICY_SCOPE)
0017 include(ECMAddAppIcon)
0018 include(ECMQtDeclareLoggingCategory)
0019 include(ECMDeprecationSettings)
0020
0021 include(ECMSetupVersion)
0022 include(ECMAddTests)
0023
0024 include(GenerateExportHeader)
0025 include(ECMGenerateHeaders)
0026
0027 include(FeatureSummary)
0028 include(KDEGitCommitHooks)
0029 include(KDEClangFormat)
0030 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0031 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0032 include(CheckFunctionExists)
0033
0034
0035 # Do NOT add quote
0036 set(KDEPIM_DEV_VERSION)
0037
0038 # add an extra space
0039 if(DEFINED KDEPIM_DEV_VERSION)
0040     set(KDEPIM_DEV_VERSION " ${KDEPIM_DEV_VERSION}")
0041 endif()
0042
0043 set(KDEPIM_VERSION "${PIM_VERSION}${KDEPIM_DEV_VERSION} (${RELEASE_SERVICE_VERSION})")
0044
0045 set(AKONADI_VERSION "6.0.0")
0046 set(KONTACTINTERFACE_LIB_VERSION "6.0.0")
0047
0048 set(KDEPIM_LIB_VERSION "${PIM_VERSION}")
0049 set(KDEPIM_LIB_SOVERSION "6")
0050
0051
0052 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Widgets Test DBus PrintSupport)
0053 set(LIBKDEPIM_LIB_VERSION "6.0.0")
0054 set(LIBGRANTLEETHEME_LIB_VERSION "6.0.0")
0055 set(PIMCOMMON_LIB_VERSION "6.0.0")
0056 set(AKONADI_SEARCH_VERSION "6.0.0")
0057 set(AKONADI_CONTACT_VERSION "6.0.0")
0058
0059 # Find KF6 package
0060 find_package(KF6DBusAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0061 find_package(KF6CoreAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0062 find_package(KF6KCMUtils ${KF_MIN_VERSION} CONFIG REQUIRED)
0063 find_package(KF6Crash ${KF_MIN_VERSION} REQUIRED)
0064
0065 find_package(KF6DocTools ${KF_MIN_VERSION})
0066 set_package_properties(KF6DocTools PROPERTIES DESCRIPTION
0067     "Tools to generate documentation"
0068     TYPE OPTIONAL
0069 )
0070
0071 find_package(KF6UserFeedback ${KF_MIN_VERSION})
0072 set_package_properties(KF6UserFeedback PROPERTIES DESCRIPTION "User Feedback lib" TYPE OPTIONAL PURPOSE "Allow to send Telemetry Information (optional).")
0073
0074 find_package(KPim6Akonadi ${AKONADI_VERSION} CONFIG REQUIRED)
0075 find_package(KPim6KontactInterface ${KONTACTINTERFACE_LIB_VERSION} CONFIG REQUIRED)
0076 find_package(KPim6Libkdepim ${LIBKDEPIM_LIB_VERSION} CONFIG REQUIRED)
0077 find_package(KPim6PimCommonAkonadi ${PIMCOMMON_LIB_VERSION} CONFIG REQUIRED)
0078 if (UNIX)
0079     find_package(KPim6AkonadiSearch ${AKONADI_SEARCH_VERSION} CONFIG REQUIRED)
0080 else()
0081     find_package(KPim6AkonadiSearch ${AKONADI_SEARCH_VERSION} CONFIG)
0082     set_package_properties(KPim6AkonadiSearch PROPERTIES DESCRIPTION "The Akonadi Search libraries" URL "https://invent.kde.org/pim/akonadi-search"
0083         TYPE OPTIONAL PURPOSE "Provides search capabilities in KAddressbook and Akonadi (only debug)")
0084 endif()
0085
0086 if (NOT KPim6AkonadiSearch_FOUND)
0087     add_definitions(-DFORCE_DISABLE_AKONADI_SEARCH)
0088 endif()
0089
0090 find_package(KPim6AkonadiContactWidgets ${AKONADI_CONTACT_VERSION} CONFIG REQUIRED)
0091 find_package(KPim6GrantleeTheme ${LIBGRANTLEETHEME_LIB_VERSION} CONFIG REQUIRED)
0092
0093 include_directories(${kaddressbook_SOURCE_DIR} ${kaddressbook_BINARY_DIR})
0094
0095 add_definitions(-DTRANSLATION_DOMAIN=\"kaddressbook\")
0096 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0097 ecm_set_disabled_deprecation_versions(QT 6.6
0098      KF 5.248.0
0099 )
0100
0101
0102
0103 if (TARGET KF6::UserFeedbackWidgets)
0104     add_definitions(-DWITH_KUSERFEEDBACK)
0105 endif()
0106 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0107
0108 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0109 if (USE_UNITY_CMAKE_SUPPORT)
0110     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0111     add_definitions(-DCOMPILE_WITH_UNITY_CMAKE_SUPPORT)
0112 endif()
0113
0114
0115 add_subdirectory(src)
0116 add_subdirectory(kontactplugin)
0117
0118 ecm_qt_install_logging_categories(
0119         EXPORT KADDRESSBOOK
0120         FILE kaddressbook.categories
0121         DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0122         )
0123
0124 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0125 ki18n_install(po)
0126 if(KF6DocTools_FOUND)
0127     kdoctools_install(po)
0128     add_subdirectory(doc)
0129 endif()
0130
0131 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)