kirkstone-support/wayland/wayland_1.21.0.bb

0001 SUMMARY = "Wayland, a protocol between a compositor and clients"
0002 DESCRIPTION = "Wayland is a protocol for a compositor to talk to its clients \
0003 as well as a C library implementation of that protocol. The compositor can be \
0004 a standalone display server running on Linux kernel modesetting and evdev \
0005 input devices, an X application, or a wayland client itself. The clients can \
0006 be traditional applications, X servers (rootless or fullscreen) or other \
0007 display servers."
0008 HOMEPAGE = "http://wayland.freedesktop.org"
0009 LICENSE = "MIT"
0010 LIC_FILES_CHKSUM = "file://COPYING;md5=b31d8f53b6aaf2b4985d7dd7810a70d1 \
0011                     file://src/wayland-server.c;endline=24;md5=b8e046164a766bb1ede8ba38e9dcd7ce"
0012
0013 DEPENDS = "expat libffi wayland-native"
0014
0015 SRC_URI = "https://gitlab.freedesktop.org/wayland/wayland/-/releases/${PV}/downloads/${BPN}-${PV}.tar.xz \
0016            file://run-ptest \
0017            file://0001-build-Fix-strndup-detection-on-MinGW.patch \
0018            "
0019 SRC_URI[sha256sum] = "6dc64d7fc16837a693a51cfdb2e568db538bfdc9f457d4656285bb9594ef11ac"
0020
0021 UPSTREAM_CHECK_URI = "https://wayland.freedesktop.org/releases.html"
0022 UPSTREAM_CHECK_REGEX = "wayland-(?P<pver>\d+\.\d+\.(?!9\d+)\d+)"
0023
0024 inherit meson pkgconfig ptest
0025
0026 PACKAGECONFIG ??= "dtd-validation"
0027 PACKAGECONFIG[dtd-validation] = "-Ddtd_validation=true,-Ddtd_validation=false,libxml2,,"
0028
0029 EXTRA_OEMESON = "-Ddocumentation=false"
0030 EXTRA_OEMESON:class-native = "-Ddocumentation=false"
0031
0032 # Wayland installs a M4 macro for other projects to use, which uses the target
0033 # pkg-config to find files.  Replace pkg-config with pkg-config-native.
0034 do_install:append:class-native() {
0035   sed -e 's,PKG_CHECK_MODULES(.*),,g' \
0036       -e 's,$PKG_CONFIG,pkg-config-native,g' \
0037       -i ${D}/${datadir}/aclocal/wayland-scanner.m4
0038 }
0039
0040 do_install_ptest() {
0041     mkdir -p ${D}${PTEST_PATH}/tests/data
0042     cp -rf ${B}/tests/*-test ${B}/tests/*-checker ${D}${PTEST_PATH}/tests
0043     cp -rf ${B}/tests/*-checker ${D}${PTEST_PATH}
0044     cp -rf ${S}/tests/scanner-test.sh ${D}${PTEST_PATH}/tests
0045     cp -rf ${S}/tests/data/* ${D}${PTEST_PATH}/tests/data/
0046     cp -rf ${S}/egl/wayland-egl-symbols-check ${D}${PTEST_PATH}/tests/
0047 }
0048
0049 sysroot_stage_all:append:class-target () {
0050         rm ${SYSROOT_DESTDIR}/${datadir}/aclocal/wayland-scanner.m4
0051         cp ${STAGING_DATADIR_NATIVE}/aclocal/wayland-scanner.m4 ${SYSROOT_DESTDIR}/${datadir}/aclocal/
0052 }
0053
0054 PACKAGES =+ "${PN}-tools"
0055
0056 FILES:${PN}-tools = "${bindir}/wayland-scanner"
0057 FILES:${PN}-dev += "${datadir}/${BPN}/wayland-scanner.mk"
0058
0059 BBCLASSEXTEND = "native nativesdk"
0060
0061 RDEPENDS:${PN}-ptest += "binutils sed ${PN}-tools"