cmake/modules/MacroOptionalFindPackage.cmake

0001 # - MACRO_OPTIONAL_FIND_PACKAGE() combines FIND_PACKAGE() with an OPTION()
0002 # MACRO_OPTIONAL_FIND_PACKAGE( <name> [QUIT] )
0003 # This macro is a combination of OPTION() and FIND_PACKAGE(), it
0004 # works like FIND_PACKAGE(), but additionally it automatically creates
0005 # an option name WITH_<name>, which can be disabled via the cmake GUI.
0006 # or via -DWITH_<name>=OFF
0007 # The standard <name>_FOUND variables can be used in the same way
0008 # as when using the normal FIND_PACKAGE()
0009
0010 # Copyright (c) 2006-2010 Alexander Neundorf, <neundorf@kde.org>
0011 #
0012 # Redistribution and use is allowed according to the terms of the BSD license.
0013 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
0014
0015 # This is just a helper macro to set a bunch of variables empty.
0016 # We don't know whether the package uses UPPERCASENAME or CamelCaseName, so we try both:
0017 macro(_MOFP_SET_EMPTY_IF_DEFINED _name _var)
0018    if(DEFINED ${_name}_${_var})
0019       set(${_name}_${_var} "")
0020    endif(DEFINED ${_name}_${_var})
0021
0022    string(TOUPPER ${_name} _nameUpper)
0023    if(DEFINED ${_nameUpper}_${_var})
0024       set(${_nameUpper}_${_var}  "")
0025    endif(DEFINED ${_nameUpper}_${_var})
0026 endmacro(_MOFP_SET_EMPTY_IF_DEFINED _package _var)
0027
0028
0029 macro (MACRO_OPTIONAL_FIND_PACKAGE _name )
0030    option(WITH_${_name} "Search for ${_name} package" ON)
0031    if (WITH_${_name})
0032       find_package(${_name} ${ARGN})
0033    else (WITH_${_name})
0034       string(TOUPPER ${_name} _nameUpper)
0035       set(${_name}_FOUND FALSE)
0036       set(${_nameUpper}_FOUND FALSE)
0037
0038       _mofp_set_empty_if_defined(${_name} INCLUDE_DIRS)
0039       _mofp_set_empty_if_defined(${_name} INCLUDE_DIR)
0040       _mofp_set_empty_if_defined(${_name} INCLUDES)
0041       _mofp_set_empty_if_defined(${_name} LIBRARY)
0042       _mofp_set_empty_if_defined(${_name} LIBRARIES)
0043       _mofp_set_empty_if_defined(${_name} LIBS)
0044       _mofp_set_empty_if_defined(${_name} FLAGS)
0045       _mofp_set_empty_if_defined(${_name} DEFINITIONS)
0046    endif (WITH_${_name})
0047 endmacro (MACRO_OPTIONAL_FIND_PACKAGE)
0048