eventviews/src/CMakeLists.txt

0001 # SPDX-License-Identifier: CC0-1.0
0002 # SPDX-FileCopyrightText: none
0003 add_definitions(-DTRANSLATION_DOMAIN=\"libeventviews6\")
0004 add_library(KPim6EventViews)
0005 add_library(KPim6::EventViews ALIAS KPim6EventViews)
0006
0007 if(KDEPIM_BUILD_EXAMPLES)
0008   add_subdirectory(viewerapp)
0009 endif()
0010
0011 ########### next target ###############
0012
0013 target_sources(KPim6EventViews PRIVATE
0014   eventview_p.cpp
0015   eventview.cpp
0016   helper.cpp
0017   prefs.cpp
0018
0019   # Agenda view specific code.
0020   agenda/agenda.cpp
0021   agenda/agendaitem.cpp
0022   agenda/agendaview.cpp
0023   agenda/alternatelabel.cpp
0024   agenda/calendardecoration.cpp
0025   agenda/decorationlabel.cpp
0026   agenda/timelabels.cpp
0027   agenda/timelabelszone.cpp
0028   agenda/timescaleconfigdialog.cpp
0029   agenda/viewcalendar.cpp
0030
0031   journal/journalframe.cpp
0032   journal/journalview.cpp
0033
0034   list/listview.cpp
0035
0036   month/monthgraphicsitems.cpp
0037   month/monthitem.cpp
0038   month/monthscene.cpp
0039   month/monthview.cpp
0040
0041   multiagenda/multiagendaview.cpp
0042
0043   todo/tododelegates.cpp
0044   todo/coloredtodoproxymodel.cpp
0045
0046   todo/todoviewquickaddline.cpp
0047   todo/todoviewquicksearch.cpp
0048   todo/todoviewsortfilterproxymodel.cpp
0049   todo/todoviewview.cpp
0050   todo/todoview.cpp
0051
0052   timeline/timelineview.cpp
0053   timeline/timelineitem.cpp
0054   timeline/timelineview_p.cpp
0055
0056   whatsnext/whatsnextview.cpp
0057
0058   eventview_p.h
0059   journal/journalframe.h
0060   journal/journalview.h
0061   list/listview.h
0062   eventview.h
0063   whatsnext/whatsnextview.h
0064   timeline/timelineview_p.h
0065   timeline/timelineview.h
0066   timeline/timelineitem.h
0067   todo/todoviewsortfilterproxymodel.h
0068   todo/todoviewview.h
0069   todo/todoviewquicksearch.h
0070   todo/tododelegates.h
0071   todo/todoview.h
0072   todo/todoviewquickaddline.h
0073   multiagenda/multiagendaview.h
0074   multiagenda/configdialoginterface.h
0075   agenda/timelabelszone.h
0076   agenda/agendaview.h
0077   agenda/timescaleconfigdialog.h
0078   agenda/alternatelabel.h
0079   agenda/agendaitem.h
0080   agenda/timelabels.h
0081   agenda/calendardecoration.h
0082   agenda/decorationlabel.h
0083   agenda/viewcalendar.h
0084   agenda/agenda.h
0085   month/monthview.h
0086   month/monthscene.h
0087   month/monthgraphicsitems.h
0088   month/monthitem.h
0089   helper.h
0090   prefs.h
0091
0092 )
0093
0094 kconfig_add_kcfg_files(KPim6EventViews prefs_base.kcfgc)
0095
0096 ecm_qt_declare_logging_category(KPim6EventViews HEADER calendarview_debug.h
0097         IDENTIFIER CALENDARVIEW_LOG
0098         CATEGORY_NAME org.kde.pim.calendarview
0099         OLD_CATEGORY_NAMES log_calendarview
0100         DESCRIPTION "kdepim (eventviews)" EXPORT EVENTVIEWS)
0101
0102 ki18n_wrap_ui(KPim6EventViews
0103   agenda/timescaleedit_base.ui
0104 )
0105
0106
0107 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0108     set_target_properties(KPim6EventViews PROPERTIES UNITY_BUILD ON)
0109 endif()
0110 ecm_generate_export_header(KPim6EventViews
0111     BASE_NAME eventviews
0112     VERSION ${EVENTVIEWS_VERSION}
0113     DEPRECATED_BASE_VERSION 0
0114     USE_VERSION_HEADER
0115 )
0116
0117 target_link_libraries(KPim6EventViews
0118 PUBLIC
0119   KPim6::AkonadiCore
0120   KPim6::CalendarSupport
0121
0122   KF6::CalendarCore
0123   KPim6::CalendarUtils
0124   KPim6::AkonadiCalendar
0125   KF6::ItemModels
0126 PRIVATE
0127   KF6::Holidays
0128   KF6::Completion
0129   KF6::Service
0130   KF6::IconThemes
0131   KF6::GuiAddons
0132   KF6::I18n
0133   KPim6::Libkdepim
0134   KF6::Codecs
0135   KGantt6
0136   KPim6::AkonadiWidgets
0137   KF6::Contacts
0138 )
0139
0140 target_include_directories(KPim6EventViews INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/EventViews/>")
0141 target_include_directories(KPim6EventViews PUBLIC "$<BUILD_INTERFACE:${eventviews_SOURCE_DIR}/src;${eventviews_BINARY_DIR}/src;>")
0142
0143 set_target_properties(KPim6EventViews PROPERTIES
0144   VERSION ${EVENTVIEWS_VERSION}
0145   SOVERSION ${EVENTVIEWS_SOVERSION}
0146   EXPORT_NAME EventViews
0147 )
0148
0149 install(TARGETS
0150   KPim6EventViews
0151   EXPORT KPim6EventViewsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0152 )
0153
0154 ecm_generate_headers(eventviews_CamelCase_HEADERS
0155   HEADER_NAMES
0156   Helper
0157   Prefs
0158   EventView
0159   REQUIRED_HEADERS eventviews_CamelCase_HEADERS
0160   PREFIX EventViews
0161 )
0162
0163 ecm_generate_headers(eventviews_CamelCaseagenda_HEADERS
0164   HEADER_NAMES
0165   CalendarDecoration
0166   AgendaView
0167   ViewCalendar
0168   REQUIRED_HEADERS eventviews_agenda_HEADERS
0169   PREFIX EventViews
0170   RELATIVE agenda
0171 )
0172
0173 ecm_generate_headers(eventviews_CamelCasetodo_HEADERS
0174   HEADER_NAMES
0175   TodoView
0176   REQUIRED_HEADERS eventviews_todo_HEADERS
0177   PREFIX EventViews
0178   RELATIVE todo
0179 )
0180
0181 ecm_generate_headers(eventviews_CamelCasemonth_HEADERS
0182   HEADER_NAMES
0183   MonthView
0184   REQUIRED_HEADERS eventviews_month_HEADERS
0185   PREFIX EventViews
0186   RELATIVE month
0187 )
0188
0189 ecm_generate_headers(eventviews_CamelCaselist_HEADERS
0190   HEADER_NAMES
0191   ListView
0192   REQUIRED_HEADERS eventviews_list_HEADERS
0193   PREFIX EventViews
0194   RELATIVE list
0195 )
0196
0197 ecm_generate_headers(eventviews_CamelCasejournal_HEADERS
0198   HEADER_NAMES
0199   JournalView
0200   REQUIRED_HEADERS eventviews_journal_HEADERS
0201   PREFIX EventViews
0202   RELATIVE journal
0203 )
0204
0205 ecm_generate_headers(eventviews_CamelCasemultiagenda_HEADERS
0206   HEADER_NAMES
0207   MultiAgendaView
0208   ConfigDialogInterface
0209   REQUIRED_HEADERS eventviews_multiagenda_HEADERS
0210   PREFIX EventViews
0211   RELATIVE multiagenda
0212 )
0213
0214 ecm_generate_headers(eventviews_CamelCasetimeline_HEADERS
0215   HEADER_NAMES
0216   TimeLineView
0217   REQUIRED_HEADERS eventviews_timeline_HEADERS
0218   PREFIX EventViews
0219   RELATIVE timeline
0220 )
0221
0222 ecm_generate_headers(eventviews_CamelCasewhatsnext_HEADERS
0223   HEADER_NAMES
0224   WhatsNextView
0225   REQUIRED_HEADERS eventviews_whatsnext_HEADERS
0226   PREFIX EventViews
0227   RELATIVE whatsnext
0228 )
0229
0230 install(FILES
0231   ${eventviews_CamelCase_HEADERS}
0232   ${eventviews_CamelCaseagenda_HEADERS}
0233   ${eventviews_CamelCasetodo_HEADERS}
0234   ${eventviews_CamelCasewhatsnext_HEADERS}
0235   ${eventviews_CamelCasetimeline_HEADERS}
0236   ${eventviews_CamelCasemultiagenda_HEADERS}
0237   ${eventviews_CamelCasejournal_HEADERS}
0238   ${eventviews_CamelCaselist_HEADERS}
0239   ${eventviews_CamelCasemonth_HEADERS}
0240   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/EventViews/EventViews
0241   COMPONENT Devel
0242 )
0243
0244 install(FILES
0245   ${eventviews_HEADERS}
0246   ${CMAKE_CURRENT_BINARY_DIR}/eventviews_export.h
0247   ${eventviews_CamelCase_HEADERS}
0248   ${eventviews_agenda_HEADERS}
0249   ${eventviews_todo_HEADERS}
0250   ${eventviews_whatsnext_HEADERS}
0251   ${eventviews_timeline_HEADERS}
0252   ${eventviews_multiagenda_HEADERS}
0253   ${eventviews_journal_HEADERS}
0254   ${eventviews_list_HEADERS}
0255   ${eventviews_month_HEADERS}
0256   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/EventViews/eventviews
0257   COMPONENT Devel
0258 )
0259
0260 ecm_qt_install_logging_categories(EXPORT EVENTVIEWS FILE eventviews.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0261
0262 if (BUILD_QCH)
0263     ecm_add_qch(
0264         KPim6EventViews_QCH
0265         NAME KPim6EventViews
0266         BASE_NAME KPim6EventViews
0267         VERSION ${PIM_VERSION}
0268         ORG_DOMAIN org.kde
0269         SOURCES # using only public headers, to cover only public API
0270         ${eventviews_CamelCase_HEADERS}
0271         ${eventviews_agenda_HEADERS}
0272         ${eventviews_todo_HEADERS}
0273         ${eventviews_whatsnext_HEADERS}
0274         ${eventviews_timeline_HEADERS}
0275         ${eventviews_multiagenda_HEADERS}
0276         ${eventviews_journal_HEADERS}
0277         ${eventviews_list_HEADERS}
0278         ${eventviews_month_HEADERS}
0279         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0280         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0281         LINK_QCHS
0282             Qt6Core_QCH
0283             Qt6Gui_QCH
0284             Qt6Widgets_QCH
0285         INCLUDE_DIRS
0286             ${CMAKE_CURRENT_BINARY_DIR}
0287         BLANK_MACROS
0288             EVENTVIEWS_EXPORT
0289         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0290         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0291         COMPONENT Devel
0292     )
0293 endif()
0294
0295 if(BUILD_TESTING)
0296     add_subdirectory(month/autotests)
0297 endif()