pim/akonadi-notes/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.40")
0005
0006 project(Akonadi-Notes VERSION ${PIM_VERSION})
0007
0008 # ECM setup
0009 set(KF_MIN_VERSION "5.248.0")
0010 set(QT_REQUIRED_VERSION "6.6.0")
0011 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDECompilerSettings NO_POLICY_SCOPE)
0017
0018 include(GenerateExportHeader)
0019 include(ECMGenerateHeaders)
0020
0021 include(ECMSetupVersion)
0022 include(FeatureSummary)
0023 include(KDEGitCommitHooks)
0024 include(KDEClangFormat)
0025 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0026 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0027
0028 include(ECMQtDeclareLoggingCategory)
0029 include(ECMDeprecationSettings)
0030 include(ECMFeatureSummary)
0031 include(ECMAddQch)
0032
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036 set(AKONADI_NOTES_VERSION ${PIM_VERSION})
0037
0038 set(KMIMELIB_VERSION "6.0.40")
0039 set(AKONADI_VERSION "6.0.40")
0040
0041 ecm_setup_version(PROJECT VARIABLE_PREFIX AKONADINOTES
0042     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/akonadi-notes_version.h"
0043     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6AkonadiNotesConfigVersion.cmake"
0044     SOVERSION 6
0045     )
0046
0047 ########### Find packages ###########
0048 find_package(Qt6Xml ${QT_REQUIRED_VERSION} CONFIG REQUIRED)
0049
0050 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0051 find_package(KPim6Mime ${KMIMELIB_VERSION} CONFIG REQUIRED)
0052 ########### Targets ###########
0053
0054 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0055
0056 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0057 if (USE_UNITY_CMAKE_SUPPORT)
0058     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0059 endif()
0060
0061 add_definitions(-DTRANSLATION_DOMAIN=\"akonadinotes6\")
0062
0063 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0064 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.249.0)
0065
0066 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6AkonadiNotes")
0067
0068 add_subdirectory(src)
0069 if (BUILD_TESTING)
0070     add_subdirectory(autotests)
0071 endif()
0072 ########### CMake Config Files ###########
0073
0074 install(FILES
0075     ${CMAKE_CURRENT_BINARY_DIR}/akonadi-notes_version.h
0076     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/AkonadiNotes COMPONENT Devel
0077     )
0078
0079 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0080 ki18n_install(po)
0081
0082 if (BUILD_QCH)
0083     ecm_install_qch_export(
0084         TARGETS KPim6AkonadiNotes_QCH
0085         FILE KPim6AkonadiNotesQchTargets.cmake
0086         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0087         COMPONENT Devel
0088     )
0089     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6AkonadiNotesQchTargets.cmake\")")
0090 endif()
0091
0092 configure_package_config_file(
0093     "${CMAKE_CURRENT_SOURCE_DIR}/KPimAkonadiNotesConfig.cmake.in"
0094     "${CMAKE_CURRENT_BINARY_DIR}/KPim6AkonadiNotesConfig.cmake"
0095     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0096     )
0097
0098 install(FILES
0099     "${CMAKE_CURRENT_BINARY_DIR}/KPim6AkonadiNotesConfig.cmake"
0100     "${CMAKE_CURRENT_BINARY_DIR}/KPim6AkonadiNotesConfigVersion.cmake"
0101     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0102     COMPONENT Devel
0103     )
0104
0105 install(EXPORT KPim6AkonadiNotesTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6AkonadiNotesTargets.cmake NAMESPACE KPim6::)
0106
0107
0108
0109 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)