yocto-meta-kde/recipes-plasma/plasma-workspace.inc

0001 # SPDX-FileCopyrightText: 2018-2020 Volker Krause <vkrause@kde.org>
0002 # SPDX-FileCopyrightText: 2019 Alistair Francis <alistair.francis@wdc.com>
0003 # SPDX-FileCopyrightText: 2020-2021 Andreas Cord-Landwehr <cordlandwehr@kde.org>
0004 #
0005 # SPDX-License-Identifier: MIT
0006
0007 DESCRIPTION = "Plasma Workspace"
0008 HOMEPAGE = ""
0009 LICENSE = "GPL-2.0"
0010 LIC_FILES_CHKSUM = "file://LICENSES/GPL-2.0-only.txt;md5=9e2385fe012386d34dcc5c9863070881"
0011 PR = "r0"
0012
0013 SRC_URI:append:visionfive2 = " \
0014     file://0001-Use-VisionFive2-specific-MESA-Fork.patch \
0015 "
0016
0017 DEPENDS = " \
0018     baloo \
0019     breeze \
0020     kactivities \
0021     kactivitiesstats \
0022     kcoreaddons \
0023     kcrash \
0024     kdbusaddons \
0025     kdeclarative \
0026     kded \
0027     kdesu \
0028     kholidays \
0029     kidletime \
0030     kitemmodels \
0031     kjsembed \
0032     knewstuff \
0033     knotifications \
0034     knotifyconfig \
0035     kpackage \
0036     kpeople \
0037     kquickcharts \
0038     krunner \
0039     kscreen \
0040     kscreenlocker \
0041     ktexteditor \
0042     kunitconversion \
0043     kuserfeedback \
0044     kwallet \
0045     kwayland \
0046     kwin \
0047     kpipewire \
0048     libkscreen \
0049     libksysguard \
0050     libqalculate \
0051     libxft \
0052     networkmanager-qt \
0053     phonon \
0054     plasma-framework \
0055     prison \
0056     qtdeclarative \
0057     qtwayland-native \
0058     solid \
0059 "
0060
0061 inherit cmake_plasma
0062 inherit mime-xdg
0063
0064 EXTRA_OECMAKE += " -DBUILD_xembed-sni-proxy=OFF"
0065
0066 FILES_SOLIBSDEV = ""
0067 FILES:${PN} += " \
0068     ${datadir}/desktop-directories/*.directory \
0069     ${datadir}/kcontrol \
0070     ${datadir}/kdisplay \
0071     ${datadir}/kfontinst \
0072     ${datadir}/kglobalaccel \
0073     ${datadir}/kio_desktop \
0074     ${datadir}/konqsidebartng \
0075     ${datadir}/kpackage \
0076     ${datadir}/krunner \
0077     ${datadir}/kservices5 \
0078     ${datadir}/ksmserver/themes \
0079     ${datadir}/ksplash/Themes \
0080     ${datadir}/kstyle/themes/*.themerc \
0081     ${datadir}/plasma/look-and-feel \
0082     ${datadir}/plasma/avatars \
0083     ${datadir}/plasma/nightcolor \
0084     ${datadir}/plasma/plasmoids \
0085     ${datadir}/plasma/services/*.operations \
0086     ${datadir}/plasma/shareprovider \
0087     ${datadir}/plasma/wallpapers \
0088     ${datadir}/sddm/themes \
0089     ${datadir}/solid/actions/*.desktop \
0090     ${datadir}/wayland-sessions/*.desktop \
0091     ${datadir}/xsessions/*.desktop \
0092     ${datadir}/kio/servicemenus \
0093     ${datadir}/zsh/site-functions/* \
0094     ${libdir}/libkrdb.so \
0095     ${libdir}/plugins/plasmacalendarplugins \
0096     ${libdir}/plugins/kf5/krunner/kcms/kcm_krunner_kill.so \
0097     ${libdir}/plugins/plasma/kcms/systemsettings/*.so \
0098     ${libdir}/plugins/plasma/kcms/systemsettings_qwidgets/kcm_fontinst.so \
0099     ${libdir}/qml/org/kde \
0100 "
0101
0102 FILES:${PN}-dev += " \
0103     ${libdir}/libcolorcorrect.so \
0104     ${libdir}/libnotificationmanager.so \
0105     ${libdir}/libkfontinst.so \
0106     ${libdir}/libkfontinstui.so \
0107     ${libdir}/libtaskmanager.so \
0108     ${libdir}/libkworkspace5.so \
0109     ${libdir}/libplasma-geolocation-interface.so \
0110     ${libdir}/libweather_ion.so \
0111 "
0112
0113 INSANE_SKIP:${PN} = "dev-so"
0114
0115 RDEPENDS:${PN} += " \
0116     kinit \
0117     kquickcharts \
0118     milou \
0119     xprop \
0120     xset \
0121     qttools-tools \
0122 "