calendarsupport/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 add_definitions(-DTRANSLATION_DOMAIN=\"calendarsupport6\")
0004
0005 ########### next target ###############
0006 add_library(KPim6CalendarSupport)
0007 add_library(KPim6::CalendarSupport ALIAS KPim6CalendarSupport)
0008 target_sources(KPim6CalendarSupport PRIVATE
0009   archivedialog.cpp
0010   attachmenthandler.cpp
0011   calendarsingleton.cpp
0012   categoryhierarchyreader.cpp
0013   cellitem.cpp
0014   collectionselection.cpp
0015   eventarchiver.cpp
0016   identitymanager.cpp
0017   incidenceattachmentmodel.cpp
0018   kcalprefs.cpp
0019   messagewidget.cpp
0020   noteeditdialog.cpp
0021   utils.cpp
0022   urihandler.cpp
0023
0024   printing/calprintpluginbase.cpp
0025   printing/calprintdefaultplugins.cpp
0026   printing/calprinter.cpp
0027   printing/journalprint.cpp
0028   printing/yearprint.cpp
0029
0030   next/incidenceviewer.cpp
0031
0032   freebusymodel/freeperiodmodel.cpp
0033   freebusymodel/freebusyitem.cpp
0034   freebusymodel/freebusyitemmodel.cpp
0035   freebusymodel/freebusycalendar.cpp
0036   next/incidenceviewer.h
0037   next/incidenceviewer_p.h
0038   categoryhierarchyreader.h
0039   calendarsingleton.h
0040   utils.h
0041   archivedialog.h
0042   cellitem.h
0043   identitymanager.h
0044   noteeditdialog.h
0045   attachmenthandler.h
0046   eventarchiver.h
0047   printing/printplugin.h
0048   printing/calprintpluginbase.h
0049   printing/journalprint.h
0050   printing/calprintdefaultplugins.h
0051   printing/yearprint.h
0052   printing/calprinter.h
0053   kcalprefs.h
0054   urihandler.h
0055   incidenceattachmentmodel.h
0056   freebusymodel/freeperiodmodel.h
0057   freebusymodel/freebusyitemmodel.h
0058   freebusymodel/freebusycalendar.h
0059   freebusymodel/freebusyitem.h
0060   collectionselection.h
0061   messagewidget.h
0062 )
0063
0064 ki18n_wrap_ui(KPim6CalendarSupport
0065   printing/calprintdayconfig_base.ui
0066   printing/calprintincidenceconfig_base.ui
0067   printing/calprintjournalconfig_base.ui
0068   printing/calprintmonthconfig_base.ui
0069   printing/calprinttodoconfig_base.ui
0070   printing/calprintweekconfig_base.ui
0071   printing/calprintyearconfig_base.ui
0072 )
0073 ecm_qt_declare_logging_category(KPim6CalendarSupport HEADER calendarsupport_debug.h IDENTIFIER CALENDARSUPPORT_LOG CATEGORY_NAME org.kde.pim.calendarsupport
0074         OLD_CATEGORY_NAMES log_calendarsupport
0075         DESCRIPTION "calendarsupport (calendarsupport)" EXPORT CALENDARSUPPORT)
0076
0077 kconfig_add_kcfg_files(KPim6CalendarSupport kcalprefs_base.kcfgc)
0078
0079 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0080     set_target_properties(KPim6CalendarSupport PROPERTIES UNITY_BUILD ON)
0081 endif()
0082 ecm_generate_export_header(
0083     KPim6CalendarSupport
0084     BASE_NAME calendarsupport
0085     VERSION ${PIM_VERSION}
0086     DEPRECATION_VERSIONS "5.24"
0087 )
0088
0089
0090 target_include_directories(KPim6CalendarSupport INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/CalendarSupport/>")
0091 target_include_directories(KPim6CalendarSupport PUBLIC "$<BUILD_INTERFACE:${calendarsupport_SOURCE_DIR}/src;${calendarsupport_BINARY_DIR}/src>")
0092
0093 target_link_libraries(
0094   KPim6CalendarSupport
0095 PUBLIC
0096   KPim6::Mime
0097   KPim6::IdentityManagementCore
0098   KPim6::AkonadiCalendar
0099   KF6::ConfigGui
0100   Qt::PrintSupport
0101 PRIVATE
0102   KF6::TextCustomEditor
0103   KF6::I18n
0104   KF6::Completion
0105   KF6::KIOWidgets
0106   KF6::GuiAddons
0107   KPim6::AkonadiWidgets
0108   KPim6::AkonadiNotes
0109   KF6::Holidays
0110   KF6::Codecs
0111   KPim6::AkonadiCore
0112   KF6::CalendarCore
0113   KPim6::CalendarUtils
0114 )
0115
0116 set_target_properties(KPim6CalendarSupport PROPERTIES
0117     VERSION ${CALENDARSUPPORT_VERSION}
0118     SOVERSION ${CALENDARSUPPORT_SOVERSION}
0119     EXPORT_NAME CalendarSupport
0120 )
0121
0122 install(TARGETS
0123     KPim6CalendarSupport
0124     EXPORT KPim6CalendarSupportTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0125 )
0126
0127 ecm_generate_headers(CalendarSupport_CamelCase_HEADERS
0128   HEADER_NAMES
0129   Utils
0130   CellItem
0131   CollectionSelection
0132   KCalPrefs
0133   IdentityManager
0134   EventArchiver
0135   CategoryHierarchyReader
0136   CalendarSingleton
0137   MessageWidget
0138   ArchiveDialog
0139   NoteEditDialog
0140   UriHandler
0141   REQUIRED_HEADERS CalendarSupport_HEADERS
0142   PREFIX CalendarSupport
0143 )
0144
0145 ecm_generate_headers(CalendarSupport_CamelCaseprinter_HEADERS
0146   HEADER_NAMES
0147   PrintPlugin
0148   CalPrinter
0149   CalPrintDefaultPlugins
0150   CalPrintPluginBase
0151   REQUIRED_HEADERS CalendarSupport_printer_HEADERS
0152   PREFIX CalendarSupport
0153   RELATIVE printing
0154 )
0155
0156 ecm_generate_headers(CalendarSupport_CamelCasenext_HEADERS
0157   HEADER_NAMES
0158   IncidenceViewer
0159   REQUIRED_HEADERS CalendarSupport_next_HEADERS
0160   PREFIX CalendarSupport
0161   RELATIVE next
0162 )
0163
0164 ecm_generate_headers(CalendarSupport_CamelCasefreebusy_HEADERS
0165   HEADER_NAMES
0166   FreeBusyItem
0167   FreeBusyItemModel
0168   FreeBusyCalendar
0169   FreePeriodModel
0170   REQUIRED_HEADERS CalendarSupport_freebusy_HEADERS
0171   PREFIX CalendarSupport
0172   RELATIVE freebusymodel
0173 )
0174
0175 install(FILES
0176     ${CalendarSupport_CamelCase_HEADERS}
0177     ${CalendarSupport_CamelCaseprinter_HEADERS}
0178     ${CalendarSupport_CamelCasenext_HEADERS}
0179     ${CalendarSupport_CamelCasefreebusy_HEADERS}
0180     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/CalendarSupport/CalendarSupport
0181     COMPONENT Devel
0182 )
0183
0184 install(FILES
0185     ${CMAKE_CURRENT_BINARY_DIR}/calendarsupport_export.h
0186     ${CMAKE_CURRENT_BINARY_DIR}/ui_calprintincidenceconfig_base.h
0187     ${CMAKE_CURRENT_BINARY_DIR}/ui_calprintdayconfig_base.h
0188     ${CMAKE_CURRENT_BINARY_DIR}/ui_calprintweekconfig_base.h
0189     ${CMAKE_CURRENT_BINARY_DIR}/ui_calprintmonthconfig_base.h
0190     ${CMAKE_CURRENT_BINARY_DIR}/ui_calprinttodoconfig_base.h
0191
0192     ${CMAKE_CURRENT_BINARY_DIR}/kcalprefs_base.h
0193     ${CalendarSupport_HEADERS}
0194     ${CalendarSupport_printer_HEADERS}
0195     ${CalendarSupport_next_HEADERS}
0196     ${CalendarSupport_freebusy_HEADERS}
0197     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/CalendarSupport/calendarsupport
0198     COMPONENT Devel
0199 )
0200 if(BUILD_TESTING)
0201     add_subdirectory(autotests)
0202     add_subdirectory(freebusymodel/autotests)
0203 endif()
0204
0205 ecm_qt_install_logging_categories(EXPORT CALENDARSUPPORT FILE calendarsupport.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0206
0207 if (BUILD_QCH)
0208     ecm_add_qch(
0209         KPim6CalendarSupport_QCH
0210         NAME KPim6CalendarSupport
0211         BASE_NAME KPim6CalendarSupport
0212         VERSION ${PIM_VERSION}
0213         ORG_DOMAIN org.kde
0214         SOURCES # using only public headers, to cover only public API
0215         ${CalendarSupport_HEADERS}
0216         ${CalendarSupport_printer_HEADERS}
0217         ${CalendarSupport_next_HEADERS}
0218         ${CalendarSupport_freebusy_HEADERS}
0219         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0220         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0221         LINK_QCHS
0222             Qt6Core_QCH
0223             Qt6Gui_QCH
0224             Qt6Widgets_QCH
0225         INCLUDE_DIRS
0226             ${CMAKE_CURRENT_BINARY_DIR}
0227         BLANK_MACROS
0228             KSIEVEUI_EXPORT
0229         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0230         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0231         COMPONENT Devel
0232     )
0233 endif()