src/app/TimelineSectionDelegate.qml

0001 // SPDX-FileCopyrightText: 2018 Volker Krause <vkrause@kde.org>
0002 // SPDX-FileCopyrightText: 2022 Carl Schwan <carl@carlschwan.eu>
0003 // SPDX-License-Identifier: LGPL-2.0-or-later
0004
0005 import QtQuick
0006 import org.kde.kirigami as Kirigami
0007 import QtQuick.Controls as QQC2
0008 import org.kde.kirigamiaddons.formcard as FormCard
0009 import QtQuick.Layouts
0010 import org.kde.itinerary
0011
0012 QQC2.Pane {
0013     property alias day: _controller.date
0014     property QtObject controller: TimelineSectionDelegateController {
0015         id: _controller;
0016         timelineModel: TimelineModel
0017     }
0018
0019     width: ListView.view.width
0020
0021     contentItem: RowLayout {
0022         Item{ Layout.fillWidth: true }
0023         RowLayout{
0024             Layout.margins: Kirigami.Units.smallSpacing
0025             Layout.maximumWidth: Kirigami.Units.gridUnit * 29
0026             Kirigami.Icon {
0027                 source: "view-calendar-day"
0028                 color: controller.isHoliday ? Kirigami.Theme.negativeTextColor : Kirigami.Theme.textColor
0029                 isMask: controller.isHoliday
0030                 implicitHeight: Kirigami.Units.iconSizes.smallMedium
0031                 implicitWidth: Kirigami.Units.iconSizes.smallMedium
0032                 Layout.alignment: Qt.AlignTop
0033             }
0034             ColumnLayout {
0035                 Layout.fillWidth: true
0036                 spacing: 0
0037                 Kirigami.Heading {
0038                     id: titleLabel
0039                     text: controller.title
0040                     type: Kirigami.Heading.Type.Secondary
0041                     font.weight: controller.isToday === Kirigami.Heading.Type.Primary ? Font.DemiBold : Font.Normal
0042                     Layout.fillWidth: true
0043                     level: 4
0044                     Accessible.ignored: true
0045                 }
0046                 QQC2.Label {
0047                     Layout.fillWidth: true
0048                     text: controller.subTitle
0049                     visible: text
0050                     Accessible.ignored: !visible
0051                     Layout.bottomMargin: Kirigami.Units.smallSpacing
0052                 }
0053             }
0054         }
0055         Item{ Layout.fillWidth: true }
0056     }
0057
0058     Accessible.name: titleLabel.text
0059 }