recipes-support/sddm/sddm.inc

0001 # SPDX-FileCopyrightText: 2019 Alistair Francis <alistair.francis@wdc.com>
0002 # SPDX-FileCopyrightText: 2019-2020 Volker Krause <vkrause@kde.org>
0003 #
0004 # SPDX-License-Identifier: MIT
0005
0006 DESCRIPTION = "QML based X11 and Wayland display manager"
0007 HOMEPAGE = "https://github.com/sddm/sddm"
0008 LICENSE = "GPLv2 & CC-BY-3.0"
0009 LIC_FILES_CHKSUM = " \
0010     file://LICENSE;md5=4641e94ec96f98fabc56ff9cc48be14b \
0011     file://LICENSE.CC-BY-3.0;md5=36b7342d5619a3a0d3b581e89803ec25 \
0012 "
0013
0014 REQUIRED_DISTRO_FEATURES = "x11"
0015
0016 DEPENDS = " \
0017     qtdeclarative \
0018     qttools \
0019     qttools-native \
0020     extra-cmake-modules \
0021     libpam \
0022     libxcb \
0023 "
0024
0025 SRC_URI = " \
0026     git://github.com/sddm/${BPN};nobranch=1;protocol=https \
0027     file://0001-Workaround-missing-sessions.patch \
0028     file://sddm.conf.plasma-mobile \
0029     file://sddm.conf.plasma-bigscreen \
0030     file://sddm.pam \
0031     file://sddm-autologin.pam \
0032 "
0033 S = "${WORKDIR}/git"
0034
0035 inherit cmake_qt5
0036 inherit pkgconfig
0037 inherit systemd
0038 inherit useradd
0039 inherit features_check
0040
0041 EXTRA_OECMAKE += " \
0042     -DLOGIN_DEFS_PATH=${STAGING_DIR_HOST}${sysconfdir}/login.defs \
0043     -DQML_INSTALL_DIR=${OE_QMAKE_PATH_QML} \
0044     -DSYSTEMD_SYSTEM_UNIT_DIR=${systemd_unitdir}/system \
0045 "
0046
0047 do_configure:append() {
0048     # fix sysroot path
0049     sed -i 's:${STAGING_DIR_HOST}.*${libdir}:${libdir}:g' ${B}/src/common/Constants.h
0050 }
0051
0052 do_install:append() {
0053     install -d ${D}/${sysconfdir}/sddm.conf.d
0054     install -m 644 ${WORKDIR}/sddm.conf.plasma-mobile ${D}/${sysconfdir}/sddm.conf.d/01-plasma-mobile.conf
0055     install -m 644 ${WORKDIR}/sddm.conf.plasma-bigscreen ${D}/${sysconfdir}/sddm.conf.d/02-plasma-bigscreen.conf
0056
0057     install -d ${D}${sysconfdir}/pam.d
0058     install -m 644 ${WORKDIR}/sddm.pam ${D}${sysconfdir}/pam.d/sddm
0059     install -m 644 ${WORKDIR}/sddm-autologin.pam ${D}${sysconfdir}/pam.d/sddm-autologin
0060
0061     install -d ${D}${localstatedir}/lib/sddm
0062     chown -R sddm:sddm ${D}${localstatedir}/lib/sddm
0063     chmod 0750 ${D}${localstatedir}/lib/sddm
0064
0065     # make SDDM actually auto-start
0066     echo "WantedBy=multi-user.target" >> ${D}/${systemd_unitdir}/system/sddm.service
0067 }
0068
0069 PACKAGES =+ " \
0070     ${PN}-config-plasma-mobile \
0071     ${PN}-config-plasma-bigscreen \
0072 "
0073
0074 FILES:${PN} += " \
0075     ${OE_QMAKE_PATH_QML} \
0076     ${libdir}/sysusers.d/* \
0077     ${libdir}/tmpfiles.d/* \
0078 "
0079
0080 FILES:${PN}-config-plasma-mobile = " \
0081     ${sysconfdir}/sddm.conf.d/01-plasma-mobile.conf \
0082 "
0083
0084 FILES:${PN}-config-plasma-bigscreen = " \
0085     ${sysconfdir}/sddm.conf.d/02-plasma-bigscreen.conf \
0086 "
0087
0088 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
0089
0090 USERADD_PACKAGES = "${PN}"
0091 USERADD_PARAM:${PN} = "--system --home ${localstatedir}/lib/sddm --shell /bin/false --user-group --groups video sddm"
0092
0093 RDEPENDS:${PN} += "\
0094     bash \
0095     packagegroup-core-x11-xserver \
0096     xcb-util \
0097     xauth \
0098     xinit \
0099     xmessage \
0100     xrdb \
0101     qtbase-plugins \
0102     qtdeclarative-plugins \
0103     qtdeclarative-qmlplugins \
0104 "
0105
0106 RRECOMMENDS:${PN} += " \
0107     qtvirtualkeyboard-plugins \
0108     qtvirtualkeyboard-qmlplugins \
0109     ${PN}-config-plasma-mobile \
0110 "