cmake/modules/FindLibXml2.cmake

0001 # - Try to find LibXml2
0002 # Once done this will define
0003 #
0004 #  LIBXML2_FOUND - System has LibXml2
0005 #  LIBXML2_INCLUDE_DIR - The LibXml2 include directory
0006 #  LIBXML2_LIBRARIES - The libraries needed to use LibXml2
0007 #  LIBXML2_DEFINITIONS - Compiler switches required for using LibXml2
0008 #  LIBXML2_XMLLINT_EXECUTABLE - The XML checking tool xmllint coming with LibXml2
0009
0010 # Copyright (c) 2006, Alexander Neundorf, <neundorf@kde.org>
0011 #
0012 # Redistribution and use is allowed according to the terms of the BSD license.
0013 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
0014
0015
0016 IF (LIBXML2_INCLUDE_DIR AND LIBXML2_LIBRARIES)
0017    # in cache already
0018    SET(LibXml2_FIND_QUIETLY TRUE)
0019 ENDIF (LIBXML2_INCLUDE_DIR AND LIBXML2_LIBRARIES)
0020
0021 IF (NOT WIN32)
0022    # use pkg-config to get the directories and then use these values
0023    # in the FIND_PATH() and FIND_LIBRARY() calls
0024    FIND_PACKAGE(PkgConfig)
0025    PKG_CHECK_MODULES(PC_LIBXML libxml-2.0)
0026    SET(LIBXML2_DEFINITIONS ${PC_LIBXML_CFLAGS_OTHER})
0027 ENDIF (NOT WIN32)
0028
0029 FIND_PATH(LIBXML2_INCLUDE_DIR libxml/xpath.h
0030    HINTS
0031    ${PC_LIBXML_INCLUDEDIR}
0032    ${PC_LIBXML_INCLUDE_DIRS}
0033    PATH_SUFFIXES libxml2
0034    )
0035
0036 FIND_LIBRARY(LIBXML2_LIBRARIES NAMES xml2 libxml2
0037    HINTS
0038    ${PC_LIBXML_LIBDIR}
0039    ${PC_LIBXML_LIBRARY_DIRS}
0040    )
0041
0042 FIND_PROGRAM(LIBXML2_XMLLINT_EXECUTABLE xmllint)
0043 # for backwards compat. with KDE 4.0.x:
0044 SET(XMLLINT_EXECUTABLE "${LIBXML2_XMLLINT_EXECUTABLE}")
0045
0046 IF( NOT LIBXML2_XMLLINT_EXECUTABLE )
0047    MESSAGE(STATUS "xmllint program not found. Install it if you want validate generated doc file.")
0048 ENDIF(NOT LIBXML2_XMLLINT_EXECUTABLE )
0049
0050
0051 INCLUDE(FindPackageHandleStandardArgs)
0052
0053 # handle the QUIETLY and REQUIRED arguments and set LIBXML2_FOUND to TRUE if
0054 # all listed variables are TRUE
0055 FIND_PACKAGE_HANDLE_STANDARD_ARGS(LibXml2 DEFAULT_MSG LIBXML2_LIBRARIES LIBXML2_INCLUDE_DIR)
0056
0057 MARK_AS_ADVANCED(LIBXML2_INCLUDE_DIR LIBXML2_LIBRARIES LIBXML2_XMLLINT_EXECUTABLE)