src/config/CMakeLists.txt

0001 # SPDX-License-Identifier: GPL-2.0-or-later
0002 # SPDX-FileCopyrightText: 2012-2022 Thomas Fischer <fischer@unix-ag.uni-kl.de>
0003 # SPDX-FileContributor: 2019 Jonathan Riddell <jr@jriddell.org>
0004
0005 set(
0006     kbibtexconfig_SRCS
0007     notificationhub.cpp
0008     bibtexentries.cpp
0009     bibtexfields.cpp
0010     preferences.cpp
0011 )
0012
0013 ecm_qt_declare_logging_category(kbibtexconfig_SRCS
0014     HEADER logging_config.h
0015     IDENTIFIER LOG_KBIBTEX_CONFIG
0016     CATEGORY_NAME kbibtex.config
0017 )
0018
0019 if(UNITY_BUILD)
0020     enable_unity_build(kbibtexconfig kbibtexconfig_SRCS)
0021 endif(UNITY_BUILD)
0022
0023 add_library(kbibtexconfig
0024     SHARED
0025     ${kbibtexconfig_SRCS}
0026 )
0027
0028 generate_export_header(kbibtexconfig)
0029 add_library(KBibTeX::Config ALIAS kbibtexconfig)
0030
0031 set_target_properties(kbibtexconfig
0032     PROPERTIES
0033     EXPORT_NAME "kbibtexconfig"
0034     VERSION ${KBIBTEX_RELEASE_VERSION}
0035     SOVERSION ${KBIBTEX_SOVERSION}
0036 )
0037
0038 target_include_directories(kbibtexconfig
0039     INTERFACE
0040         $<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KBibTeX/config>
0041 )
0042
0043 target_link_libraries(kbibtexconfig
0044     PUBLIC
0045         Qt${QT_VERSION_MAJOR}::Core
0046         KBibTeX::Global
0047     PRIVATE
0048         KF${QT_VERSION_MAJOR}::ConfigCore
0049 )
0050
0051 if(KF${QT_VERSION_MAJOR}I18n_FOUND)
0052     target_link_libraries(kbibtexconfig
0053         PRIVATE
0054             KF${QT_VERSION_MAJOR}::I18n
0055     )
0056 endif()
0057
0058 install(
0059     TARGETS kbibtexconfig
0060     EXPORT kbibtexconfig-targets
0061     LIBRARY NAMELINK_SKIP
0062     ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0063 )
0064
0065 set_target_properties(kbibtexconfig PROPERTIES
0066     EXPORT_NAME "Config"
0067 )
0068
0069 ecm_generate_headers(kbibtexconfig_HEADERS
0070     HEADER_NAMES
0071         BibTeXEntries
0072         BibTeXFields
0073         NotificationHub
0074         Preferences
0075     REQUIRED_HEADERS kbibtexconfig_HEADERS
0076 )
0077
0078 install(FILES
0079     ${CMAKE_CURRENT_BINARY_DIR}/kbibtexconfig_export.h
0080     ${kbibtexconfig_HEADERS}
0081     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KBibTeX/config
0082     COMPONENT Devel
0083 )
0084
0085 include(CMakePackageConfigHelpers)
0086 write_basic_package_version_file(
0087     ${CMAKE_CURRENT_BINARY_DIR}/KBibTeXConfig-configVersion.cmake
0088     VERSION ${PROJECT_VERSION}
0089     COMPATIBILITY ExactVersion
0090 )
0091
0092 configure_package_config_file(${CMAKE_CURRENT_LIST_DIR}/cmake/KBibTeXConfig-config.cmake.in
0093     ${CMAKE_CURRENT_BINARY_DIR}/KBibTeXConfig-config.cmake
0094     INSTALL_DESTINATION ${KDE_INSTALL_LIBDIR}/cmake/KBibTeX
0095 )
0096
0097 install(FILES
0098     ${CMAKE_CURRENT_BINARY_DIR}/KBibTeXConfig-config.cmake
0099     ${CMAKE_CURRENT_BINARY_DIR}/KBibTeXConfig-configVersion.cmake
0100     DESTINATION ${KDE_INSTALL_LIBDIR}/cmake/KBibTeX
0101 )