akonadi-search/lib/CMakeLists.txt

0001 # SPDX-License-Identifier: CC0-1.0
0002 # SPDX-FileCopyrightText: none
0003 kde_enable_exceptions()
0004 include_directories(
0005     ${XAPIAN_INCLUDE_DIR}
0006 )
0007
0008
0009 add_library(KPim6AkonadiSearchPIM)
0010 add_library(KPim6::AkonadiSearchPIM ALIAS KPim6AkonadiSearchPIM)
0011
0012
0013 target_sources(KPim6AkonadiSearchPIM PRIVATE
0014     query.cpp
0015     resultiterator.cpp
0016     contactquery.cpp
0017     emailquery.cpp
0018     notequery.cpp
0019     contactcompleter.cpp
0020     collectionquery.cpp
0021     indexeditems.cpp
0022
0023     ../search/email/agepostingsource.cpp
0024
0025     query.h
0026     resultiterator.h
0027     contactquery.h
0028     emailquery.h
0029     notequery.h
0030     contactcompleter.h
0031     collectionquery.h
0032     indexeditems.h
0033
0034     ../search/email/agepostingsource.h
0035     )
0036
0037 ecm_qt_declare_logging_category(KPim6AkonadiSearchPIM HEADER akonadi_search_pim_debug.h IDENTIFIER AKONADI_SEARCH_PIM_LOG CATEGORY_NAME org.kde.pim.akonadi_search_pim
0038         DESCRIPTION "akonadisearch(akonadi pim lib)"
0039         OLD_CATEGORY_NAMES log_akonadi_search_pim
0040         EXPORT AKONADISEARCH
0041     )
0042
0043 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0044     set_target_properties(KPim6AkonadiSearchPIM PROPERTIES UNITY_BUILD ON)
0045 endif()
0046
0047
0048 generate_export_header(KPim6AkonadiSearchPIM BASE_NAME AKONADI_SEARCH_PIM EXPORT_FILE_NAME search_pim_export.h)
0049
0050 target_link_libraries(KPim6AkonadiSearchPIM
0051     PUBLIC
0052     Qt::Core
0053
0054     PRIVATE
0055     KPim6::AkonadiCore
0056     ${XAPIAN_LIBRARIES}
0057 )
0058
0059 set_target_properties(KPim6AkonadiSearchPIM PROPERTIES
0060     VERSION ${AKONADISEARCH_VERSION}
0061     SOVERSION ${AKONADISEARCH_SOVERSION}
0062     EXPORT_NAME AkonadiSearchPIM
0063 )
0064
0065 target_include_directories(KPim6AkonadiSearchPIM INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/AkonadiSearch>")
0066
0067 install(TARGETS KPim6AkonadiSearchPIM EXPORT KPim6AkonadiSearchTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0068
0069 set(AKONADISEARCH_INCLUDES
0070     query.h
0071     contactquery.h
0072     emailquery.h
0073     contactcompleter.h
0074     notequery.h
0075     collectionquery.h
0076     indexeditems.h
0077
0078     resultiterator.h
0079     )
0080
0081 install(FILES
0082     ${AKONADISEARCH_INCLUDES}
0083     ${CMAKE_CURRENT_BINARY_DIR}/search_pim_export.h
0084
0085     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/AkonadiSearch/PIM
0086     COMPONENT Devel
0087 )
0088
0089 if(BUILD_TESTING)
0090     add_subdirectory(tests)
0091 endif()
0092
0093 if (BUILD_QCH)
0094     ecm_add_qch(
0095         KPim6AkonadiSearchPIM_QCH
0096         NAME KPim6AkonadiSearchPIM
0097         BASE_NAME KPim6AkonadiSearchPIM
0098         VERSION ${PIM_VERSION}
0099         ORG_DOMAIN org.kde
0100         SOURCES # using only public headers, to cover only public API
0101         ${AKONADISEARCH_INCLUDES}
0102         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0103         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0104         LINK_QCHS
0105             Qt6Core_QCH
0106             Qt6Gui_QCH
0107             Qt6Widgets_QCH
0108         INCLUDE_DIRS
0109             ${CMAKE_CURRENT_BINARY_DIR}
0110         BLANK_MACROS
0111             AKONADI_SEARCH_PIM_EXPORT
0112         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0113         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0114         COMPONENT Devel
0115     )
0116 endif()