office/kile/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 project(kile)
0004
0005 set(KILE_VERSION CACHE STRING "Kile's version; can be used to set the internal version of Kile on MacOSX")
0006
0007 find_package(ECM 5.19.0 REQUIRED NO_MODULE)
0008 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0009
0010 include(KDECompilerSettings NO_POLICY_SCOPE)
0011
0012 include(ECMAddAppIcon)
0013 include(ECMOptionalAddSubdirectory)
0014 include(ECMInstallIcons)
0015 include(ECMSetupVersion)
0016 include(ECMMarkNonGuiExecutable)
0017 include(ECMGenerateHeaders)
0018
0019 include(GenerateExportHeader)
0020 include(CMakePackageConfigHelpers)
0021 include(FeatureSummary)
0022 include(WriteBasicConfigVersionFile)
0023 include(CheckFunctionExists)
0024
0025 include(KDEInstallDirs)
0026 include(KDECMakeSettings)
0027
0028 kde_enable_exceptions()
0029 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake/modules)
0030
0031 find_package(QT NAMES Qt6 Qt5 REQUIRED COMPONENTS Core)
0032 message(STATUS "Found Qt version ${QT_VERSION_MAJOR}")
0033 if(BUILD_WITH_QT6)
0034     message(STATUS "Using Qt version 6, honoring BUILD_WITH_QT6")
0035     set(QT_VERSION_MAJOR 6)
0036 elseif(BUILD_WITH_QT5)
0037     message(STATUS "Using Qt version 5, honoring BUILD_WITH_QT5")
0038     set(QT_VERSION_MAJOR 5)
0039 elseif(QT_MAJOR_VERSION)
0040     message(STATUS "Using Qt version " ${QT_MAJOR_VERSION} ", honoring QT_MAJOR_VERSION")
0041     set(QT_VERSION_MAJOR ${QT_MAJOR_VERSION})
0042 endif()
0043
0044 find_package(Qt${QT_VERSION_MAJOR} ${QT_REQUIRED_VERSION} CONFIG REQUIRED
0045         Core
0046         DBus
0047         Widgets
0048         Test
0049 )
0050
0051 if (${QT_VERSION_MAJOR} STREQUAL 5)
0052     find_package(Qt${QT_VERSION_MAJOR} ${QT_REQUIRED_VERSION} CONFIG REQUIRED Script)
0053 else()
0054     find_package(Qt${QT_VERSION_MAJOR} ${QT_REQUIRED_VERSION} CONFIG REQUIRED Qml)
0055 endif()
0056
0057 find_package(KF${QT_VERSION_MAJOR} 5.108 REQUIRED COMPONENTS
0058         Config
0059         CoreAddons
0060         Crash
0061         DBusAddons
0062         DocTools
0063         GuiAddons
0064         I18n
0065         IconThemes
0066         KIO
0067         Parts
0068         TextEditor
0069         WindowSystem
0070         XmlGui
0071 )
0072
0073 set(CMAKE_CXX_STANDARD 17)
0074 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0075 set(CMAKE_CXX_EXTENSIONS OFF)
0076
0077 find_package(Okular${QT_VERSION_MAJOR} REQUIRED)
0078 set_package_properties(Okular${QT_VERSION_MAJOR} PROPERTIES
0079         DESCRIPTION "Okular core library"
0080         URL "https://okular.kde.org")
0081
0082 find_package(Poppler COMPONENTS Qt${QT_VERSION_MAJOR})
0083 set_package_properties("Poppler" PROPERTIES
0084         TYPE RECOMMENDED
0085         PURPOSE "Support for PDF file operations.")
0086
0087 if(TARGET Poppler::Qt${QT_VERSION_MAJOR})
0088         set(HAVE_POPPLER TRUE)
0089 endif()
0090
0091 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/src/config.h)
0092
0093 # find_package(SharedMimeInfo REQUIRED)
0094
0095 add_definitions(
0096 #   -DQT_USE_QSTRINGBUILDER
0097 #   -DQT_NO_CAST_FROM_ASCII
0098 #   -DQT_NO_CAST_FROM_BYTEARRAY
0099 #   -DQT_USE_FAST_OPERATOR_PLUS
0100   -DQT_NO_CAST_TO_ASCII
0101   -DQT_STRICT_ITERATORS
0102   -DQT_NO_URL_CAST_FROM_STRING
0103   -DQT_NO_SIGNALS_SLOTS_KEYWORDS
0104 )
0105
0106 if(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
0107   add_definitions(-DQT_MESSAGELOGCONTEXT)
0108 endif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
0109
0110 add_subdirectory(doc)
0111 add_subdirectory(src)
0112
0113 ########### install files ###############
0114
0115 install(
0116         FILES kile.xml
0117         DESTINATION ${KDE_INSTALL_MIMEDIR})
0118 # update_xdg_mimetypes(${XDG_MIME_INSTALL_DIR})
0119
0120 install(
0121         FILES
0122                 kile.upd
0123         DESTINATION ${KDE_INSTALL_DATAROOTDIR}/kconf_update)
0124
0125 install(
0126         PROGRAMS
0127                 kile1.6_upd.pl
0128                 kile1.7_upd.pl
0129                 kile1.9_upd.pl
0130                 kile1.9-1_upd.pl
0131                 kile2.0-1_upd.pl
0132                 kile2.0-2_upd.pl
0133                 kile2.0-3_upd.pl
0134                 kile2.0-4_upd.pl
0135                 kile2.0-5_upd.pl
0136         DESTINATION ${KDE_INSTALL_DATAROOTDIR}/kconf_update)
0137
0138 install(FILES
0139                 AUTHORS
0140                 ChangeLog
0141                 README
0142                 README.cwl
0143                 kile-remote-control.txt
0144         DESTINATION ${KDE_INSTALL_DATAROOTDIR}/doc/kile)
0145
0146 ki18n_install(po)
0147
0148 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)