yocto-meta-kde/recipes-plasma/kwin.inc

0001 # SPDX-FileCopyrightText: 2017-2020 Volker Krause <vkrause@kde.org>
0002 # SPDX-FileCopyrightText: 2018 Alistair Francis <alistair.francis@wdc.com>
0003 # SPDX-FileCopyrightText: 2020-2022 Andreas Cord-Landwehr <cordlandwehr@kde.org>
0004 #
0005 # SPDX-License-Identifier: MIT
0006
0007 DESCRIPTION = "KWin"
0008 HOMEPAGE = ""
0009 LICENSE = "GPL-2.0"
0010 LIC_FILES_CHKSUM = "file://LICENSES/GPL-2.0-only.txt;md5=93e64b4a83c7e441e48bbdeeea05c977"
0011 PR = "r0"
0012
0013 DEPENDS:class-target = " \
0014     qtdeclarative \
0015     qtsensors \
0016     qtwayland-native \
0017     kpackage-native \
0018     qtscript \
0019     kconfigwidgets \
0020     kcrash \
0021     kglobalaccel \
0022     kinit \
0023     knotifications \
0024     kpackage \
0025     kwin-native \
0026     wayland \
0027     wayland-protocols \
0028     plasma-framework \
0029     kwindowsystem \
0030     kiconthemes \
0031     kidletime \
0032     kwayland \
0033     kcompletion \
0034     kdeclarative \
0035     kio \
0036     ktextwidgets \
0037     knewstuff \
0038     kservice \
0039     kxmlgui \
0040     kdecoration \
0041     krunner \
0042     kscreenlocker \
0043     libxcb \
0044     xcb-util-cursor \
0045     fontconfig \
0046     lcms \
0047     libepoxy \
0048     libinput \
0049     pipewire \
0050     libxcvt \
0051     hwdata \
0052 "
0053
0054 DEPENDS:class-native = " \
0055     qtbase-native \
0056     extra-cmake-modules-native \
0057 "
0058
0059 SRC_URI:append = " \
0060     file://kwinrc \
0061     file://0002-Include-missing-header-for-std-round.patch \
0062     file://0003-Add-missing-cmath-include-for-std-ceil.patch \
0063 "
0064
0065 SRC_URI:append:class-native = " \
0066     file://0001-Add-install-operation-for-native-build.patch \
0067 "
0068
0069 OECMAKE_SOURCEPATH:class-native = "${S}/src/wayland/tools"
0070 EXTRA_OECMAKE:append:class-target = " \
0071     -DQTWAYLANDSCANNER_KDE_EXECUTABLE=${STAGING_DIR_NATIVE}/${bindir}/qtwaylandscanner_kde \
0072     -DBUILD_TESTING=OFF \
0073 "
0074
0075 inherit kauth
0076 inherit kcmutils
0077 inherit kconfig
0078 inherit kdoctools
0079 inherit cmake_qt5
0080 inherit pkgconfig
0081 # TODO skip inherit of cmake_plasma for now because it leads to build errors for native package
0082
0083 do_install:append() {
0084     # dirty workaround for aurora crash on Wayland
0085     rm -rf ${D}/${libdir}/plugins/org.kde.kdecoration2/
0086
0087     install -d ${D}/${sysconfdir}/xdg
0088     install -m 644 ${WORKDIR}/kwinrc ${D}/${sysconfdir}/xdg/kwinrc
0089 }
0090
0091 FILES_SOLIBSDEV = ""
0092 FILES:${PN} += " \
0093     ${datadir}/config.kcfg/*.kcfg \
0094     ${datadir}/icons/hicolor \
0095     ${datadir}/kconf_update/* \
0096     ${datadir}/knotifications5/*.notifyrc \
0097     ${datadir}/knsrcfiles/* \
0098     ${datadir}/kpackage \
0099     ${datadir}/krunner/dbusplugins/*.desktop \
0100     ${datadir}/kservices5/*.desktop \
0101     ${datadir}/kservices5/kwin/*.desktop \
0102     ${datadir}/kservicetypes5/*.desktop \
0103     ${datadir}/kwincompositing/qml/*.qml \
0104     ${datadir}/qlogging-categories5 \
0105     ${libdir}/kconf_update_bin/kwin5_update_default_rules \
0106     ${libdir}/plugins/*.so \
0107     ${libdir}/plugins/kf5/org.kde.kidletime.platforms/*.so \
0108     ${libdir}/plugins/kpackage/packagestructure/*.so \
0109     ${libdir}/plugins/kwin/effects/configs/*.so \
0110     ${libdir}/plugins/kwin/plugins/*.so \
0111     ${libdir}/plugins/org.kde.kdecoration2/*.so \
0112     ${libdir}/plugins/org.kde.kglobalaccel5.platforms/*.so \
0113     ${libdir}/plugins/org.kde.kwin.platforms/*.so \
0114     ${libdir}/plugins/org.kde.kwin.scenes/*.so \
0115     ${libdir}/plugins/org.kde.kwin.waylandbackends/*.so \
0116     ${libdir}/plugins/plasma/kcms/systemsettings/*.so \
0117     ${libdir}/plugins/plasma/kcms/systemsettings_qwidgets/*.so \
0118     ${libdir}/plugins/platforms/*.so \
0119     ${libdir}/qml/org/kde/kwin.2/* \
0120     ${libdir}/qml/org/kde/kwin/decoration/* \
0121     ${libdir}/qml/org/kde/kwin/decorations/plastik/* \
0122     ${libdir}/qml/org/kde/kwin/effects/* \
0123     ${libdir}/qml/org/kde/kwin/private/effects/* \
0124     ${libdir}/qml/org/kde/kwin/private/kdecoration/* \
0125     ${libdir}/qml/org/kde/plasma/quicksetting/nightcolor/* \
0126     ${libdir}/systemd/user/*.service \
0127 "
0128
0129 FILES:${PN}-dev += " \
0130     ${libdir}/libkwin*.so \
0131     ${datadir}/dbus-1/interfaces/*.xml \
0132 "
0133
0134 RDEPENDS:${PN}:append:class-target = " \
0135     maliit-keyboard-qt5 \
0136     qtwayland-plugins \
0137     xwayland \
0138     perl \
0139 "
0140
0141 BBCLASSEXTEND = "native"