plugins/kbanking/CMakeLists.txt

0001 # patch the version with the version defined in the build system
0002 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/kbanking.json.cmake ${CMAKE_CURRENT_BINARY_DIR}/kbanking.json @ONLY)
0003
0004 file(STRINGS "${AQBANKING_INCLUDE_DIRS}/aqbanking/banking.h" HAVE_REGISTRATION_FEATURE REGEX "AB_Banking_RuntimeConfig_SetCharValue")
0005 if (NOT ${HAVE_REGISTRATION_FEATURE} STREQUAL "")
0006   add_definitions(-DENABLE_FINTS_REGISTRATION)
0007 endif()
0008
0009
0010 add_subdirectory( dialogs )
0011 add_subdirectory( widgets )
0012 add_subdirectory( tasksettings )
0013
0014 set(kbanking_PART_SRCS
0015     kbanking.cpp
0016     banking.cpp
0017     aqbankingkmmoperators.cpp
0018     gwenhywfarqtoperators.cpp
0019     gwenkdegui.cpp
0020 )
0021
0022 kconfig_add_kcfg_files(kbanking_PART_SRCS kbankingsettings.kcfgc)
0023
0024 # Add new menu entries if debugging is enabled
0025 set(KMM_BANKING_DEBUG_OPTIONS)
0026 # preprocessor definitions in case this is a debug build
0027 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_TOLOWER)
0028 if("${CMAKE_BUILD_TYPE_TOLOWER}" MATCHES "debug")
0029     file(READ kbanking_debug_rc KMM_BANKING_DEBUG_OPTIONS)
0030 endif()
0031 configure_file(kbanking.rc.in "${CMAKE_CURRENT_BINARY_DIR}/kbanking.rc" @ONLY)
0032
0033 # need to load kbanking.qrc from ${CMAKE_CURRENT_BINARY_DIR} because the resource files
0034 # must be located in the same directory as the .qrc file, or one of its subdirectories.
0035 configure_file(kbanking.qrc "${CMAKE_CURRENT_BINARY_DIR}/kbanking.qrc" COPYONLY)
0036 qt5_add_resources(kbanking_PART_SRCS "${CMAKE_CURRENT_BINARY_DIR}/kbanking.qrc")
0037
0038 qt5_add_resources(kbanking_PART_SRCS "qml/chipTan/chipTan.qrc")
0039
0040 kmymoney_add_plugin(kbanking SOURCES ${kbanking_PART_SRCS})
0041
0042 target_link_libraries(kbanking
0043                       kbanking_dialogs
0044                       kbanking_widgets
0045                       kbanking_tasksettings
0046                       kmm_mymoney
0047                       kmm_base_widgets
0048                       kmm_plugin
0049                       KF5::ConfigCore
0050                       KF5::ConfigGui
0051                       Qt::Core
0052                       Alkimia::alkimia
0053                       gwenhywfar::core
0054                       gwenhywfar::gui-cpp
0055                       gwenhywfar::gui-qt5
0056                       aqbanking::aqbanking
0057 )
0058
0059 ########### install files ###############
0060
0061 install(FILES kbanking.kcfg
0062         DESTINATION ${KCFG_INSTALL_DIR})