kirkstone-support/wayland/libinput_1.19.3.bb

0001 SUMMARY = "Library to handle input devices in Wayland compositors"
0002 DESCRIPTION = "libinput is a library to handle input devices in Wayland \
0003 compositors and to provide a generic X.Org input driver. It provides \
0004 device detection, device handling, input device event processing and \
0005 abstraction so minimize the amount of custom input code compositors need to \
0006 provide the common set of functionality that users expect."
0007 HOMEPAGE = "http://www.freedesktop.org/wiki/Software/libinput/"
0008 SECTION = "libs"
0009
0010 LICENSE = "MIT"
0011 LIC_FILES_CHKSUM = "file://COPYING;md5=bab4ac7dc1c10bc0fb037dc76c46ef8a"
0012
0013 DEPENDS = "libevdev udev mtdev libcheck"
0014
0015 SRC_URI = "http://www.freedesktop.org/software/${BPN}/${BP}.tar.xz \
0016            file://run-ptest \
0017            file://determinism.patch \
0018            "
0019 SRC_URI[sha256sum] = "3cae78ccde19d7d0f387e58bc734d4d17ab5f6426f54a9e8b728c90b17baa068"
0020
0021 UPSTREAM_CHECK_REGEX = "libinput-(?P<pver>\d+\.\d+\.(?!9\d+)\d+)"
0022
0023 inherit meson pkgconfig lib_package ptest
0024
0025 # Patch out build directory, otherwise it leaks into ptest binary
0026 do_configure:append() {
0027     sed -i -e "s,${WORKDIR},,g" config.h
0028     if [ -e "litest-config.h" ]; then
0029         sed -i -e "s,${WORKDIR},,g" litest-config.h
0030     fi
0031 }
0032
0033 PACKAGECONFIG ??= ""
0034 PACKAGECONFIG[libwacom] = "-Dlibwacom=true,-Dlibwacom=false,libwacom"
0035 PACKAGECONFIG[gui] = "-Ddebug-gui=true,-Ddebug-gui=false,cairo gtk+3"
0036
0037 UDEVDIR = "`pkg-config --variable=udevdir udev`"
0038
0039 EXTRA_OEMESON += "-Dudev-dir=${UDEVDIR} \
0040                   -Ddocumentation=false \
0041                   ${@bb.utils.contains('PTEST_ENABLED', '1', '-Dtests=true -Dinstall-tests=true', '-Dtests=false -Dinstall-tests=false', d)} \
0042                   -Dzshcompletiondir=no"
0043
0044 # package name changed in 1.8.1 upgrade: make sure package upgrades work
0045 RPROVIDES:${PN} = "libinput"
0046 RREPLACES:${PN} = "libinput"
0047 RCONFLICTS:${PN} = "libinput"
0048
0049 FILES:${PN}-ptest += "${libexecdir}/libinput/libinput-test-suite"