pim/akonadi-mime/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004
0005 set(PIM_VERSION "6.0.0")
0006 project(Akonadi-Mime VERSION ${PIM_VERSION})
0007
0008 # ECM setup
0009 set(KF_MIN_VERSION "5.246.0")
0010
0011 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013 set(QT_REQUIRED_VERSION "6.6.0")
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDECompilerSettings NO_POLICY_SCOPE)
0018
0019 include(GenerateExportHeader)
0020 include(ECMGenerateHeaders)
0021
0022 include(ECMSetupVersion)
0023 include(FeatureSummary)
0024 include(KDEGitCommitHooks)
0025 include(KDEClangFormat)
0026 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0027 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0028
0029 include(ECMQtDeclareLoggingCategory)
0030 include(ECMDeprecationSettings)
0031 include(ECMAddQch)
0032
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036 set(AKONADI_MIME_VERSION ${PIM_VERSION})
0037 set(AKONADI_VERSION "6.0.0")
0038 set(KPIM_MIME_VERSION "6.0.0")
0039
0040 ecm_setup_version(PROJECT VARIABLE_PREFIX AKONADIMIME
0041     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/akonadi-mime_version.h"
0042     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6AkonadiMimeConfigVersion.cmake"
0043     SOVERSION 6
0044     )
0045
0046 ########### Find packages ###########
0047 find_package(KF6KIO ${KF_MIN_VERSION} CONFIG REQUIRED)
0048 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0049 find_package(KF6XmlGui ${KF_MIN_VERSION} CONFIG REQUIRED)
0050 find_package(KPim6Mime ${KPIM_MIME_VERSION} CONFIG REQUIRED)
0051 find_package(KF6ItemModels ${KF_MIN_VERSION} CONFIG REQUIRED)
0052
0053 find_package(KPim6Akonadi ${AKONADI_VERSION} CONFIG REQUIRED)
0054
0055 set( SharedMimeInfo_MINIMUM_VERSION "1.3" )
0056 find_package(SharedMimeInfo ${SharedMimeInfo_MINIMUM_VERSION} REQUIRED)
0057
0058 find_package(LibXslt)
0059 set_package_properties(LibXslt PROPERTIES
0060     DESCRIPTION "xsltproc"
0061     URL "http://xmlsoft.org/XSLT/"
0062     TYPE REQUIRED
0063     PURPOSE "Needed to generate D-Bus interface specifications"
0064     )
0065
0066 ########### Targets ###########
0067
0068 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0069 ecm_set_disabled_deprecation_versions(QT 6.6
0070      KF 5.105.0
0071 )
0072
0073 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0074
0075 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0076 if (USE_UNITY_CMAKE_SUPPORT)
0077     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0078 endif()
0079 if(BUILD_TESTING)
0080     set(AKONADI_MIME_TEST_EXPORT AKONADI_MIME_EXPORT)
0081 endif()
0082 configure_file(akonadi-mimeprivate_export.h.in "${CMAKE_CURRENT_BINARY_DIR}/akonadi-mimeprivate_export.h")
0083 include_directories(${CMAKE_CURRENT_BINARY_DIR})
0084
0085 add_subdirectory(src)
0086 add_subdirectory(serializers)
0087
0088 if(BUILD_TESTING)
0089     add_subdirectory(autotests)
0090     add_subdirectory(tests)
0091 endif()
0092
0093 ########### CMake Config Files ###########
0094 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6AkonadiMime")
0095 if (BUILD_QCH)
0096     ecm_install_qch_export(
0097         TARGETS KPim6AkonadiMime_QCH
0098         FILE KPim6AkonadiMimeQchTargets.cmake
0099         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0100         COMPONENT Devel
0101     )
0102     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6AkonadiMimeQchTargets.cmake\")")
0103 endif()
0104
0105 configure_package_config_file(
0106     "${CMAKE_CURRENT_SOURCE_DIR}/KPimAkonadiMimeConfig.cmake.in"
0107     "${CMAKE_CURRENT_BINARY_DIR}/KPim6AkonadiMimeConfig.cmake"
0108     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0109     )
0110
0111 install(FILES
0112     "${CMAKE_CURRENT_BINARY_DIR}/KPim6AkonadiMimeConfig.cmake"
0113     "${CMAKE_CURRENT_BINARY_DIR}/KPim6AkonadiMimeConfigVersion.cmake"
0114     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0115     COMPONENT Devel
0116     )
0117
0118 install(EXPORT KPim6AkonadiMimeTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6AkonadiMimeTargets.cmake NAMESPACE KPim6::)
0119
0120 install(FILES
0121     ${CMAKE_CURRENT_BINARY_DIR}/akonadi-mime_version.h
0122     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/AkonadiMime COMPONENT Devel
0123     )
0124
0125 ecm_qt_install_logging_categories(
0126         EXPORT AKONADIMIME
0127         FILE akonadi-mime.categories
0128         DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0129         )
0130
0131
0132 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0133 ki18n_install(po)
0134
0135 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)