network/ktp-contact-list/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 # KDE Application Version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set (RELEASE_SERVICE_VERSION_MINOR "07")
0006 set (RELEASE_SERVICE_VERSION_MICRO "70")
0007
0008 set(KTP_CONTACT_LIST_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0009
0010 project (ktp-contactlist VERSION ${KTP_CONTACT_LIST_VERSION})
0011
0012 find_package(ECM 1.6.0 REQUIRED NO_MODULE)
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 find_package (Qt5 5.0 REQUIRED COMPONENTS Widgets Xml)
0016 find_package (KF5 5.11 REQUIRED COMPONENTS DBusAddons KIO KCMUtils Notifications WindowSystem NotifyConfig I18n IconThemes XmlGui KCMUtils People)
0017 find_package (TelepathyQt5 0.9.3 REQUIRED)
0018 find_package (KTp REQUIRED)
0019
0020 include(KDEInstallDirs)
0021 include(KDECMakeSettings)
0022 include(KDECompilerSettings NO_POLICY_SCOPE)
0023 include(FeatureSummary)
0024
0025 set_package_properties(KF5People PROPERTIES DESCRIPTION "KDE Contacts aggregation"
0026                        TYPE OPTIONAL
0027 )
0028
0029 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0030
0031 if (KF5People_FOUND)
0032     add_definitions(-DHAVE_KPEOPLE)
0033 endif ()
0034 add_definitions(-DQT_NO_URL_CAST_FROM_STRING)
0035
0036 set (ktp_contactlist_SRCS
0037      contact-list-widget.cpp
0038      context-menu.cpp
0039      abstract-contact-delegate.cpp
0040      contact-view-hover-button.cpp
0041      contact-overlays.cpp
0042      contact-delegate-overlay.cpp
0043      contact-delegate.cpp
0044      contact-delegate-compact.cpp
0045      empty-row-filter.cpp
0046      ktp-contactlist-debug.cpp
0047      filter-bar.cpp
0048      main.cpp
0049      main-widget.cpp
0050      global-presence-chooser.cpp
0051      dialogs/remove-contact-dialog.cpp
0052      dialogs/custom-presence-dialog.cpp
0053      dialogs/advanced-presence-dialog.cpp
0054      tooltips/ktooltip.cpp
0055      tooltips/tooltipmanager.cpp
0056      tooltips/ktooltipwindow.cpp
0057      tooltips/contacttooltip.cpp
0058      tooltips/persontooltip.cpp
0059 )
0060
0061 if(KF5People_FOUND)
0062     set (ktp_contactlist_LIBS
0063         KF5::PeopleWidgets
0064     )
0065 endif()
0066
0067 configure_file(version.h.in ${CMAKE_CURRENT_BINARY_DIR}/version.h)
0068
0069 ki18n_wrap_ui(ktp_contactlist_SRCS
0070     main-widget.ui
0071     dialogs/remove-contact-dialog.ui
0072     tooltips/contacttooltip.ui
0073     tooltips/persontooltip.ui
0074 )
0075
0076 add_executable (ktp-contactlist ${ktp_contactlist_SRCS})
0077
0078 target_link_libraries (ktp-contactlist ${ktp_contactlist_LIBS}
0079     KF5::KIOWidgets
0080     KF5::KCMUtils
0081     KF5::NotifyConfig
0082     KF5::DBusAddons
0083     KF5::I18n
0084     KF5::IconThemes
0085     KF5::XmlGui
0086     KF5::KCMUtils
0087     KF5::Notifications
0088     KF5::WindowSystem
0089     KTp::Models
0090     KTp::Widgets
0091     KTp::Logger
0092     KTp::CommonInternals
0093 )
0094
0095 configure_file(org.kde.ktpcontactlist.service.in
0096                ${CMAKE_CURRENT_BINARY_DIR}/org.kde.ktpcontactlist.service)
0097
0098
0099 # Install:
0100 install (TARGETS ktp-contactlist
0101          ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0102 )
0103
0104 install (PROGRAMS org.kde.ktpcontactlist.desktop
0105          DESTINATION ${KDE_INSTALL_APPDIR}
0106 )
0107
0108 install (FILES ${CMAKE_CURRENT_BINARY_DIR}/org.kde.ktpcontactlist.service
0109          DESTINATION ${KDE_INSTALL_DBUSSERVICEDIR}
0110 )
0111
0112 ki18n_install(po)