akonadi-search/core/CMakeLists.txt

0001 # SPDX-License-Identifier: CC0-1.0
0002 # SPDX-FileCopyrightText: none
0003 kde_enable_exceptions()
0004 add_library(KPim6AkonadiSearchCore)
0005 add_library(KPim6::AkonadiSearchCore ALIAS KPim6AkonadiSearchCore)
0006 target_sources(KPim6AkonadiSearchCore PRIVATE
0007     searchstore.cpp
0008     term.cpp
0009     query.cpp
0010     resultiterator.cpp
0011
0012     searchstore.h
0013     term.h
0014     query.h
0015     resultiterator.h
0016     )
0017
0018 ecm_qt_declare_logging_category(KPim6AkonadiSearchCore HEADER akonadi_search_core_debug.h IDENTIFIER AKONADI_SEARCH_CORE_LOG CATEGORY_NAME org.kde.pim.akonadi_search_core
0019         DESCRIPTION "akonadisearch (akonadi core lib)"
0020         EXPORT AKONADISEARCH
0021     )
0022
0023 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0024     set_target_properties(KPim6AkonadiSearchCore PROPERTIES UNITY_BUILD ON)
0025 endif()
0026
0027
0028
0029 target_link_libraries(KPim6AkonadiSearchCore
0030     PUBLIC
0031     Qt::Core
0032 )
0033
0034 set_target_properties(KPim6AkonadiSearchCore PROPERTIES
0035     VERSION ${AKONADISEARCH_VERSION}
0036     SOVERSION ${AKONADISEARCH_SOVERSION}
0037     EXPORT_NAME AkonadiSearchCore
0038 )
0039 target_include_directories(KPim6AkonadiSearchCore INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/AkonadiSearch>")
0040
0041 generate_export_header(KPim6AkonadiSearchCore BASE_NAME AKONADI_SEARCH_CORE EXPORT_FILE_NAME search_core_export.h)
0042
0043 ecm_generate_headers(KPim6AkonadiSearchCore_CamelCasecore_HEADERS
0044     HEADER_NAMES
0045     Term
0046     Query
0047     ResultIterator
0048     SearchStore
0049     REQUIRED_HEADERS KPim6AkonadiSearchCore_core_HEADERS
0050     PREFIX Core
0051     )
0052
0053 install(TARGETS KPim6AkonadiSearchCore EXPORT KPim6AkonadiSearchTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0054
0055 install(FILES
0056     ${KPim6AkonadiSearchCore_CamelCasecore_HEADERS}
0057     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/AkonadiSearch/Core
0058     COMPONENT Devel
0059 )
0060 install(FILES
0061     ${KPim6AkonadiSearchCore_core_HEADERS}
0062     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/AkonadiSearch/core
0063     COMPONENT Devel
0064 )
0065
0066 install(FILES
0067     ${CMAKE_CURRENT_BINARY_DIR}/search_core_export.h
0068     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/AkonadiSearch
0069     COMPONENT Devel
0070 )