incidenceeditor/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 add_definitions(-DTRANSLATION_DOMAIN=\"libincidenceeditors6\")
0004 add_library(KPim6IncidenceEditor)
0005 add_library(KPim6::IncidenceEditor ALIAS KPim6IncidenceEditor)
0006
0007 target_sources(KPim6IncidenceEditor PRIVATE
0008   attachmenteditdialog.cpp
0009   attachmenticonview.cpp
0010   attendeedata.cpp
0011   attendeeline.cpp
0012   attendeecomboboxdelegate.cpp
0013   attendeelineeditdelegate.cpp
0014   attendeetablemodel.cpp
0015   attendeeeditor.cpp
0016
0017   alarmpresets.cpp
0018   alarmdialog.cpp
0019   incidenceeditorsettings.cpp
0020
0021   ktimezonecombobox.cpp
0022
0023   # TODO: Move the next two to akonadi libs when finished
0024   editoritemmanager.cpp
0025
0026   freebusyurldialog.cpp
0027
0028   # Shared incidence editors code
0029   combinedincidenceeditor.cpp
0030   incidenceeditor.cpp
0031
0032   # Specific editors
0033   incidencealarm.cpp
0034   incidenceattachment.cpp
0035   incidenceattendee.cpp
0036   incidencecategories.cpp
0037   incidencecompletionpriority.cpp
0038   incidencedescription.cpp
0039   incidencewhatwhere.cpp
0040   incidencedatetime.cpp
0041   incidencerecurrence.cpp
0042   incidenceresource.cpp
0043   incidencesecrecy.cpp
0044
0045   freebusyganttproxymodel.cpp
0046   conflictresolver.cpp
0047   schedulingdialog.cpp
0048   groupwareuidelegate.cpp
0049
0050   incidencedefaults.cpp
0051   editorconfig.cpp
0052   korganizereditorconfig.cpp
0053
0054   # Individual mail
0055   individualmailcomponentfactory.cpp
0056   individualmaildialog.cpp
0057   opencomposerjob.cpp
0058
0059   # Resourcemanagement
0060   ldaputils.cpp
0061   resourcemanagement.cpp
0062   resourceitem.cpp
0063   resourcemodel.cpp
0064   kweekdaycheckcombo.cpp
0065
0066   attendeeeditor.h
0067   editorconfig.h
0068   alarmpresets.h
0069   individualmaildialog.h
0070   attachmenteditdialog.h
0071   incidencecompletionpriority.h
0072   incidencewhatwhere.h
0073   visualfreebusywidget.h
0074   attachmenticonview.h
0075   incidenceeditor_private_export.h
0076   resourcemanagement.h
0077   ldaputils.h
0078   resourcemodel.h
0079   incidencealarm.h
0080   incidencedefaults.h
0081   freebusyganttproxymodel.h
0082   incidenceattendee.h
0083   korganizereditorconfig.h
0084   freebusyurldialog.h
0085   ktimezonecombobox.h
0086   incidencedescription.h
0087   conflictresolver.h
0088   editoritemmanager.h
0089   alarmdialog.h
0090   incidencesecrecy.h
0091   combinedincidenceeditor.h
0092   incidencedatetime.h
0093   groupwareuidelegate.h
0094   incidencerecurrence.h
0095   attendeetablemodel.h
0096   incidenceresource.h
0097   individualmailcomponentfactory.h
0098   opencomposerjob.h
0099   schedulingdialog.h
0100   incidencedialog.h
0101   attendeecomboboxdelegate.h
0102   incidencedialogfactory.h
0103   templatemanagementdialog.h
0104   incidenceeditor-ng.h
0105   incidencecategories.h
0106   attendeedata.h
0107   resourceitem.h
0108   kweekdaycheckcombo.h
0109   incidenceattachment.h
0110   attendeelineeditdelegate.h
0111   incidenceeditorsettings.h
0112   attendeeline.h
0113 )
0114
0115 ecm_qt_declare_logging_category(KPim6IncidenceEditor HEADER incidenceeditor_debug.h IDENTIFIER INCIDENCEEDITOR_LOG CATEGORY_NAME org.kde.pim.incidenceeditor
0116         OLD_CATEGORY_NAMES log_incidenceeditor
0117         DESCRIPTION "incidenceeditor (incidenceeditor)" EXPORT INCIDENCEEDITOR)
0118
0119 kconfig_add_kcfg_files(KPim6IncidenceEditor globalsettings_incidenceeditor.kcfgc)
0120
0121 ### Build the desktop version
0122
0123 target_sources(KPim6IncidenceEditor PRIVATE
0124   templatemanagementdialog.cpp
0125   incidencedialogfactory.cpp
0126   incidencedialog.cpp
0127   visualfreebusywidget.cpp
0128   incidenceeditor.qrc
0129 )
0130
0131 ki18n_wrap_ui(KPim6IncidenceEditor
0132   ui/template_management_dialog_base.ui
0133   ui/dialogdesktop.ui
0134   ui/alarmdialog.ui
0135   ui/attachmenteditdialog.ui
0136   ui/schedulingdialog.ui
0137   ui/resourcemanagement.ui
0138 )
0139
0140 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0141     set_target_properties(KPim6IncidenceEditor PROPERTIES UNITY_BUILD ON)
0142 endif()
0143 ecm_generate_export_header(KPim6IncidenceEditor
0144     BASE_NAME incidenceeditor
0145     VERSION ${INCIDENCEEDITOR_VERSION}
0146     DEPRECATED_BASE_VERSION 0
0147     USE_VERSION_HEADER
0148 )
0149
0150
0151 target_link_libraries(KPim6IncidenceEditor
0152 PUBLIC
0153   KPim6::AkonadiCalendar
0154   KPim6::AkonadiMime
0155   KF6::CalendarCore
0156   KPim6::CalendarUtils
0157   KPim6::CalendarSupport      # For KCalPrefs
0158   KPim6::EventViews
0159 PRIVATE
0160   KGantt6             # For FreeBusy Editor
0161   KPim6::PimTextEdit
0162   KF6::Codecs
0163   KPim6::LdapWidgets
0164   KPim6::AkonadiWidgets
0165   KF6::IconThemes
0166   KF6::Completion
0167   KF6::KIOWidgets
0168   KF6::TextWidgets
0169   KF6::WidgetsAddons
0170   KF6::XmlGui
0171   KF6::Contacts
0172   KPim6::Libkdepim
0173   KPim6::PimCommonAkonadi
0174   KPim6::IdentityManagementCore
0175 )
0176 target_include_directories(KPim6IncidenceEditor INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/IncidenceEditor/>")
0177 target_include_directories(KPim6IncidenceEditor PUBLIC "$<BUILD_INTERFACE:${incidenceeditor_SOURCE_DIR}/src;${incidenceeditor_BINARY_DIR}/src;>")
0178
0179 set_target_properties(KPim6IncidenceEditor PROPERTIES
0180     VERSION ${INCIDENCEEDITOR_VERSION}
0181     SOVERSION ${INCIDENCEEDITOR_SOVERSION}
0182     EXPORT_NAME IncidenceEditor
0183 )
0184
0185 install(TARGETS
0186     KPim6IncidenceEditor
0187     EXPORT KPim6IncidenceEditorTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0188 )
0189
0190 ecm_generate_headers(IncidenceEditor_CamelCase_HEADERS
0191   HEADER_NAMES
0192   IncidenceDialog
0193   IncidenceDialogFactory
0194   IncidenceEditorSettings
0195   IncidenceDefaults
0196   IndividualMailComponentFactory
0197   GroupwareUiDelegate
0198   EditorItemManager
0199   IncidenceEditor-Ng
0200   REQUIRED_HEADERS IncidenceEditor_HEADERS
0201   PREFIX IncidenceEditor
0202 )
0203
0204 install(FILES
0205     ${IncidenceEditor_CamelCase_HEADERS}
0206     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/IncidenceEditor/IncidenceEditor
0207     COMPONENT Devel
0208 )
0209
0210 install(FILES
0211     ${CMAKE_CURRENT_BINARY_DIR}/globalsettings_incidenceeditor.h
0212     ${CMAKE_CURRENT_BINARY_DIR}/incidenceeditor_export.h
0213     ${IncidenceEditor_HEADERS}
0214     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/IncidenceEditor/incidenceeditor
0215     COMPONENT Devel
0216 )
0217
0218
0219 ######
0220 if (BUILD_TESTING)
0221    add_subdirectory(tests)
0222 endif()
0223
0224 if (BUILD_QCH)
0225     ecm_add_qch(
0226         KPim6IncidenceEditor_QCH
0227         NAME KIncidenceEditor
0228         BASE_NAME KPim6IncidenceEditor
0229         VERSION ${PIM_VERSION}
0230         ORG_DOMAIN org.kde
0231         SOURCES # using only public headers, to cover only public API
0232             ${IncidenceEditor_HEADERS}
0233         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0234         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0235         LINK_QCHS
0236             Qt6Core_QCH
0237             Qt6Gui_QCH
0238             Qt6Widgets_QCH
0239         INCLUDE_DIRS
0240             ${CMAKE_CURRENT_BINARY_DIR}
0241         BLANK_MACROS
0242             INCIDENCEEDITOR_EXPORT
0243         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0244         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0245         COMPONENT Devel
0246     )
0247 endif()
0248
0249 ecm_qt_install_logging_categories(EXPORT INCIDENCEEDITOR FILE incidenceeditor.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})