pim/calendarsupport/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.0")
0005
0006 project(calendarsupport VERSION ${PIM_VERSION})
0007
0008 set(KF_MIN_VERSION "5.246.0")
0009 set(QT_REQUIRED_VERSION "6.6.0")
0010 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDECompilerSettings NO_POLICY_SCOPE)
0017
0018 include(ECMGenerateExportHeader)
0019 include(ECMSetupVersion)
0020 include(ECMGenerateHeaders)
0021
0022 include(FeatureSummary)
0023 include(KDEGitCommitHooks)
0024 include(KDEClangFormat)
0025 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0026 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0027
0028 include(ECMQtDeclareLoggingCategory)
0029 include(ECMDeprecationSettings)
0030 include(ECMAddTests)
0031
0032 include(ECMAddQch)
0033
0034
0035 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0036 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0037
0038 set(CALENDARSUPPORT_LIB_VERSION ${PIM_VERSION})
0039 set(KMIME_LIB_VERSION "6.0.0")
0040 set(CALENDARUTILS_LIB_VERSION "6.0.0")
0041 set(IDENTITYMANAGEMENT_LIB_VERSION "6.0.0")
0042 set(AKONADICALENDAR_LIB_VERSION "6.0.0")
0043 set(AKONADI_VERSION "6.0.0")
0044 set(AKONADI_NOTES_VERSION "6.0.0")
0045 set(KTEXTADDONS_MIN_VERSION "1.5.2")
0046 find_package(KPim6Akonadi ${AKONADI_VERSION} CONFIG REQUIRED)
0047 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Widgets Test PrintSupport)
0048 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0049 find_package(KF6GuiAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0050 find_package(KF6KIO ${KF_MIN_VERSION} CONFIG REQUIRED)
0051 find_package(KPim6Mime ${KMIME_LIB_VERSION} CONFIG REQUIRED)
0052 find_package(KF6Codecs ${KF_MIN_VERSION} CONFIG REQUIRED)
0053 find_package(KPim6CalendarUtils ${CALENDARUTILS_LIB_VERSION} CONFIG REQUIRED)
0054 find_package(KF6CalendarCore ${KF_MIN_VERSION} CONFIG REQUIRED)
0055 find_package(KPim6IdentityManagementCore ${IDENTITYMANAGEMENT_LIB_VERSION} CONFIG REQUIRED)
0056 find_package(KF6Holidays ${KF_MIN_VERSION} CONFIG REQUIRED)
0057 find_package(KPim6AkonadiCalendar ${AKONADICALENDAR_LIB_VERSION} CONFIG REQUIRED)
0058 find_package(KPim6AkonadiNotes ${AKONADI_NOTES_VERSION} CONFIG REQUIRED)
0059 find_package(KF6TextCustomEditor ${KTEXTADDONS_MIN_VERSION} CONFIG REQUIRED)
0060
0061 ecm_setup_version(PROJECT VARIABLE_PREFIX CALENDARSUPPORT
0062                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/calendarsupport_version.h"
0063                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarSupportConfigVersion.cmake"
0064                         SOVERSION 6
0065 )
0066
0067 ########### Targets ###########
0068
0069
0070 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0071 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.248.0)
0072
0073 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0074
0075 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0076 if (USE_UNITY_CMAKE_SUPPORT)
0077     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0078 endif()
0079
0080 ########### CMake Config Files ###########
0081 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6CalendarSupport")
0082
0083 add_subdirectory(src)
0084
0085 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0086 ki18n_install(po)
0087
0088 if (BUILD_QCH)
0089     ecm_install_qch_export(
0090         TARGETS KPim6CalendarSupport_QCH
0091         FILE KPim6CalendarSupportQchTargets.cmake
0092         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0093         COMPONENT Devel
0094     )
0095     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6CalendarSupportQchTargets.cmake\")")
0096 endif()
0097
0098 configure_package_config_file(
0099   "${CMAKE_CURRENT_SOURCE_DIR}/KPimCalendarSupportConfig.cmake.in"
0100   "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarSupportConfig.cmake"
0101   INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0102 )
0103
0104 install(FILES
0105   "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarSupportConfig.cmake"
0106   "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarSupportConfigVersion.cmake"
0107   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0108   COMPONENT Devel
0109 )
0110
0111 install(EXPORT KPim6CalendarSupportTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0112     FILE KPim6CalendarSupportTargets.cmake NAMESPACE KPim6::)
0113
0114 install(
0115   FILES ${CMAKE_CURRENT_BINARY_DIR}/src/calendarsupport_version.h
0116   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/CalendarSupport/ COMPONENT Devel
0117 )
0118
0119 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)